lib/Web/Dispatch/ParamParser.pm

   1 package Web::Dispatch::ParamParser;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 use Encode 'decode_utf8';
   7
   8 sub UNPACKED_QUERY () { __PACKAGE__.'.unpacked_query' }
   9 sub UNPACKED_BODY () { __PACKAGE__.'.unpacked_body' }
  10 sub UNPACKED_BODY_OBJECT () { __PACKAGE__.'.unpacked_body_object' }
  11 sub UNPACKED_UPLOADS () { __PACKAGE__.'.unpacked_uploads' }
  12 sub ORIG_ENV () { 'Web::Dispatch.original_env' }
  13
  14 sub get_unpacked_query_from {
  15   return ($_[0]->{+ORIG_ENV}||$_[0])->{+UNPACKED_QUERY} ||= do {
  16     _unpack_params($_[0]->{QUERY_STRING})
  17   };
  18 }
  19
  20 sub get_unpacked_body_from {
  21   return ($_[0]->{+ORIG_ENV}||$_[0])->{+UNPACKED_BODY} ||= do {
  22     my $ct = lc($_[0]->{CONTENT_TYPE}||'');
  23     if (!$_[0]->{CONTENT_LENGTH}) {
  24       {}
  25     } elsif (index($ct, 'application/x-www-form-urlencoded') >= 0) {
  26       $_[0]->{'psgi.input'}->read(my $buf, $_[0]->{CONTENT_LENGTH});
  27       _unpack_params($buf);
  28     } elsif (index($ct, 'multipart/form-data') >= 0) {
  29       my $p = get_unpacked_body_object_from($_[0])->param;
  30       # forcible arrayification (functional, $p does not belong to us,
  31       # do NOT replace this with a side-effect ridden "simpler" version)
  32       +{
  33         map +(ref($p->{$_}) eq 'ARRAY'
  34                ? ($_ => $p->{$_})
  35                : ($_ => [ $p->{$_} ])
  36              ), keys %$p
  37       };
  38     } else {
  39       {}
  40     }
  41   };
  42 }
  43
  44 sub get_unpacked_body_object_from {
  45   # we may have no object at all - so use a single element arrayref for ||=
  46   return (($_[0]->{+ORIG_ENV}||$_[0])->{+UNPACKED_BODY_OBJECT} ||= do {
  47     if (!$_[0]->{CONTENT_LENGTH}) {
  48       [ undef ]
  49     } elsif (index(lc($_[0]->{CONTENT_TYPE}||''),'multipart/form-data')==-1) {
  50       [ undef ]
  51     } else {
  52       [ _make_http_body($_[0]) ]
  53     }
  54   })->[0];
  55 }
  56
  57 sub get_unpacked_uploads_from {
  58   $_[0]->{+UNPACKED_UPLOADS} ||= do {
  59     require Web::Dispatch::Upload; require HTTP::Headers;
  60     my ($final, $reason) = (
  61       {}, "field %s exists with value %s but body was not multipart/form-data"
  62     );
  63     if (my $body = get_unpacked_body_object_from($_[0])) {
  64       my $u = $body->upload;
  65       $reason = "field %s exists with value %s but was not an upload";
  66       foreach my $k (keys %$u) {
  67         foreach my $v (ref($u->{$k}) eq 'ARRAY' ? @{$u->{$k}} : $u->{$k}) {
  68           push(@{$final->{$k}||=[]}, Web::Dispatch::Upload->new(
  69             %{$v},
  70             headers => HTTP::Headers->new($v->{headers})
  71           ));
  72         }
  73       }
  74     }
  75     my $b = get_unpacked_body_from($_[0]);
  76     foreach my $k (keys %$b) {
  77       next if $final->{$k};
  78       foreach my $v (@{$b->{$k}}) {
  79         next unless $v;
  80         push(@{$final->{$k}||=[]}, Web::Dispatch::NotAnUpload->new(
  81           filename => $v,
  82           reason => sprintf($reason, $k, $v)
  83         ));
  84       }
  85     }
  86     $final;
  87   };
  88 }
  89
  90 {
  91   # shamelessly stolen from HTTP::Body::UrlEncoded by Christian Hansen
  92
  93   my $DECODE = qr/%([0-9a-fA-F]{2})/;
  94
  95   my %hex_chr;
  96
  97   foreach my $num ( 0 .. 255 ) {
  98     my $h = sprintf "%02X", $num;
  99     $hex_chr{ lc $h } = $hex_chr{ uc $h } = chr $num;
 100   }
 101
 102   sub _unpack_params {
 103     my %unpack;
 104     (my $params = $_[0]) =~ s/\+/ /g;
 105     my ($name, $value);
 106     foreach my $pair (split(/[&;](?:\s+)?/, $params)) {
 107       next unless (($name, $value) = split(/=/, $pair, 2)) == 2;
 108
 109       s/$DECODE/$hex_chr{$1}/gs for ($name, $value);
 110       $_ = decode_utf8 $_ for ($name, $value);
 111
 112       push(@{$unpack{$name}||=[]}, $value);
 113     }
 114     \%unpack;
 115   }
 116 }
 117
 118 {
 119   # shamelessly stolen from Plack::Request by miyagawa
 120
 121   sub _make_http_body {
 122
 123     # Can't actually do this yet, since Plack::Request deletes the
 124     # header structure out of the uploads in its copy of the body.
 125     # I suspect I need to supply miyagawa with a failing test.
 126
 127     #if (my $plack_body = $_[0]->{'plack.request.http.body'}) {
 128     #  # Plack already constructed one; probably wasteful to do it again
 129     #  return $plack_body;
 130     #}
 131
 132     require HTTP::Body;
 133     my $body = HTTP::Body->new(@{$_[0]}{qw(CONTENT_TYPE CONTENT_LENGTH)});
 134     $body->cleanup(1);
 135     my $spin = 0;
 136     my $input = $_[0]->{'psgi.input'};
 137     my $cl = $_[0]->{CONTENT_LENGTH};
 138     while ($cl) {
 139       $input->read(my $chunk, $cl < 8192 ? $cl : 8192);
 140       my $read = length $chunk;
 141       $cl -= $read;
 142       $body->add($chunk);
 143
 144       if ($read == 0 && $spin++ > 2000) {
 145         require Carp;
 146         Carp::croak("Bad Content-Length: maybe client disconnect? ($cl bytes remaining)");
 147       }
 148     }
 149     return $body;
 150   }
 151 }
 152
 153 1;