lib/Web/Simple/Application.pm

   1 package Web::Simple::Application;
   2
   3 use Scalar::Util 'weaken';
   4 use Try::Tiny;
   5
   6 use Moo;
   7
   8 has 'config' => (
   9   is => 'ro',
  10   default => sub {
  11     my ($self) = @_;
  12     +{ $self->default_config }
  13   },
  14   trigger => sub {
  15     my ($self, $value) = @_;
  16     my %default = $self->default_config;
  17     my @not = grep !exists $value->{$_}, keys %default;
  18     @{$value}{@not} = @default{@not};
  19   }
  20 );
  21
  22 sub default_config { () }
  23
  24 has '_dispatcher' => (is => 'lazy');
  25
  26 sub _build__dispatcher {
  27   my $self = shift;
  28   require Web::Dispatch;
  29   my $final = $self->_build_final_dispatcher;
  30
  31   # We need to weaken both the copy of $self that the
  32   # app parameter will close over and the copy that'll
  33   # be passed through as a node argument.
  34   #
  35   # To ensure that this doesn't then result in us being
  36   # DESTROYed unexpectedly early, our to_psgi_app method
  37   # closes back over $self
  38
  39   weaken($self);
  40   my %dispatch_args = (
  41     dispatch_app => sub { $self->dispatch_request(@_), $final },
  42     dispatch_object => $self
  43   );
  44   weaken($dispatch_args{dispatch_object});
  45   Web::Dispatch->new(%dispatch_args);
  46 }
  47
  48 sub _build_final_dispatcher {
  49   [ 404, [ 'Content-type', 'text/plain' ], [ 'Not found' ] ]
  50 }
  51
  52 sub run_if_script {
  53   my ( $self, @args ) = @_;
  54   # ->to_psgi_app is true for require() but also works for plackup
  55   return $self->to_psgi_app if caller(1);
  56   $self = ref($self) ? $self : $self->_build_for_run_if_script(@args);
  57   $self->run;
  58 }
  59
  60 sub _build_for_run_if_script {
  61   my ( $self, @args ) = @_;
  62   try { $self->new(@args) }
  63   catch {
  64     die "Failed to create new '$self' object during run_if_script"
  65       . " (should your .pm file end with just '1;'?) : $_\n";
  66   };
  67 }
  68
  69 sub _run_cgi {
  70   my $self = shift;
  71   require Plack::Handler::CGI;
  72   Plack::Handler::CGI->new->run($self->to_psgi_app);
  73 }
  74
  75 sub _run_fcgi {
  76   my $self = shift;
  77   require Plack::Handler::FCGI;
  78   Plack::Handler::FCGI->new->run($self->to_psgi_app);
  79 }
  80
  81 sub to_psgi_app {
  82   my $self = ref($_[0]) ? $_[0] : $_[0]->new;
  83   my $app = $self->_dispatcher->to_app;
  84
  85   # Close over $self to keep $self alive even though
  86   # we weakened the copies the dispatcher has; the
  87   # if 0 causes the ops to be optimised away to
  88   # minimise the performance impact and avoid void
  89   # context warnings while still doing the closing
  90   # over part. As Mithaldu said: "Gnarly." ...
  91
  92   return sub { $self if 0; goto &$app; };
  93 }
  94
  95 sub run {
  96   my $self = shift;
  97   if (
  98     $ENV{PHP_FCGI_CHILDREN} || $ENV{FCGI_ROLE} || $ENV{FCGI_SOCKET_PATH}
  99     || ( -S STDIN && !$ENV{GATEWAY_INTERFACE} )
 100     # If STDIN is a socket, almost certainly FastCGI, except for mod_cgid
 101     ) {
 102     return $self->_run_fcgi;
 103   } elsif ($ENV{GATEWAY_INTERFACE}) {
 104     return $self->_run_cgi;
 105   }
 106   unless (@ARGV && $ARGV[0] =~ m{(^[A-Z/])|\@}) {
 107     return $self->_run_cli(@ARGV);
 108   }
 109
 110   my @args = @ARGV;
 111
 112   unshift(@args, 'GET') if $args[0] !~ /^[A-Z]/;
 113
 114   $self->_run_cli_test_request(@args);
 115 }
 116
 117 sub _test_request_spec_to_http_request {
 118   my ($self, $method, $path, @rest) = @_;
 119
 120   # if it's a reference, assume a request object
 121   return $method if ref($method);
 122
 123   if ($path =~ s/^(.*?)\@//) {
 124     my $basic = $1;
 125     require MIME::Base64;
 126     unshift @rest, 'Authorization:', 'Basic '.MIME::Base64::encode($basic);
 127   }
 128
 129   my $request = HTTP::Request->new($method => $path);
 130
 131   my @params;
 132
 133   while (my ($header, $value) = splice(@rest, 0, 2)) {
 134     unless ($header =~ s/:$//) {
 135       push @params, $header, $value;
 136     }
 137     $header =~ s/_/-/g;
 138     if ($header eq 'Content') {
 139       $request->content($value);
 140     } else {
 141       $request->headers->push_header($header, $value);
 142     }
 143   }
 144
 145   if (($method eq 'POST' or $method eq 'PUT') and @params) {
 146     my $content = do {
 147       require URI;
 148       my $url = URI->new('http:');
 149       $url->query_form(@params);
 150       $url->query;
 151     };
 152     $request->header('Content-Type' => 'application/x-www-form-urlencoded');
 153     $request->header('Content-Length' => length($content));
 154     $request->content($content);
 155   }
 156
 157   return $request;
 158 }
 159
 160 sub run_test_request {
 161   my ($self, @req) = @_;
 162
 163   require HTTP::Request;
 164
 165   require Plack::Test;
 166
 167   my $request = $self->_test_request_spec_to_http_request(@req);
 168
 169   Plack::Test::test_psgi(
 170     $self->to_psgi_app, sub { shift->($request) }
 171   );
 172 }
 173
 174 sub _run_cli_test_request {
 175   my ($self, @req) = @_;
 176   my $response = $self->run_test_request(@req);
 177
 178   binmode(STDOUT); binmode(STDERR); # for win32
 179
 180   print STDERR $response->status_line."\n";
 181   print STDERR $response->headers_as_string("\n")."\n";
 182   my $content = $response->content;
 183   $content .= "\n" if length($content) and $content !~ /\n\z/;
 184   print STDOUT $content if $content;
 185 }
 186
 187 sub _run_cli {
 188   my $self = shift;
 189   die $self->_cli_usage;
 190 }
 191
 192 sub _cli_usage {
 193   "To run this script in CGI test mode, pass a URL path beginning with /:\n".
 194   "\n".
 195   "  $0 /some/path\n".
 196   "  $0 /\n"
 197 }
 198
 199 1;
 200
 201 =head1 NAME
 202
 203 Web::Simple::Application - A base class for your Web-Simple application
 204
 205 =head1 DESCRIPTION
 206
 207 This is a base class for your L<Web::Simple> application.  You probably don't
 208 need to construct this class yourself, since L<Web::Simple> does the 'heavy
 209 lifting' for you in that regards.
 210
 211 =head1 METHODS
 212
 213 This class exposes the following public methods.
 214
 215 =head2 default_config
 216
 217 Merges with the C<config> initializer to provide configuration information for
 218 your application.  For example:
 219
 220   sub default_config {
 221     (
 222       title => 'Bloggery',
 223       posts_dir => $FindBin::Bin.'/posts',
 224     );
 225   }
 226
 227 Now, the C<config> attribute of C<$self>  will be set to a HashRef
 228 containing keys 'title' and 'posts_dir'.
 229
 230 The keys from default_config are merged into any config supplied, so
 231 if you construct your application like:
 232
 233   MyWebSimpleApp::Web->new(
 234     config => { title => 'Spoon', environment => 'dev' }
 235   )
 236
 237 then C<config> will contain:
 238
 239   {
 240     title => 'Spoon',
 241     posts_dir => '/path/to/myapp/posts',
 242     environment => 'dev'
 243   }
 244
 245 =head2 run_if_script
 246
 247 The run_if_script method is designed to be used at the end of the script
 248 or .pm file where your application class is defined - for example:
 249
 250   ## my_web_simple_app.pl
 251   #!/usr/bin/env perl
 252   use Web::Simple 'HelloWorld';
 253
 254   {
 255     package HelloWorld;
 256
 257     sub dispatch_request {
 258       sub (GET) {
 259         [ 200, [ 'Content-type', 'text/plain' ], [ 'Hello world!' ] ]
 260       },
 261       sub () {
 262         [ 405, [ 'Content-type', 'text/plain' ], [ 'Method not allowed' ] ]
 263       }
 264     }
 265   }
 266
 267   HelloWorld->run_if_script;
 268
 269 This returns a true value, so your file is now valid as a module - so
 270
 271   require 'my_web_simple_app.pl';
 272
 273   my $hw = HelloWorld->new;
 274
 275 will work fine (and you can rename it to lib/HelloWorld.pm later to make it
 276 a real use-able module).
 277
 278 However, it detects if it's being run as a script (via testing $0) and if
 279 so attempts to do the right thing.
 280
 281 If run under a CGI environment, your application will execute as a CGI.
 282
 283 If run under a FastCGI environment, your application will execute as a
 284 FastCGI process (this works both for dynamic shared-hosting-style FastCGI
 285 and for apache FastCgiServer style setups).
 286
 287 If run from the commandline with a URL path, it runs a GET request against
 288 that path -
 289
 290   $ perl -Ilib examples/hello-world/hello-world.cgi /
 291   200 OK
 292   Content-Type: text/plain
 293
 294   Hello world!
 295
 296 You can also provide a method name -
 297
 298   $ perl -Ilib examples/hello-world/hello-world.cgi POST /
 299   405 Method Not Allowed
 300   Content-Type: text/plain
 301
 302   Method not allowed
 303
 304 For a POST or PUT request, pairs on the command line will be treated
 305 as form variables. For any request, pairs on the command line ending in :
 306 are treated as headers, and 'Content:' will set the request body -
 307
 308   $ ./myapp POST / Accept: text/html form_field_name form_field_value
 309
 310   $ ./myapp POST / Content-Type: text/json Content: '{ "json": "here" }'
 311
 312 The body of the response is sent to STDOUT and the headers to STDERR, so
 313
 314   $ ./myapp GET / >index.html
 315
 316 will generally do the right thing.
 317
 318 To send basic authentication credentials, use user:pass@ syntax -
 319
 320   $ ./myapp GET bob:secret@/protected/path
 321
 322 Additionally, you can treat the file as though it were a standard PSGI
 323 application file (*.psgi).  For example you can start up up with C<plackup>
 324
 325   plackup my_web_simple_app.pl
 326
 327 or C<starman>
 328
 329   starman my_web_simple_app.pl
 330
 331 =head2 to_psgi_app
 332
 333 This method is called by L</run_if_script> to create the L<PSGI> app coderef
 334 for use via L<Plack> and L<plackup>. If you want to globally add middleware,
 335 you can override this method:
 336
 337   use Web::Simple 'HelloWorld';
 338   use Plack::Builder;
 339
 340   {
 341     package HelloWorld;
 342
 343
 344     around 'to_psgi_app', sub {
 345       my ($orig, $self) = (shift, shift);
 346       my $app = $self->$orig(@_);
 347       builder {
 348         enable ...; ## whatever middleware you want
 349         $app;
 350       };
 351     };
 352   }
 353
 354 This method can also be used to mount a Web::Simple application within
 355 a separate C<*.psgi> file -
 356
 357   use strictures 1;
 358   use Plack::Builder;
 359   use WSApp;
 360   use AnotherWSApp;
 361
 362   builder {
 363     mount '/' => WSApp->to_psgi_app;
 364     mount '/another' => AnotherWSApp->to_psgi_app;
 365   };
 366
 367 This method can be called as a class method, in which case it implicitly
 368 calls ->new, or as an object method ... in which case it doesn't.
 369
 370 =head2 run
 371
 372 Used for running your application under stand-alone CGI and FCGI modes.
 373
 374 I should document this more extensively but run_if_script will call it when
 375 you need it, so don't worry about it too much.
 376
 377 =head2 run_test_request
 378
 379   my $res = $app->run_test_request(GET => '/' => %headers);
 380
 381   my $res = $app->run_test_request(POST => '/' => %headers_or_form);
 382
 383   my $res = $app->run_test_request($http_request);
 384
 385 Accepts either an L<HTTP::Request> object or ($method, $path) and runs that
 386 request against the application, returning an L<HTTP::Response> object.
 387
 388 If the HTTP method is POST or PUT, then a series of pairs can be passed after
 389 this to create a form style message body. If you need to test an upload, then
 390 create an L<HTTP::Request> object by hand or use the C<POST> subroutine
 391 provided by L<HTTP::Request::Common>.
 392
 393 If you prefix the URL with 'user:pass@' this will be converted into
 394 an Authorization header for HTTP basic auth:
 395
 396   my $res = $app->run_test_request(
 397               GET => 'bob:secret@/protected/resource'
 398             );
 399
 400 If pairs are passed where the key ends in :, it is instead treated as a
 401 headers, so:
 402
 403   my $res = $app->run_test_request(
 404               POST => '/',
 405              'Accept:' => 'text/html',
 406               some_form_key => 'value'
 407             );
 408
 409 will do what you expect. You can also pass a special key of Content: to
 410 set the request body:
 411
 412   my $res = $app->run_test_request(
 413               POST => '/',
 414               'Content-Type:' => 'text/json',
 415               'Content:' => '{ "json": "here" }',
 416             );
 417
 418 =head1 AUTHORS
 419
 420 See L<Web::Simple> for authors.
 421
 422 =head1 COPYRIGHT AND LICENSE
 423
 424 See L<Web::Simple> for the copyright and license.
 425
 426 =cut