lib/Web/Dispatch.pm

   1 package Web::Dispatch;
   2
   3 use Sub::Quote;
   4 use Scalar::Util qw(blessed);
   5
   6 sub MAGIC_MIDDLEWARE_KEY { __PACKAGE__.'.middleware' }
   7
   8 use Moo;
   9 use Web::Dispatch::Parser;
  10 use Web::Dispatch::Node;
  11
  12 with 'Web::Dispatch::ToApp';
  13
  14 has app => (is => 'ro', required => 1);
  15 has parser_class => (
  16   is => 'ro', default => quote_sub q{ 'Web::Dispatch::Parser' }
  17 );
  18 has node_class => (
  19   is => 'ro', default => quote_sub q{ 'Web::Dispatch::Node' }
  20 );
  21 has node_args => (is => 'ro', default => quote_sub q{ {} });
  22 has _parser => (is => 'lazy');
  23
  24 sub _build__parser {
  25   my ($self) = @_;
  26   $self->parser_class->new;
  27 }
  28
  29 sub call {
  30   my ($self, $env) = @_;
  31   $self->_dispatch($env, $self->app);
  32 }
  33
  34 sub _dispatch {
  35   my ($self, $env, @match) = @_;
  36   while (my $try = shift @match) {
  37
  38     return $try if ref($try) eq 'ARRAY';
  39     if (ref($try) eq 'HASH') {
  40       $env = { %$env, %$try };
  41       next;
  42     }
  43
  44     my @result = $self->_to_try($try, \@match)->($env, @match);
  45     next unless @result and defined($result[0]);
  46
  47     my $first = $result[0];
  48     my $dispatch = $self->_valid_dispatch( $first, \@result, \@match, $env );
  49     return $dispatch if $dispatch;
  50
  51     # make a copy so we don't screw with it assigning further up
  52     my $env = $env;
  53     unshift @match, sub { $self->_dispatch($env, @result) };
  54   }
  55
  56   return;
  57 }
  58
  59 sub _valid_dispatch {
  60   my ( $self, $first, $result, $match, $env ) = @_;
  61
  62   if ( ref($first) eq 'ARRAY' ) {
  63     return $self->_unpack_array_match( $first );
  64   }
  65   elsif ( blessed($first) && $first->isa('Plack::Middleware') ) {
  66     return $self->_prepare_middleware( $first, $result );
  67   }
  68   elsif ( ref($first) eq 'HASH' and $first->{+MAGIC_MIDDLEWARE_KEY} ) {
  69     return $self->_unwrap_middleware( $first, $match, $env );
  70   }
  71   elsif ( blessed($first) && !$first->can('to_app') ) {
  72     return $first;
  73   }
  74
  75   return;
  76 }
  77
  78 sub _unpack_array_match {
  79   my ( $self, $match ) = @_;
  80   return $match->[0] if @{$match} == 1 and ref($match->[0]) eq 'CODE';
  81   return $match;
  82 }
  83
  84 sub _prepare_middleware {
  85   my ( $self, $match, $results ) = @_;
  86   die "Multiple results but first one is a middleware ($match)"
  87     if @{$results} > 1;
  88   # middleware needs to uplevel exactly once to wrap the rest of the
  89   # level it was created for - next elsif unwraps it
  90   return { MAGIC_MIDDLEWARE_KEY, $match };
  91 }
  92
  93 sub _unwrap_middleware {
  94   my ( $self, $first, $match, $env ) = @_;
  95
  96   my $mw = $first->{+MAGIC_MIDDLEWARE_KEY};
  97
  98   $mw->app(sub { $self->_dispatch($_[0], @{$match}) });
  99
 100   return $mw->to_app->($env);
 101 }
 102
 103 sub _to_try {
 104   my ($self, $try, $more) = @_;
 105   if (ref($try) eq 'CODE') {
 106     if (defined(my $proto = prototype($try))) {
 107       $self->_construct_node(
 108         match => $self->_parser->parse($proto), run => $try
 109       )->to_app;
 110     } else {
 111       $try
 112     }
 113   } elsif (!ref($try) and ref($more->[0]) eq 'CODE') {
 114     $self->_construct_node(
 115       match => $self->_parser->parse($try), run => shift(@$more)
 116     )->to_app;
 117   } elsif (blessed($try) && $try->can('to_app')) {
 118     $try->to_app;
 119   } else {
 120     die "No idea how we got here with $try";
 121   }
 122 }
 123
 124 sub _construct_node {
 125   my ($self, %args) = @_;
 126   $self->node_class->new({ %{$self->node_args}, %args });
 127 }
 128
 129 1;