lib/Test/EOL.pm

   1 package Test::EOL;
   2 # ABSTRACT: Check the correct line endings in your project
   3
   4 use strict;
   5 use warnings;
   6
   7 use Test::Builder;
   8 use File::Spec;
   9 use File::Find;
  10 use Cwd qw/ cwd /;
  11
  12 use vars qw( $PERL $UNTAINT_PATTERN $PERL_PATTERN);
  13
  14 $PERL    = $^X || 'perl';
  15 $UNTAINT_PATTERN  = qr|^([-+@\w./:\\]+)$|;
  16 $PERL_PATTERN     = qr/^#!.*perl/;
  17
  18 my %file_find_arg = ($] <= 5.006) ? () : (
  19     untaint => 1,
  20     untaint_pattern => $UNTAINT_PATTERN,
  21     untaint_skip => 1,
  22 );
  23
  24 my $Test  = Test::Builder->new;
  25 my $updir = File::Spec->updir();
  26
  27 sub import {
  28     my $self   = shift;
  29     my $caller = caller;
  30     {
  31         no strict 'refs';
  32         *{$caller.'::eol_unix_ok'} = \&eol_unix_ok;
  33         *{$caller.'::all_perl_files_ok'} = \&all_perl_files_ok;
  34     }
  35     $Test->exported_to($caller);
  36     $Test->plan(@_);
  37 }
  38
  39 sub _all_perl_files {
  40     my @all_files = _all_files(@_);
  41     return grep { _is_perl_module($_) || _is_perl_script($_) } @all_files;
  42 }
  43
  44 sub _all_files {
  45     my @base_dirs = @_ ? @_ : cwd();
  46     my $options = pop(@base_dirs) if ref $base_dirs[-1] eq 'HASH';
  47     my @found;
  48     my $want_sub = sub {
  49         return if ($File::Find::dir =~ m![\\/]?CVS[\\/]|[\\/]?\.svn[\\/]!); # Filter out cvs or subversion dirs/
  50         return if ($File::Find::dir =~ m![\\/]?blib[\\/]libdoc$!); # Filter out pod doc in dist
  51         return if ($File::Find::dir =~ m![\\/]?blib[\\/]man\d$!); # Filter out pod doc in dist
  52         return if ($File::Find::dir =~ m![\\/]?inc!); # Filter out Module::Install stuff
  53         return if ($File::Find::name =~ m!Build$!i); # Filter out autogenerated Build script
  54         return unless (-f $File::Find::name && -r _);
  55         push @found, File::Spec->no_upwards( $File::Find::name );
  56     };
  57     my $find_arg = {
  58         %file_find_arg,
  59         wanted   => $want_sub,
  60         no_chdir => 1,
  61     };
  62     find( $find_arg, @base_dirs);
  63     return @found;
  64 }
  65
  66 # Formats various human invisible symbols
  67 # to similar visible ones.
  68 # Perhaps ^M or something like that
  69 # would be more appropriate?
  70
  71 sub _show_whitespace {
  72     my $string = shift;
  73     $string =~ s/\r/[\\r]/g;
  74     $string =~ s/\t/[\\t]/g;
  75     $string =~ s/ /[\\s]/g;
  76     return $string;
  77 }
  78
  79 # Format a line record for diagnostics.
  80
  81 sub _debug_line {
  82     my ( $options, $line ) = @_;
  83     $line->[2] =~ s/\n\z//g;
  84     return "line $line->[1]: $line->[0] " . (
  85       $options->{show_lines} ? qq{: } . _show_whitespace( $line->[2] )  : q{}
  86     );
  87 }
  88
  89 sub eol_unix_ok {
  90     my $file = shift;
  91     my $test_txt;
  92     $test_txt   = shift if !ref $_[0];
  93     $test_txt ||= "No incorrect line endings in '$file'";
  94     my $options = shift if ref $_[0] eq 'HASH';
  95     $options ||= {
  96         trailing_whitespace => 0,
  97         all_reasons => 0,
  98     };
  99     $file = _module_to_path($file);
 100
 101     open my $fh, $file or do { $Test->ok(0, $test_txt); $Test->diag("Could not open $file: $!"); return; };
 102     # Windows-- , default is :crlf, which hides \r\n  -_-
 103     binmode( $fh, ':raw' );
 104     my $line = 0;
 105     my @fails;
 106     while (<$fh>) {
 107         $line++;
 108         if ( !$options->{trailing_whitespace} && /(\r+)$/ ) {
 109           my $match = $1;
 110           push @fails, [ _show_whitespace( $match ) , $line , $_ ];
 111         }
 112         if (  $options->{trailing_whitespace} && /([ \t]*\r+|[ \t]+)$/ ) {
 113           my $match = $1;
 114           push @fails, [ _show_whitespace($match), $line , $_ ];
 115         }
 116         # Minor short-circuit for people who don't need the whole file scanned
 117         # once there's an err.
 118         last if( @fails > 0 && !$options->{all_reasons} );
 119     }
 120     if( @fails ){
 121        $Test->ok( 0, $test_txt . " on "  . _debug_line({ show_lines => 0 } , $fails[0]  )  );
 122        if ( $options->{all_reasons} || 1 ){
 123           $Test->diag( "  Problem Lines: ");
 124           for ( @fails ){
 125             $Test->diag(_debug_line({ show_lines => 1 } , $_ ) );
 126           }
 127        }
 128        return 0;
 129     }
 130     $Test->ok(1, $test_txt);
 131     return 1;
 132 }
 133 sub all_perl_files_ok {
 134     my $options = shift if ref $_[0] eq 'HASH';
 135     my @files = _all_perl_files( @_ );
 136     _make_plan();
 137     foreach my $file ( @files ) {
 138       eol_unix_ok($file, $options);
 139     }
 140 }
 141
 142 sub _is_perl_module {
 143     $_[0] =~ /\.pm$/i || $_[0] =~ /::/;
 144 }
 145
 146 sub _is_perl_script {
 147     my $file = shift;
 148     return 1 if $file =~ /\.pl$/i;
 149     return 1 if $file =~ /\.t$/;
 150     open (my $fh, $file) or return;
 151     my $first = <$fh>;
 152     return 1 if defined $first && ($first =~ $PERL_PATTERN);
 153     return;
 154 }
 155
 156 sub _module_to_path {
 157     my $file = shift;
 158     return $file unless ($file =~ /::/);
 159     my @parts = split /::/, $file;
 160     my $module = File::Spec->catfile(@parts) . '.pm';
 161     foreach my $dir (@INC) {
 162         my $candidate = File::Spec->catfile($dir, $module);
 163         next unless (-e $candidate && -f _ && -r _);
 164         return $candidate;
 165     }
 166     return $file;
 167 }
 168
 169 sub _make_plan {
 170     unless ($Test->has_plan) {
 171         $Test->plan( 'no_plan' );
 172     }
 173     $Test->expected_tests;
 174 }
 175
 176 sub _untaint {
 177     my @untainted = map { ($_ =~ $UNTAINT_PATTERN) } @_;
 178     return wantarray ? @untainted : $untainted[0];
 179 }
 180
 181 1;
 182
 183 =head1 SYNOPSIS
 184
 185 C<Test::EOL> lets you check for the presence of trailing whitespace and/or
 186 windows line endings in your perl code. It reports its results in standard
 187 C<Test::Simple> fashion:
 188
 189   use Test::EOL tests => 1;
 190   eol_unix_ok( 'lib/Module.pm', 'Module is ^M free');
 191
 192 and to add checks for trailing whitespace:
 193
 194   use Test::EOL tests => 1;
 195   eol_unix_ok( 'lib/Module.pm', 'Module is ^M and trailing whitespace free', { trailing_whitespace => 1 });
 196
 197 Module authors can include the following in a t/eol.t and have C<Test::EOL>
 198 automatically find and check all perl files in a module distribution:
 199
 200   use Test::EOL;
 201   all_perl_files_ok();
 202
 203 or
 204
 205   use Test::EOL;
 206   all_perl_files_ok( @mydirs );
 207
 208 and if authors would like to check for trailing whitespace:
 209
 210   use Test::EOL;
 211   all_perl_files_ok({ trailing_whitespace => 1 });
 212
 213 or
 214
 215   use Test::EOL;
 216   all_perl_files_ok({ trailing_whitespace => 1 }, @mydirs );
 217
 218 =head1 DESCRIPTION
 219
 220 This module scans your project/distribution for any perl files (scripts,
 221 modules, etc) for the presence of windows line endings.
 222
 223 =head1 EXPORT
 224
 225 A list of functions that can be exported.  You can delete this section
 226 if you don't export anything, such as for a purely object-oriented module.
 227
 228 =func all_perl_files_ok
 229
 230   all_perl_files_ok( [ \%options ], [ @directories ] )
 231
 232 Applies C<eol_unix_ok()> to all perl files found in C<@directories> (and sub
 233 directories). If no <@directories> is given, the starting point is one level
 234 above the current running script, that should cover all the files of a typical
 235 CPAN distribution. A perl file is *.pl or *.pm or *.t or a file starting
 236 with C<#!...perl>
 237
 238 Valid C<\%options> currently are:
 239
 240 =over
 241
 242 =item * trailing_whitespace
 243
 244 By default Test::EOL only looks for Windows (CR/LF) line-endings. Set this
 245 to true to raise errors if any kind of trailing whitespace is present in
 246 the file.
 247
 248 =item * all_reasons
 249
 250 Normally Test::EOL reports only the first error in every file (given that
 251 a text file originated on Windows will fail every single line). Set this
 252 a true value to register a test failure for every line with an error.
 253
 254 =back
 255
 256 If the test plan is defined:
 257
 258   use Test::EOL tests => 3;
 259   all_perl_files_ok();
 260
 261 the total number of files tested must be specified.
 262
 263 =func eol_unix_ok
 264
 265   eol_unix_ok ( $file [, $text] [, \%options ] )
 266
 267 Run a unix EOL check on C<$file>. For a module, the path (lib/My/Module.pm) or the
 268 name (My::Module) can be both used. C<$text> is the diagnostic label emited after
 269 the C<ok>/C<not ok> TAP output. C<\%options> takes the same values as described in
 270 L</all_perl_files_ok>.
 271
 272 =head1 ACKNOWLEDGEMENTS
 273
 274 Shamelessly ripped off from L<Test::NoTabs>.
 275
 276 =head1 SEE ALSO
 277
 278 L<Test::More>, L<Test::Pod>. L<Test::Distribution>, L<Test:NoWarnings>,
 279 L<Test::NoTabs>, L<Module::Install::AuthorTests>.
 280
 281 =cut