lib/Web/Dispatch/Parser.pm

   1 package Web::Dispatch::Parser;
   2
   3 sub DEBUG () { 0 }
   4
   5 BEGIN {
   6   if ($ENV{WEB_DISPATCH_PARSER_DEBUG}) {
   7     no warnings 'redefine';
   8     *DEBUG = sub () { 1 }
   9   }
  10 }
  11
  12 use Sub::Quote;
  13 use Web::Dispatch::Predicates;
  14 use Moo;
  15
  16 has _cache => (
  17   is => 'lazy', default => quote_sub q{ {} }
  18 );
  19
  20 sub diag { if (DEBUG) { warn $_[0] } }
  21
  22 sub _blam {
  23   my ($self, $error) = @_;
  24   my $hat = (' ' x (pos||0)).'^';
  25   die "Error parsing dispatch specification: ${error}\n
  26 ${_}
  27 ${hat} here\n";
  28 }
  29
  30 sub parse {
  31   my ($self, $spec) = @_;
  32   $spec =~ s/\s+//g; # whitespace is not valid
  33   return $self->_cache->{$spec} ||= $self->_parse_spec($spec);
  34 }
  35
  36 sub _parse_spec {
  37   my ($self, $spec, $nested) = @_;
  38   for ($_[1]) {
  39     my @match;
  40     PARSE: { do {
  41       push @match, $self->_parse_spec_section($_)
  42         or $self->_blam("Unable to work out what the next section is");
  43       if (/\G\)/gc) {
  44         $self->_blam("Found closing ) with no opening (") unless $nested;
  45         last PARSE;
  46       }
  47       last PARSE if (pos == length);
  48       $match[-1] = $self->_parse_spec_combinator($_, $match[-1])
  49         or $self->_blam('No valid combinator - expected + or |');
  50     } until (pos == length) }; # accept trailing whitespace
  51     if ($nested and pos == length) {
  52       pos = $nested - 1;
  53       $self->_blam("No closing ) found for opening (");
  54     }
  55     return $match[0] if (@match == 1);
  56     return match_and(@match);
  57   }
  58 }
  59
  60 sub _parse_spec_combinator {
  61   my ($self, $spec, $match) = @_;
  62   for ($_[1]) {
  63
  64     /\G\+/gc and
  65       return $match;
  66
  67     /\G\|/gc and
  68       return do {
  69         my @match = $match;
  70         PARSE: { do {
  71           push @match, $self->_parse_spec_section($_)
  72             or $self->_blam("Unable to work out what the next section is");
  73           last PARSE if (pos == length);
  74           last PARSE unless /\G\|/gc; # give up when next thing isn't |
  75         } until (pos == length) }; # accept trailing whitespace
  76         return match_or(@match);
  77       };
  78   }
  79   return;
  80 }
  81
  82 sub _parse_spec_section {
  83   my ($self) = @_;
  84   for ($_[1]) {
  85
  86     # GET POST PUT HEAD ...
  87
  88     /\G([A-Z]+)/gc and
  89       return match_method($1);
  90
  91     # /...
  92
  93     /\G(?=\/)/gc and
  94       return $self->_url_path_match($_);
  95
  96     # .* and .html
  97
  98     /\G\.(\*|\w+)/gc and
  99       return match_extension($1);
 100
 101     # (...)
 102
 103     /\G\(/gc and
 104       return $self->_parse_spec($_, pos);
 105
 106     # !something
 107
 108     /\G!/gc and
 109       return match_not($self->_parse_spec_section($_));
 110
 111     # ?<param spec>
 112     /\G\?/gc and
 113       return $self->_parse_param_handler($_, 'query');
 114
 115     # %<param spec>
 116     /\G\%/gc and
 117       return $self->_parse_param_handler($_, 'body');
 118   }
 119   return; # () will trigger the blam in our caller
 120 }
 121
 122 sub _url_path_match {
 123   my ($self) = @_;
 124   for ($_[1]) {
 125     my @path;
 126     my $end = '';
 127     my $keep_dot;
 128     PATH: while (/\G\//gc) {
 129       /\G\.\.\./gc
 130         and do {
 131           $end = '(/.*)';
 132           last PATH;
 133         };
 134       push @path, $self->_url_path_segment_match($_)
 135         or $self->_blam("Couldn't parse path match segment");
 136       /\G\.\*/gc
 137         and do {
 138           $keep_dot = 1;
 139           last PATH;
 140         };
 141     }
 142     if (@path && !$end && !$keep_dot) {
 143       length and $_ .= '(?:\.\w+)?' for $path[-1];
 144     }
 145     my $re = '^('.join('/','',@path).')'.$end.'$';
 146     $re = qr/$re/;
 147     if ($end) {
 148       return match_path_strip($re);
 149     } else {
 150       return match_path($re);
 151     }
 152   }
 153   return;
 154 }
 155
 156 sub _url_path_segment_match {
 157   my ($self) = @_;
 158   for ($_[1]) {
 159     # trailing / -> require / on end of URL
 160     /\G(?:(?=[+|\)])|$)/gc and
 161       return '';
 162     # word chars only -> exact path part match
 163     /\G([\w\-]+)/gc and
 164       return "\Q$1";
 165     # ** -> capture unlimited path parts
 166     /\G\*\*/gc and
 167       return '(.*?[^/])';
 168     # * -> capture path part
 169     /\G\*/gc and
 170       return '([^/]+?)';
 171   }
 172   return ();
 173 }
 174
 175 sub _parse_param_handler {
 176   my ($self, $spec, $type) = @_;
 177
 178   for ($_[1]) {
 179     my (@required, @single, %multi, $star, $multistar, %positional, $have_kw);
 180     my %spec;
 181     my $pos_idx = 0;
 182     PARAM: { do {
 183
 184       # ?:foo or ?@:foo
 185
 186       my $is_kw = /\G\:/gc;
 187
 188       # ?@foo or ?@*
 189
 190       my $multi = /\G\@/gc;
 191
 192       # @* or *
 193
 194       if (/\G\*/gc) {
 195
 196         $self->_blam("* is always named; no need to supply :") if $is_kw;
 197
 198         if ($star) {
 199           $self->_blam("Can only use one * or \@* in a parameter match");
 200         }
 201
 202         $spec{star} = { multi => $multi };
 203       } else {
 204
 205         # @foo= or foo= or @foo~ or foo~
 206
 207         /\G(\w+)/gc or $self->_blam('Expected parameter name');
 208
 209         my $name = $1;
 210
 211         # check for = or ~ on the end
 212
 213         /\G\=/gc
 214           ? push(@{$spec{required}||=[]}, $name)
 215           : (/\G\~/gc or $self->_blam('Expected = or ~ after parameter name'));
 216
 217         # record positional or keyword
 218
 219         push @{$spec{$is_kw ? 'named' : 'positional'}||=[]},
 220           { name => $name, multi => $multi };
 221       }
 222     } while (/\G\&/gc) }
 223
 224     return Web::Dispatch::Predicates->can("match_${type}")->(\%spec);
 225   }
 226 }
 227
 228 1;