lib/Test/EOL.pm

   1 package Test::EOL;
   2 # ABSTRACT: Check the correct line endings in your project
   3
   4 use strict;
   5 use warnings;
   6
   7 use Test::Builder;
   8 use File::Spec;
   9 use File::Find;
  10 use Cwd qw/ cwd /;
  11
  12 use vars qw( $PERL $UNTAINT_PATTERN $PERL_PATTERN);
  13
  14 $PERL    = $^X || 'perl';
  15 $UNTAINT_PATTERN  = qr|^([-+@\w./:\\]+)$|;
  16 $PERL_PATTERN     = qr/^#!.*perl/;
  17
  18 my %file_find_arg = ($] <= 5.006) ? () : (
  19     untaint => 1,
  20     untaint_pattern => $UNTAINT_PATTERN,
  21     untaint_skip => 1,
  22 );
  23
  24 my $Test  = Test::Builder->new;
  25
  26 my $no_plan;
  27
  28 sub import {
  29     my $self   = shift;
  30     my $caller = caller;
  31     {
  32         no strict 'refs';
  33         *{$caller.'::eol_unix_ok'} = \&eol_unix_ok;
  34         *{$caller.'::all_perl_files_ok'} = \&all_perl_files_ok;
  35     }
  36     $Test->exported_to($caller);
  37
  38     if ($_[0] && $_[0] eq 'no_plan') {
  39         shift;
  40         $no_plan = 1;
  41     }
  42     $Test->plan(@_);
  43 }
  44
  45 sub _all_perl_files {
  46     my @all_files = _all_files(@_);
  47     return grep { _is_perl_module($_) || _is_perl_script($_) || _is_pod_file($_) } @all_files;
  48 }
  49
  50 sub _all_files {
  51     my @base_dirs = @_ ? @_ : cwd();
  52     my $options = pop(@base_dirs) if ref $base_dirs[-1] eq 'HASH';
  53     my @found;
  54     my $want_sub = sub {
  55         return if ($File::Find::dir =~ m![\\/]?CVS[\\/]|[\\/]?\.svn[\\/]!); # Filter out cvs or subversion dirs/
  56         return if ($File::Find::dir =~ m![\\/]?blib[\\/]libdoc$!); # Filter out pod doc in dist
  57         return if ($File::Find::dir =~ m![\\/]?blib[\\/]man\d$!); # Filter out pod doc in dist
  58         return if ($File::Find::dir =~ m![\\/]?inc!); # Filter out Module::Install stuff
  59         return if ($File::Find::name =~ m!Build$!i); # Filter out autogenerated Build script
  60         return unless (-f $File::Find::name && -r _);
  61         push @found, File::Spec->no_upwards( $File::Find::name );
  62     };
  63     my $find_arg = {
  64         %file_find_arg,
  65         wanted   => $want_sub,
  66         no_chdir => 1,
  67     };
  68     find( $find_arg, @base_dirs);
  69     return @found;
  70 }
  71
  72 # Formats various human invisible symbols
  73 # to similar visible ones.
  74 # Perhaps ^M or something like that
  75 # would be more appropriate?
  76
  77 sub _show_whitespace {
  78     my $string = shift;
  79     $string =~ s/\r/[\\r]/g;
  80     $string =~ s/\t/[\\t]/g;
  81     $string =~ s/ /[\\s]/g;
  82     return $string;
  83 }
  84
  85 # Format a line record for diagnostics.
  86
  87 sub _debug_line {
  88     my ( $options, $line ) = @_;
  89     $line->[2] =~ s/\n\z//g;
  90     return "line $line->[1]: $line->[0]" . (
  91       $options->{show_lines} ? qq{: } . _show_whitespace( $line->[2] )  : q{}
  92     );
  93 }
  94
  95 sub eol_unix_ok {
  96     my $file = shift;
  97     my $test_txt;
  98     $test_txt   = shift if !ref $_[0];
  99     $test_txt ||= "No incorrect line endings in '$file'";
 100     my $options = shift if ref $_[0] eq 'HASH';
 101     $options ||= {
 102         trailing_whitespace => 0,
 103         all_reasons => 0,
 104     };
 105     $file = _module_to_path($file);
 106
 107     open my $fh, $file or do { $Test->ok(0, $test_txt); $Test->diag("Could not open $file: $!"); return; };
 108     # Windows-- , default is :crlf, which hides \r\n  -_-
 109     binmode( $fh, ':raw' );
 110     my $line = 0;
 111     my @fails;
 112     while (<$fh>) {
 113         $line++;
 114         if ( !$options->{trailing_whitespace} && /(\r+)$/ ) {
 115           my $match = $1;
 116           push @fails, [ _show_whitespace( $match ) , $line , $_ ];
 117         }
 118         if (  $options->{trailing_whitespace} && /([ \t]*\r+|[ \t]+)$/ ) {
 119           my $match = $1;
 120           push @fails, [ _show_whitespace($match), $line , $_ ];
 121         }
 122         # Minor short-circuit for people who don't need the whole file scanned
 123         # once there's an err.
 124         last if( @fails > 0 && !$options->{all_reasons} );
 125     }
 126     if( @fails ){
 127        $Test->ok( 0, $test_txt . " on "  . _debug_line({ show_lines => 0 } , $fails[0]  )  );
 128        if ( $options->{all_reasons} || 1 ){
 129           $Test->diag( "  Problem Lines: ");
 130           for ( @fails ){
 131             $Test->diag(_debug_line({ show_lines => 1 } , $_ ) );
 132           }
 133        }
 134        return 0;
 135     }
 136     $Test->ok(1, $test_txt);
 137     return 1;
 138 }
 139 sub all_perl_files_ok {
 140     my $options = shift if ref $_[0] eq 'HASH';
 141     my @files = _all_perl_files( @_ );
 142     _make_plan();
 143     foreach my $file ( @files ) {
 144       eol_unix_ok($file, $options);
 145     }
 146 }
 147
 148 sub _is_perl_module {
 149     $_[0] =~ /\.pm$/i || $_[0] =~ /::/;
 150 }
 151
 152 sub _is_pod_file {
 153     $_[0] =~ /\.pod$/i;
 154 }
 155
 156 sub _is_perl_script {
 157     my $file = shift;
 158     return 1 if $file =~ /\.pl$/i;
 159     return 1 if $file =~ /\.t$/;
 160     open (my $fh, $file) or return;
 161     my $first = <$fh>;
 162     return 1 if defined $first && ($first =~ $PERL_PATTERN);
 163     return;
 164 }
 165
 166 sub _module_to_path {
 167     my $file = shift;
 168     return $file unless ($file =~ /::/);
 169     my @parts = split /::/, $file;
 170     my $module = File::Spec->catfile(@parts) . '.pm';
 171     foreach my $dir (@INC) {
 172         my $candidate = File::Spec->catfile($dir, $module);
 173         next unless (-e $candidate && -f _ && -r _);
 174         return $candidate;
 175     }
 176     return $file;
 177 }
 178
 179 sub _make_plan {
 180     return if $no_plan;
 181     unless ($Test->has_plan) {
 182         $Test->plan( 'no_plan' );
 183     }
 184     $Test->expected_tests;
 185 }
 186
 187 sub _untaint {
 188     my @untainted = map { ($_ =~ $UNTAINT_PATTERN) } @_;
 189     return wantarray ? @untainted : $untainted[0];
 190 }
 191
 192 1;
 193
 194 =head1 SYNOPSIS
 195
 196 C<Test::EOL> lets you check for the presence of trailing whitespace and/or
 197 windows line endings in your perl code. It reports its results in standard
 198 C<Test::Simple> fashion:
 199
 200   use Test::EOL tests => 1;
 201   eol_unix_ok( 'lib/Module.pm', 'Module is ^M free');
 202
 203 and to add checks for trailing whitespace:
 204
 205   use Test::EOL tests => 1;
 206   eol_unix_ok( 'lib/Module.pm', 'Module is ^M and trailing whitespace free', { trailing_whitespace => 1 });
 207
 208 Module authors can include the following in a t/eol.t and have C<Test::EOL>
 209 automatically find and check all perl files in a module distribution:
 210
 211   use Test::EOL;
 212   all_perl_files_ok();
 213
 214 or
 215
 216   use Test::EOL;
 217   all_perl_files_ok( @mydirs );
 218
 219 and if authors would like to check for trailing whitespace:
 220
 221   use Test::EOL;
 222   all_perl_files_ok({ trailing_whitespace => 1 });
 223
 224 or
 225
 226   use Test::EOL;
 227   all_perl_files_ok({ trailing_whitespace => 1 }, @mydirs );
 228
 229 or
 230
 231   use Test::More;
 232   use Test::EOL 'no_test';
 233   all_perl_files_ok();
 234   done_testing;
 235
 236 =head1 DESCRIPTION
 237
 238 This module scans your project/distribution for any perl files (scripts,
 239 modules, etc) for the presence of windows line endings.
 240
 241 =head1 EXPORT
 242
 243 A list of functions that can be exported.  You can delete this section
 244 if you don't export anything, such as for a purely object-oriented module.
 245
 246 =func all_perl_files_ok
 247
 248   all_perl_files_ok( [ \%options ], [ @directories ] )
 249
 250 Applies C<eol_unix_ok()> to all perl files found in C<@directories> (and sub
 251 directories). If no <@directories> is given, the starting point is the current
 252 working directory, as tests are usually run from the top directory in a typical
 253 CPAN distribution. A perl file is *.pl or *.pm or *.pod or *.t or a file starting
 254 with C<#!...perl>
 255
 256 Valid C<\%options> currently are:
 257
 258 =over
 259
 260 =item * trailing_whitespace
 261
 262 By default Test::EOL only looks for Windows (CR/LF) line-endings. Set this
 263 to true to raise errors if any kind of trailing whitespace is present in
 264 the file.
 265
 266 =item * all_reasons
 267
 268 Normally Test::EOL reports only the first error in every file (given that
 269 a text file originated on Windows will fail every single line). Set this
 270 a true value to register a test failure for every line with an error.
 271
 272 =back
 273
 274 If the test plan is defined:
 275
 276   use Test::EOL tests => 3;
 277   all_perl_files_ok();
 278
 279 the total number of files tested must be specified.
 280
 281 =func eol_unix_ok
 282
 283   eol_unix_ok ( $file [, $text] [, \%options ] )
 284
 285 Run a unix EOL check on C<$file>. For a module, the path (lib/My/Module.pm) or the
 286 name (My::Module) can be both used. C<$text> is the diagnostic label emited after
 287 the C<ok>/C<not ok> TAP output. C<\%options> takes the same values as described in
 288 L</all_perl_files_ok>.
 289
 290 =head1 ACKNOWLEDGEMENTS
 291
 292 Shamelessly ripped off from L<Test::NoTabs>.
 293
 294 =head1 SEE ALSO
 295
 296 L<Test::More>, L<Test::Pod>. L<Test::Distribution>, L<Test:NoWarnings>,
 297 L<Test::NoTabs>, L<Module::Install::AuthorTests>.
 298
 299 =cut