lib/Web/Simple/Application.pm

   1 package Web::Simple::Application;
   2
   3 use Moo;
   4
   5 has 'config' => (
   6   is => 'ro',
   7   default => sub {
   8     my ($self) = @_;
   9     +{ $self->default_config }
  10   },
  11   trigger => sub {
  12     my ($self, $value) = @_;
  13     my %default = $self->default_config;
  14     my @not = grep !exists $value->{$_}, keys %default;
  15     @{$value}{@not} = @default{@not};
  16   }
  17 );
  18
  19 sub default_config { () }
  20
  21 has '_dispatcher' => (is => 'lazy');
  22
  23 sub _build__dispatcher {
  24   my $self = shift;
  25   require Web::Dispatch;
  26   require Web::Simple::DispatchNode;
  27   my $final = $self->_build_final_dispatcher;
  28   Web::Dispatch->new(
  29     app => sub { $self->dispatch_request(@_), $final },
  30     node_class => 'Web::Simple::DispatchNode',
  31     node_args => { app_object => $self }
  32   );
  33 }
  34
  35 sub _build_final_dispatcher {
  36   [ 404, [ 'Content-type', 'text/plain' ], [ 'Not found' ] ]
  37 }
  38
  39 sub run_if_script {
  40   # ->to_psgi_app is true for require() but also works for plackup
  41   return $_[0]->to_psgi_app if caller(1);
  42   my $self = ref($_[0]) ? $_[0] : $_[0]->new;
  43   $self->run(@_);
  44 }
  45
  46 sub _run_cgi {
  47   my $self = shift;
  48   require Plack::Handler::CGI;
  49   Plack::Handler::CGI->new->run($self->to_psgi_app);
  50 }
  51
  52 sub _run_fcgi {
  53   my $self = shift;
  54   require Plack::Handler::FCGI;
  55   Plack::Handler::FCGI->new->run($self->to_psgi_app);
  56 }
  57
  58 sub to_psgi_app {
  59   my $self = ref($_[0]) ? $_[0] : $_[0]->new;
  60   $self->_dispatcher->to_app;
  61 }
  62
  63 sub run {
  64   my $self = shift;
  65   if (
  66     $ENV{PHP_FCGI_CHILDREN} || $ENV{FCGI_ROLE} || $ENV{FCGI_SOCKET_PATH}
  67     || -S STDIN # STDIN is a socket, almost certainly FastCGI
  68     ) {
  69     return $self->_run_fcgi;
  70   } elsif ($ENV{GATEWAY_INTERFACE}) {
  71     return $self->_run_cgi;
  72   }
  73   unless (@ARGV && $ARGV[0] =~ m{^[A-Z/]}) {
  74     return $self->_run_cli(@ARGV);
  75   }
  76
  77   my @args = @ARGV;
  78
  79   unshift(@args, 'GET') if $args[0] =~ m{^/};
  80
  81   $self->_run_test_request(@args);
  82 }
  83
  84 sub _run_test_request {
  85   my ($self, $method, $path, @rest) = @_;
  86
  87   require HTTP::Request;
  88   require Plack::Test;
  89
  90   my $request = HTTP::Request->new($method => $path);
  91   if ($method eq 'POST' or $method eq 'PUT' and @rest) {
  92     my $content = do {
  93       require URI;
  94       my $url = URI->new('http:');
  95       $url->query_form(@rest);
  96       $url->query;
  97     };
  98     $request->header('Content-Type' => 'application/x-www-form-urlencoded');
  99     $request->header('Content-Length' => length($content));
 100     $request->content($content);
 101   }
 102   my $response;
 103   Plack::Test::test_psgi(
 104     $self->to_psgi_app, sub { $response = shift->($request) }
 105   );
 106   print STDERR $response->status_line."\n";
 107   print STDERR $response->headers_as_string("\n")."\n";
 108   my $content = $response->content;
 109   $content .= "\n" if length($content) and $content !~ /\n\z/;
 110   print STDOUT $content if $content;
 111 }
 112
 113 sub _run_cli {
 114   my $self = shift;
 115   die $self->_cli_usage;
 116 }
 117
 118 sub _cli_usage {
 119   "To run this script in CGI test mode, pass a URL path beginning with /:\n".
 120   "\n".
 121   "  $0 /some/path\n".
 122   "  $0 /\n"
 123 }
 124
 125 1;
 126
 127 =head1 NAME
 128
 129 Web::Simple::Application - A base class for your Web-Simple application
 130
 131 =head1 DESCRIPTION
 132
 133 This is a base class for your L<Web::Simple> application.  You probably don't
 134 need to construct this class yourself, since L<Web::Simple> does the 'heavy
 135 lifting' for you in that regards.
 136
 137 =head1 METHODS
 138
 139 This class exposes the following public methods.
 140
 141 =head2 default_config
 142
 143 Merges with the C<config> initializer to provide configuration information for
 144 your application.  For example:
 145
 146   sub default_config {
 147     (
 148       title => 'Bloggery',
 149       posts_dir => $FindBin::Bin.'/posts',
 150     );
 151   }
 152
 153 Now, the C<config> attribute of C<$self>  will be set to a HashRef
 154 containing keys 'title' and 'posts_dir'.
 155
 156 The keys from default_config are merged into any config supplied, so
 157 if you construct your application like:
 158
 159   MyWebSimpleApp::Web->new(
 160     config => { title => 'Spoon', environment => 'dev' }
 161   )
 162
 163 then C<config> will contain:
 164
 165   {
 166     title => 'Spoon',
 167     posts_dir => '/path/to/myapp/posts',
 168     environment => 'dev'
 169   }
 170
 171 =head2 run_if_script
 172
 173 The run_if_script method is designed to be used at the end of the script
 174 or .pm file where your application class is defined - for example:
 175
 176   ## my_web_simple_app.pl
 177   #!/usr/bin/env perl
 178   use Web::Simple 'HelloWorld';
 179
 180   {
 181     package HelloWorld;
 182
 183     sub dispatch_request {
 184       sub (GET) {
 185         [ 200, [ 'Content-type', 'text/plain' ], [ 'Hello world!' ] ]
 186       },
 187       sub () {
 188         [ 405, [ 'Content-type', 'text/plain' ], [ 'Method not allowed' ] ]
 189       }
 190     }
 191   }
 192
 193   HelloWorld->run_if_script;
 194
 195 This returns a true value, so your file is now valid as a module - so
 196
 197   require 'my_web_simple_app.pl';
 198
 199   my $hw = HelloWorld->new;
 200
 201 will work fine (and you can rename it to lib/HelloWorld.pm later to make it
 202 a real use-able module).
 203
 204 However, it detects if it's being run as a script (via testing $0) and if
 205 so attempts to do the right thing.
 206
 207 If run under a CGI environment, your application will execute as a CGI.
 208
 209 If run under a FastCGI environment, your application will execute as a
 210 FastCGI process (this works both for dynamic shared-hosting-style FastCGI
 211 and for apache FastCgiServer style setups).
 212
 213 If run from the commandline with a URL path, it runs a GET request against
 214 that path -
 215
 216   $ perl -Ilib examples/hello-world/hello-world.cgi /
 217   200 OK
 218   Content-Type: text/plain
 219
 220   Hello world!
 221
 222 Additionally, you can treat the file as though it were a standard PSGI
 223 application file (*.psgi).  For example you can start up up with C<plackup>
 224
 225   plackup my_web_simple_app.pl
 226
 227 or C<starman>
 228
 229   starman my_web_simple_app.pl
 230
 231 =head2 to_psgi_app
 232
 233 This method is called by L</run_if_script> to create the L<PSGI> app coderef
 234 for use via L<Plack> and L<plackup>. If you want to globally add middleware,
 235 you can override this method:
 236
 237   use Web::Simple 'HelloWorld';
 238   use Plack::Builder;
 239
 240   {
 241     package HelloWorld;
 242
 243
 244     around 'to_psgi_app', sub {
 245       my ($orig, $self) = (shift, shift);
 246       my $app = $self->$orig(@_);
 247       builder {
 248         enable ...; ## whatever middleware you want
 249         $app;
 250       };
 251     };
 252   }
 253
 254 This method can also be used to mount a Web::Simple application within
 255 a separate C<*.psgi> file -
 256
 257   use strictures 1;
 258   use Plack::Builder;
 259   use WSApp;
 260   use AnotherWSApp;
 261
 262   builder {
 263     mount '/' => WSApp->to_psgi_app;
 264     mount '/another' => AnotherWSApp->to_psgi_app;
 265   };
 266
 267 This method can be called as a class method, in which case it implicitly
 268 calls ->new, or as an object method ... in which case it doesn't.
 269
 270 =head2 run
 271
 272 Used for running your application under stand-alone CGI and FCGI modes.
 273
 274 =head1 AUTHORS
 275
 276 See L<Web::Simple> for authors.
 277
 278 =head1 COPYRIGHT AND LICENSE
 279
 280 See L<Web::Simple> for the copyright and license.
 281
 282 =cut