lib/Web/Simple/Application.pm

   1 package Web::Simple::Application;
   2
   3 use Moo;
   4
   5 has 'config' => (
   6   is => 'ro',
   7   default => sub {
   8     my ($self) = @_;
   9     +{ $self->default_config }
  10   },
  11   trigger => sub {
  12     my ($self, $value) = @_;
  13     my %default = $self->default_config;
  14     my @not = grep !exists $value->{$_}, keys %default;
  15     @{$value}{@not} = @default{@not};
  16   }
  17 );
  18
  19 sub default_config { () }
  20
  21 has '_dispatcher' => (is => 'lazy');
  22
  23 sub _build__dispatcher {
  24   my $self = shift;
  25   require Web::Dispatch;
  26   require Web::Simple::DispatchNode;
  27   my $final = $self->_build_final_dispatcher;
  28   Web::Dispatch->new(
  29     app => sub { $self->dispatch_request(@_), $final },
  30     node_class => 'Web::Simple::DispatchNode',
  31     node_args => { app_object => $self }
  32   );
  33 }
  34
  35 sub _build_final_dispatcher {
  36   [ 404, [ 'Content-type', 'text/plain' ], [ 'Not found' ] ]
  37 }
  38
  39 sub run_if_script {
  40   # ->to_psgi_app is true for require() but also works for plackup
  41   return $_[0]->to_psgi_app if caller(1);
  42   my $self = ref($_[0]) ? $_[0] : $_[0]->new;
  43   $self->run(@_);
  44 }
  45
  46 sub _run_cgi {
  47   my $self = shift;
  48   require Plack::Server::CGI;
  49   Plack::Server::CGI->run($self->to_psgi_app);
  50 }
  51
  52 sub _run_fcgi {
  53   my $self = shift;
  54   require Plack::Server::FCGI;
  55   Plack::Server::FCGI->run($self->to_psgi_app);
  56 }
  57
  58 sub to_psgi_app {
  59   my $self = ref($_[0]) ? $_[0] : $_[0]->new;
  60   $self->_dispatcher->to_app;
  61 }
  62
  63 sub run {
  64   my $self = shift;
  65   if ($ENV{PHP_FCGI_CHILDREN} || $ENV{FCGI_ROLE} || $ENV{FCGI_SOCKET_PATH}) {
  66     return $self->_run_fcgi;
  67   } elsif ($ENV{GATEWAY_INTERFACE}) {
  68     return $self->_run_cgi;
  69   }
  70   unless (@ARGV && $ARGV[0] =~ m{^/}) {
  71     return $self->_run_cli(@ARGV);
  72   }
  73
  74   my $path = shift @ARGV;
  75
  76   require HTTP::Request::Common;
  77   require Plack::Test;
  78   local *GET = \&HTTP::Request::Common::GET;
  79
  80   my $request = GET($path);
  81   my $response;
  82   Plack::Test::test_psgi($self->to_psgi_app, sub { $response = shift->($request) });
  83   print $response->as_string;
  84 }
  85
  86 sub _run_cli {
  87   my $self = shift;
  88   die $self->_cli_usage;
  89 }
  90
  91 sub _cli_usage {
  92   "To run this script in CGI test mode, pass a URL path beginning with /:\n".
  93   "\n".
  94   "  $0 /some/path\n".
  95   "  $0 /\n"
  96 }
  97
  98 1;
  99
 100 =head1 NAME
 101
 102 Web::Simple::Application - A base class for your Web-Simple application
 103
 104 =head1 DESCRIPTION
 105
 106 This is a base class for your L<Web::Simple> application.  You probably don't
 107 need to construct this class yourself, since L<Web::Simple> does the 'heavy
 108 lifting' for you in that regards.
 109
 110 =head1 METHODS
 111
 112 This class exposes the following public methods.
 113
 114 =head2 default_config
 115
 116 Merges with the C<config> initializer to provide configuration information for
 117 your application.  For example:
 118
 119   sub default_config {
 120     (
 121       title => 'Bloggery',
 122       posts_dir => $FindBin::Bin.'/posts',
 123     );
 124   }
 125
 126 Now, the C<config> attribute of C<$self>  will be set to a HashRef
 127 containing keys 'title' and 'posts_dir'.
 128
 129 The keys from default_config are merged into any config supplied, so
 130 if you construct your application like:
 131
 132   MyWebSimpleApp::Web->new(
 133     config => { title => 'Spoon', environment => 'dev' }
 134   )
 135
 136 then C<config> will contain:
 137
 138   {
 139     title => 'Spoon',
 140     posts_dir => '/path/to/myapp/posts',
 141     environment => 'dev'
 142   }
 143
 144 =head2 run_if_script
 145
 146 The run_if_script method is designed to be used at the end of the script
 147 or .pm file where your application class is defined - for example:
 148
 149   ## my_web_simple_app.pl
 150   #!/usr/bin/env perl
 151   use Web::Simple 'HelloWorld';
 152
 153   {
 154     package HelloWorld;
 155
 156     sub dispatch_request {
 157       sub (GET) {
 158         [ 200, [ 'Content-type', 'text/plain' ], [ 'Hello world!' ] ]
 159       },
 160       sub () {
 161         [ 405, [ 'Content-type', 'text/plain' ], [ 'Method not allowed' ] ]
 162       }
 163     }
 164   }
 165
 166   HelloWorld->run_if_script;
 167
 168 This returns a true value, so your file is now valid as a module - so
 169
 170   require 'my_web_simple_app.pl';
 171
 172   my $hw = HelloWorld->new;
 173
 174 will work fine (and you can rename it to lib/HelloWorld.pm later to make it
 175 a real use-able module).
 176
 177 However, it detects if it's being run as a script (via testing $0) and if
 178 so attempts to do the right thing.
 179
 180 If run under a CGI environment, your application will execute as a CGI.
 181
 182 If run under a FastCGI environment, your application will execute as a
 183 FastCGI process (this works both for dynamic shared-hosting-style FastCGI
 184 and for apache FastCgiServer style setups).
 185
 186 If run from the commandline with a URL path, it runs a GET request against
 187 that path -
 188
 189   $ perl -Ilib examples/hello-world/hello-world.cgi /
 190   200 OK
 191   Content-Type: text/plain
 192
 193   Hello world!
 194
 195 Additionally, you can treat the file as though it were a standard PSGI
 196 application file (*.psgi).  For example you can start up up with C<plackup>
 197
 198   plackup my_web_simple_app.pl
 199
 200 or C<starman>
 201
 202   starman my_web_simple_app.pl
 203
 204 =head2 to_psgi_app
 205
 206 This method is called by L</run_if_script> to create the L<PSGI> app coderef
 207 for use via L<Plack> and L<plackup>. If you want to globally add middleware,
 208 you can override this method:
 209
 210   use Web::Simple 'HelloWorld';
 211   use Plack::Builder;
 212
 213   {
 214     package HelloWorld;
 215
 216
 217     around 'to_psgi_app', sub {
 218       my ($orig, $self) = (shift, shift);
 219       my $app = $self->$orig(@_);
 220       builder {
 221         enable ...; ## whatever middleware you want
 222         $app;
 223       };
 224     };
 225   }
 226
 227 This method can also be used to mount a Web::Simple application within
 228 a separate C<*.psgi> file -
 229
 230   use strictures 1;
 231   use Plack::Builder;
 232   use WSApp;
 233   use AnotherWSApp;
 234
 235   builder {
 236     mount '/' => WSApp->to_psgi_app;
 237     mount '/another' => AnotherWSApp->to_psgi_app;
 238   };
 239
 240 This method can be called as a class method, in which case it implicitly
 241 calls ->new, or as an object method ... in which case it doesn't.
 242
 243 =head2 run
 244
 245 Used for running your application under stand-alone CGI and FCGI modes. Also
 246 useful for testing:
 247
 248     my $app = MyWebSimpleApp::Web->new;
 249     my $c = HTTP::Request::AsCGI->new(@args)->setup;
 250     $app->run;
 251
 252 =head1 AUTHOR
 253
 254 Matt S. Trout <mst@shadowcat.co.uk>
 255
 256 =head1 CONTRIBUTORS
 257
 258 None required yet. Maybe this module is perfect (hahahahaha ...).
 259
 260 =head1 COPYRIGHT
 261
 262 Copyright (c) 2010 the Web::Simple L</AUTHOR> and L</CONTRIBUTORS>
 263 as listed above.
 264
 265 =head1 LICENSE
 266
 267 This library is free software and may be distributed under the same terms
 268 as perl itself.
 269
 270 =cut