lib/Web/Dispatch/Parser.pm

   1 package Web::Dispatch::Parser;
   2
   3 sub DEBUG () { 0 }
   4
   5 BEGIN {
   6   if ($ENV{WEB_DISPATCH_PARSER_DEBUG}) {
   7     no warnings 'redefine';
   8     *DEBUG = sub () { 1 }
   9   }
  10 }
  11
  12 use Sub::Quote;
  13 use Web::Dispatch::Predicates;
  14 use Moo;
  15
  16 has _cache => (
  17   is => 'lazy', default => quote_sub q{ {} }
  18 );
  19
  20 sub diag { if (DEBUG) { warn $_[0] } }
  21
  22 sub _blam {
  23   my ($self, $error) = @_;
  24   my $hat = (' ' x (pos||0)).'^';
  25   die "Error parsing dispatch specification: ${error}\n
  26 ${_}
  27 ${hat} here\n";
  28 }
  29
  30 sub parse {
  31   my ($self, $spec) = @_;
  32   $spec =~ s/\s+//g; # whitespace is not valid
  33   return $self->_cache->{$spec} ||= $self->_parse_spec($spec);
  34 }
  35
  36 sub _parse_spec {
  37   my ($self, $spec, $nested) = @_;
  38   for ($_[1]) {
  39     my @match;
  40     PARSE: { do {
  41       push @match, $self->_parse_spec_section($_)
  42         or $self->_blam("Unable to work out what the next section is");
  43       if (/\G\)/gc) {
  44         $self->_blam("Found closing ) with no opening (") unless $nested;
  45         last PARSE;
  46       }
  47       last PARSE if (pos == length);
  48       $match[-1] = $self->_parse_spec_combinator($_, $match[-1])
  49         or $self->_blam('No valid combinator - expected + or |');
  50     } until (pos == length) }; # accept trailing whitespace
  51     if ($nested and pos == length) {
  52       pos = $nested - 1;
  53       $self->_blam("No closing ) found for opening (");
  54     }
  55     return $match[0] if (@match == 1);
  56     return match_and(@match);
  57   }
  58 }
  59
  60 sub _parse_spec_combinator {
  61   my ($self, $spec, $match) = @_;
  62   for ($_[1]) {
  63
  64     /\G\+/gc and
  65       return $match;
  66
  67     /\G\|/gc and
  68       return do {
  69         my @match = $match;
  70         PARSE: { do {
  71           push @match, $self->_parse_spec_section($_)
  72             or $self->_blam("Unable to work out what the next section is");
  73           last PARSE if (pos == length);
  74           last PARSE unless /\G\|/gc; # give up when next thing isn't |
  75         } until (pos == length) }; # accept trailing whitespace
  76         return match_or(@match);
  77       };
  78   }
  79   return;
  80 }
  81
  82 sub _parse_spec_section {
  83   my ($self) = @_;
  84   for ($_[1]) {
  85
  86     # GET POST PUT HEAD ...
  87
  88     /\G([A-Z]+)/gc and
  89       return match_method($1);
  90
  91     # /...
  92
  93     /\G(?=\/)/gc and
  94       return $self->_url_path_match($_);
  95
  96     # .* and .html
  97
  98     /\G\.(\*|\w+)/gc and
  99       return match_extension($1);
 100
 101     # (...)
 102
 103     /\G\(/gc and
 104       return $self->_parse_spec($_, pos);
 105
 106     # !something
 107
 108     /\G!/gc and
 109       return match_not($self->_parse_spec_section($_));
 110
 111     # ?<param spec>
 112     /\G\?/gc and
 113       return $self->_parse_param_handler($_, 'query');
 114
 115     # %<param spec>
 116     /\G\%/gc and
 117       return $self->_parse_param_handler($_, 'body');
 118   }
 119   return; # () will trigger the blam in our caller
 120 }
 121
 122 sub _url_path_match {
 123   my ($self) = @_;
 124   for ($_[1]) {
 125     my @path;
 126     my $end = '';
 127     PATH: while (/\G\//gc) {
 128       /\G\.\.\./gc
 129         and do {
 130           $end = '(/.*)';
 131           last PATH;
 132         };
 133       push @path, $self->_url_path_segment_match($_)
 134         or $self->_blam("Couldn't parse path match segment");
 135     }
 136     if (@path && !$end) {
 137       length and $_ .= '(?:\.\w+)?' for $path[-1];
 138     }
 139     my $re = '^('.join('/','',@path).')'.$end.'$';
 140     $re = qr/$re/;
 141     if ($end) {
 142       return match_path_strip($re);
 143     } else {
 144       return match_path($re);
 145     }
 146   }
 147   return;
 148 }
 149
 150 sub _url_path_segment_match {
 151   my ($self) = @_;
 152   for ($_[1]) {
 153     # trailing / -> require / on end of URL
 154     /\G(?:(?=[+|\)])|$)/gc and
 155       return '';
 156     # word chars only -> exact path part match
 157     /\G([\w\-]+)/gc and
 158       return "\Q$1";
 159     # ** -> capture unlimited path parts
 160     /\G\*\*/gc and
 161       return '(.*?[^/])';
 162     # * -> capture path part
 163     /\G\*/gc and
 164       return '([^/]+?)';
 165   }
 166   return ();
 167 }
 168
 169 sub _parse_param_handler {
 170   my ($self, $spec, $type) = @_;
 171
 172   require Web::Simple::ParamParser;
 173   my $unpacker = Web::Simple::ParamParser->can("get_unpacked_${type}_from");
 174
 175   for ($_[1]) {
 176     my (@required, @single, %multi, $star, $multistar, %positional, $have_kw);
 177     my $pos_idx = 0;
 178     PARAM: { do {
 179
 180       # ?:foo or ?@:foo
 181
 182       my $is_kw = /\G\:/gc;
 183
 184       # ?@foo or ?@*
 185
 186       my $multi = /\G\@/gc;
 187
 188       # @* or *
 189
 190       if (/\G\*/gc) {
 191
 192         $self->_blam("* is always named; no need to supply :") if $is_kw;
 193
 194         $multi ? ($multistar = 1) : ($star = 1);
 195
 196         $have_kw = 1;
 197
 198         if ($star && $multistar) {
 199           $self->_blam("Can't use * and \@* in the same parameter match");
 200         }
 201       } else {
 202
 203         # @foo= or foo= or @foo~ or foo~
 204
 205         /\G(\w+)/gc or $self->_blam('Expected parameter name');
 206
 207         my $name = $1;
 208
 209         # check for = or ~ on the end
 210
 211         /\G\=/gc
 212           ? push(@required, $name)
 213           : (/\G\~/gc or $self->_blam('Expected = or ~ after parameter name'));
 214
 215         # record the key in the right category depending on the multi (@) flag
 216
 217         $multi ? ($multi{$name} = 1) : (push @single, $name);
 218
 219         # record positional or keyword
 220
 221         $is_kw ? ($have_kw = 1) : ($positional{$name} = $pos_idx++);
 222       }
 223     } while (/\G\&/gc) }
 224
 225     return sub {
 226       my $raw = $unpacker->($_[0]);
 227       foreach my $name (@required) {
 228         return unless exists $raw->{$name};
 229       }
 230       my (%p, %done);
 231       my @p = (undef) x $pos_idx;
 232       foreach my $name (
 233         @single,
 234         ($star
 235           ? (grep { !exists $multi{$_} } keys %$raw)
 236           : ()
 237         )
 238       ) {
 239         if (exists $raw->{$name}) {
 240           if (exists $positional{$name}) {
 241             $p[$positional{$name}] = $raw->{$name}->[-1];
 242           } else {
 243             $p{$name} = $raw->{$name}->[-1];
 244           }
 245         }
 246         $done{$name} = 1;
 247       }
 248       foreach my $name (
 249         keys %multi,
 250         ($multistar
 251           ? (grep { !exists $done{$_} && !exists $multi{$_} } keys %$raw)
 252           : ()
 253         )
 254       ) {
 255         if (exists $positional{$name}) {
 256           $p[$positional{$name}] = $raw->{$name}||[];
 257         } else {
 258           $p{$name} = $raw->{$name}||[];
 259         }
 260       }
 261       $p[$pos_idx] = \%p if $have_kw;
 262       return ({}, @p);
 263     };
 264   }
 265 }
 266
 267 1;