lib/Web/Dispatch/Parser.pm

   1 package Web::Dispatch::Parser;
   2
   3 sub DEBUG () { 0 }
   4
   5 BEGIN {
   6   if ($ENV{WEB_DISPATCH_PARSER_DEBUG}) {
   7     no warnings 'redefine';
   8     *DEBUG = sub () { 1 }
   9   }
  10 }
  11
  12 use Sub::Quote;
  13 use Web::Dispatch::Predicates;
  14 use Moo;
  15
  16 has _cache => (
  17   is => 'lazy', default => quote_sub q{ {} }
  18 );
  19
  20 sub diag { if (DEBUG) { warn $_[0] } }
  21
  22 sub _blam {
  23   my ($self, $error) = @_;
  24   my $hat = (' ' x (pos||0)).'^';
  25   die "Error parsing dispatch specification: ${error}\n
  26 ${_}
  27 ${hat} here\n";
  28 }
  29
  30 sub parse {
  31   my ($self, $spec) = @_;
  32   return $self->_cache->{$spec} ||= $self->_parse_spec($spec);
  33 }
  34
  35 sub _parse_spec {
  36   my ($self, $spec, $nested) = @_;
  37   for ($_[1]) {
  38     my @match;
  39     /^\G\s*/; # eat leading whitespace
  40     PARSE: { do {
  41       push @match, $self->_parse_spec_section($_)
  42         or $self->_blam("Unable to work out what the next section is");
  43       if (/\G\)/gc) {
  44         $self->_blam("Found closing ) with no opening (") unless $nested;
  45         last PARSE;
  46       }
  47       last PARSE if (pos == length);
  48       $match[-1] = $self->_parse_spec_combinator($_, $match[-1])
  49         or $self->_blam('No valid combinator - expected + or |');
  50     } until (pos == length) }; # accept trailing whitespace
  51     if ($nested and pos == length) {
  52       pos = $nested - 1;
  53       $self->_blam("No closing ) found for opening (");
  54     }
  55     return $match[0] if (@match == 1);
  56     return match_and(@match);
  57   }
  58 }
  59
  60 sub _parse_spec_combinator {
  61   my ($self, $spec, $match) = @_;
  62   for ($_[1]) {
  63
  64     /\G\+/gc and
  65       return $match;
  66
  67     /\G\|/gc and
  68       return do {
  69         my @match = $match;
  70         PARSE: { do {
  71           push @match, $self->_parse_spec_section($_)
  72             or $self->_blam("Unable to work out what the next section is");
  73           last PARSE if (pos == length);
  74           last PARSE unless /\G\|/gc; # give up when next thing isn't |
  75         } until (pos == length) }; # accept trailing whitespace
  76         return match_or(@match);
  77       };
  78   }
  79   return;
  80 }
  81
  82 sub _parse_spec_section {
  83   my ($self) = @_;
  84   for ($_[1]) {
  85
  86     # GET POST PUT HEAD ...
  87
  88     /\G([A-Z]+)/gc and
  89       return $self->_http_method_match($_, $1);
  90
  91     # /...
  92
  93     /\G(?=\/)/gc and
  94       return $self->_url_path_match($_);
  95
  96     # .* and .html
  97
  98     /\G\.(\*|\w+)/gc and
  99       return $self->_url_extension_match($_, $1);
 100
 101     # (...)
 102
 103     /\G\(/gc and
 104       return $self->_parse_spec($_, pos);
 105
 106     # !something
 107
 108     /\G!/gc and
 109       return do {
 110         my $match = $self->_parse_spec_section($_);
 111         return sub {
 112           return {} unless $match->(@_);
 113           return;
 114         };
 115       };
 116
 117     # ?<param spec>
 118     /\G\?/gc and
 119       return $self->_parse_param_handler($_, 'query');
 120
 121     # %<param spec>
 122     /\G\%/gc and
 123       return $self->_parse_param_handler($_, 'body');
 124   }
 125   return; # () will trigger the blam in our caller
 126 }
 127
 128 sub _http_method_match {
 129   my ($self, $str, $method) = @_;
 130   match_method($method);
 131 }
 132
 133 sub _url_path_match {
 134   my ($self) = @_;
 135   for ($_[1]) {
 136     my @path;
 137     my $full_path = '$';
 138     PATH: while (/\G\//gc) {
 139       /\G\.\.\./gc
 140         and do {
 141           $full_path = '';
 142           last PATH;
 143         };
 144       push @path, $self->_url_path_segment_match($_)
 145         or $self->_blam("Couldn't parse path match segment");
 146     }
 147     my $re = '^('.join('/','',@path).')'.($full_path ? '$' : '(/.*)$');
 148     $re = qr/$re/;
 149     if ($full_path) {
 150       return match_path($re);
 151     }
 152     return match_path_strip($re);
 153   }
 154   return;
 155 }
 156
 157 sub _url_path_segment_match {
 158   my ($self) = @_;
 159   for ($_[1]) {
 160     # trailing / -> require / on end of URL
 161     /\G(?:(?=[+|\)])|$)/gc and
 162       return '$';
 163     # word chars only -> exact path part match
 164     /\G(\w+)/gc and
 165       return "\Q$1";
 166     # ** -> capture unlimited path parts
 167     /\G\*\*/gc and
 168       return '(.*?[^/])';
 169     # * -> capture path part
 170     /\G\*/gc and
 171       return '([^/]+)';
 172   }
 173   return ();
 174 }
 175
 176 sub _url_extension_match {
 177   my ($self, $str, $extension) = @_;
 178   if ($extension eq '*') {
 179     sub {
 180       if ((my $tmp = shift->{PATH_INFO}) =~ s/\.(\w+)$//) {
 181         ({ PATH_INFO => $tmp }, $1);
 182       } else {
 183         ();
 184       }
 185     };
 186   } else {
 187     sub {
 188       if ((my $tmp = shift->{PATH_INFO}) =~ s/\.\Q${extension}\E$//) {
 189         ({ PATH_INFO => $tmp });
 190       } else {
 191         ();
 192       }
 193     };
 194   }
 195 }
 196
 197 sub _parse_param_handler {
 198   my ($self, $spec, $type) = @_;
 199
 200   require Web::Simple::ParamParser;
 201   my $unpacker = Web::Simple::ParamParser->can("get_unpacked_${type}_from");
 202
 203   for ($_[1]) {
 204     my (@required, @single, %multi, $star, $multistar, %positional, $have_kw);
 205     my $pos_idx = 0;
 206     PARAM: { do {
 207
 208       # ?:foo or ?@:foo
 209
 210       my $is_kw = /\G\:/gc;
 211
 212       # ?@foo or ?@*
 213
 214       my $multi = /\G\@/gc;
 215
 216       # @* or *
 217
 218       if (/\G\*/gc) {
 219
 220         $self->_blam("* is always named; no need to supply :") if $is_kw;
 221
 222         $multi ? ($multistar = 1) : ($star = 1);
 223
 224         $have_kw = 1;
 225
 226         if ($star && $multistar) {
 227           $self->_blam("Can't use * and \@* in the same parameter match");
 228         }
 229       } else {
 230
 231         # @foo= or foo= or @foo~ or foo~
 232
 233         /\G(\w+)/gc or $self->_blam('Expected parameter name');
 234
 235         my $name = $1;
 236
 237         # check for = or ~ on the end
 238
 239         /\G\=/gc
 240           ? push(@required, $name)
 241           : (/\G\~/gc or $self->_blam('Expected = or ~ after parameter name'));
 242
 243         # record the key in the right category depending on the multi (@) flag
 244
 245         $multi ? ($multi{$name} = 1) : (push @single, $name);
 246
 247         # record positional or keyword
 248
 249         $is_kw ? ($have_kw = 1) : ($positional{$name} = $pos_idx++);
 250       }
 251     } while (/\G\&/gc) }
 252
 253     return sub {
 254       my $raw = $unpacker->($_[0]);
 255       foreach my $name (@required) {
 256         return unless exists $raw->{$name};
 257       }
 258       my (%p, %done);
 259       my @p = (undef) x $pos_idx;
 260       foreach my $name (
 261         @single,
 262         ($star
 263           ? (grep { !exists $multi{$_} } keys %$raw)
 264           : ()
 265         )
 266       ) {
 267         if (exists $raw->{$name}) {
 268           if (exists $positional{$name}) {
 269             $p[$positional{$name}] = $raw->{$name}->[-1];
 270           } else {
 271             $p{$name} = $raw->{$name}->[-1];
 272           }
 273         }
 274         $done{$name} = 1;
 275       }
 276       foreach my $name (
 277         keys %multi,
 278         ($multistar
 279           ? (grep { !exists $done{$_} && !exists $multi{$_} } keys %$raw)
 280           : ()
 281         )
 282       ) {
 283         if (exists $positional{$name}) {
 284           $p[$positional{$name}] = $raw->{$name}||[];
 285         } else {
 286           $p{$name} = $raw->{$name}||[];
 287         }
 288       }
 289       $p[$pos_idx] = \%p if $have_kw;
 290       return ({}, @p);
 291     };
 292   }
 293 }
 294
 295 1;