lib/Web/Dispatch/Parser.pm

   1 package Web::Dispatch::Parser;
   2
   3 sub DEBUG () { 0 }
   4
   5 BEGIN {
   6   if ($ENV{WEB_DISPATCH_PARSER_DEBUG}) {
   7     no warnings 'redefine';
   8     *DEBUG = sub () { 1 }
   9   }
  10 }
  11
  12 use Sub::Quote;
  13 use Web::Dispatch::Predicates;
  14 use Moo;
  15
  16 has _cache => (
  17   is => 'lazy', default => quote_sub q{ {} }
  18 );
  19
  20 sub diag { if (DEBUG) { warn $_[0] } }
  21
  22 sub _blam {
  23   my ($self, $error) = @_;
  24   my $hat = (' ' x (pos||0)).'^';
  25   die "Error parsing dispatch specification: ${error}\n
  26 ${_}
  27 ${hat} here\n";
  28 }
  29
  30 sub parse {
  31   my ($self, $spec) = @_;
  32   $spec =~ s/\s+//g; # whitespace is not valid
  33   return $self->_cache->{$spec} ||= $self->_parse_spec($spec);
  34 }
  35
  36 sub _parse_spec {
  37   my ($self, $spec, $nested) = @_;
  38   for ($_[1]) {
  39     my @match;
  40     PARSE: { do {
  41       push @match, $self->_parse_spec_section($_)
  42         or $self->_blam("Unable to work out what the next section is");
  43       if (/\G\)/gc) {
  44         $self->_blam("Found closing ) with no opening (") unless $nested;
  45         last PARSE;
  46       }
  47       last PARSE if (pos == length);
  48       $match[-1] = $self->_parse_spec_combinator($_, $match[-1])
  49         or $self->_blam('No valid combinator - expected + or |');
  50     } until (pos == length) }; # accept trailing whitespace
  51     if ($nested and pos == length) {
  52       pos = $nested - 1;
  53       $self->_blam("No closing ) found for opening (");
  54     }
  55     return $match[0] if (@match == 1);
  56     return match_and(@match);
  57   }
  58 }
  59
  60 sub _parse_spec_combinator {
  61   my ($self, $spec, $match) = @_;
  62   for ($_[1]) {
  63
  64     /\G\+/gc and
  65       return $match;
  66
  67     /\G\|/gc and
  68       return do {
  69         my @match = $match;
  70         PARSE: { do {
  71           push @match, $self->_parse_spec_section($_)
  72             or $self->_blam("Unable to work out what the next section is");
  73           last PARSE if (pos == length);
  74           last PARSE unless /\G\|/gc; # give up when next thing isn't |
  75         } until (pos == length) }; # accept trailing whitespace
  76         return match_or(@match);
  77       };
  78   }
  79   return;
  80 }
  81
  82 sub _parse_spec_section {
  83   my ($self) = @_;
  84   for ($_[1]) {
  85
  86     # GET POST PUT HEAD ...
  87
  88     /\G([A-Z]+)/gc and
  89       return $self->_http_method_match($_, $1);
  90
  91     # /...
  92
  93     /\G(?=\/)/gc and
  94       return $self->_url_path_match($_);
  95
  96     # .* and .html
  97
  98     /\G\.(\*|\w+)/gc and
  99       return $self->_url_extension_match($_, $1);
 100
 101     # (...)
 102
 103     /\G\(/gc and
 104       return $self->_parse_spec($_, pos);
 105
 106     # !something
 107
 108     /\G!/gc and
 109       return do {
 110         my $match = $self->_parse_spec_section($_);
 111         return sub {
 112           return {} unless my @discard = $match->(@_);
 113           return;
 114         };
 115       };
 116
 117     # ?<param spec>
 118     /\G\?/gc and
 119       return $self->_parse_param_handler($_, 'query');
 120
 121     # %<param spec>
 122     /\G\%/gc and
 123       return $self->_parse_param_handler($_, 'body');
 124   }
 125   return; # () will trigger the blam in our caller
 126 }
 127
 128 sub _http_method_match {
 129   my ($self, $str, $method) = @_;
 130   match_method($method);
 131 }
 132
 133 sub _url_path_match {
 134   my ($self) = @_;
 135   for ($_[1]) {
 136     my @path;
 137     my $end = '';
 138     PATH: while (/\G\//gc) {
 139       /\G\.\.\./gc
 140         and do {
 141           $end = '(/.*)';
 142           last PATH;
 143         };
 144       push @path, $self->_url_path_segment_match($_)
 145         or $self->_blam("Couldn't parse path match segment");
 146     }
 147     if (@path && !$end) {
 148       length and $_ .= '(?:\.\w+)?' for $path[-1];
 149     }
 150     my $re = '^('.join('/','',@path).')'.$end.'$';
 151     $re = qr/$re/;
 152     if ($end) {
 153       return match_path_strip($re);
 154     } else {
 155       return match_path($re);
 156     }
 157   }
 158   return;
 159 }
 160
 161 sub _url_path_segment_match {
 162   my ($self) = @_;
 163   for ($_[1]) {
 164     # trailing / -> require / on end of URL
 165     /\G(?:(?=[+|\)])|$)/gc and
 166       return '';
 167     # word chars only -> exact path part match
 168     /\G([\w\-]+)/gc and
 169       return "\Q$1";
 170     # ** -> capture unlimited path parts
 171     /\G\*\*/gc and
 172       return '(.*?[^/])';
 173     # * -> capture path part
 174     /\G\*/gc and
 175       return '([^/]+?)';
 176   }
 177   return ();
 178 }
 179
 180 sub _url_extension_match {
 181   my ($self, $str, $extension) = @_;
 182   match_extension($extension);
 183 }
 184
 185 sub _parse_param_handler {
 186   my ($self, $spec, $type) = @_;
 187
 188   require Web::Simple::ParamParser;
 189   my $unpacker = Web::Simple::ParamParser->can("get_unpacked_${type}_from");
 190
 191   for ($_[1]) {
 192     my (@required, @single, %multi, $star, $multistar, %positional, $have_kw);
 193     my $pos_idx = 0;
 194     PARAM: { do {
 195
 196       # ?:foo or ?@:foo
 197
 198       my $is_kw = /\G\:/gc;
 199
 200       # ?@foo or ?@*
 201
 202       my $multi = /\G\@/gc;
 203
 204       # @* or *
 205
 206       if (/\G\*/gc) {
 207
 208         $self->_blam("* is always named; no need to supply :") if $is_kw;
 209
 210         $multi ? ($multistar = 1) : ($star = 1);
 211
 212         $have_kw = 1;
 213
 214         if ($star && $multistar) {
 215           $self->_blam("Can't use * and \@* in the same parameter match");
 216         }
 217       } else {
 218
 219         # @foo= or foo= or @foo~ or foo~
 220
 221         /\G(\w+)/gc or $self->_blam('Expected parameter name');
 222
 223         my $name = $1;
 224
 225         # check for = or ~ on the end
 226
 227         /\G\=/gc
 228           ? push(@required, $name)
 229           : (/\G\~/gc or $self->_blam('Expected = or ~ after parameter name'));
 230
 231         # record the key in the right category depending on the multi (@) flag
 232
 233         $multi ? ($multi{$name} = 1) : (push @single, $name);
 234
 235         # record positional or keyword
 236
 237         $is_kw ? ($have_kw = 1) : ($positional{$name} = $pos_idx++);
 238       }
 239     } while (/\G\&/gc) }
 240
 241     return sub {
 242       my $raw = $unpacker->($_[0]);
 243       foreach my $name (@required) {
 244         return unless exists $raw->{$name};
 245       }
 246       my (%p, %done);
 247       my @p = (undef) x $pos_idx;
 248       foreach my $name (
 249         @single,
 250         ($star
 251           ? (grep { !exists $multi{$_} } keys %$raw)
 252           : ()
 253         )
 254       ) {
 255         if (exists $raw->{$name}) {
 256           if (exists $positional{$name}) {
 257             $p[$positional{$name}] = $raw->{$name}->[-1];
 258           } else {
 259             $p{$name} = $raw->{$name}->[-1];
 260           }
 261         }
 262         $done{$name} = 1;
 263       }
 264       foreach my $name (
 265         keys %multi,
 266         ($multistar
 267           ? (grep { !exists $done{$_} && !exists $multi{$_} } keys %$raw)
 268           : ()
 269         )
 270       ) {
 271         if (exists $positional{$name}) {
 272           $p[$positional{$name}] = $raw->{$name}||[];
 273         } else {
 274           $p{$name} = $raw->{$name}||[];
 275         }
 276       }
 277       $p[$pos_idx] = \%p if $have_kw;
 278       return ({}, @p);
 279     };
 280   }
 281 }
 282
 283 1;