lib/HTTP/Request/AsCGI.pm

   1 package HTTP::Request::AsCGI;
   2 # ABSTRACT: Set up a CGI environment from an HTTP::Request
   3 use strict;
   4 use warnings;
   5 use bytes;
   6 use base 'Class::Accessor::Fast';
   7
   8 our $VERSION = '0.9';
   9
  10 use Carp;
  11 use HTTP::Response;
  12 use IO::Handle;
  13 use IO::File;
  14 use URI ();
  15 use URI::Escape ();
  16
  17 __PACKAGE__->mk_accessors(qw[ environment request stdin stdout stderr ]);
  18
  19 # old typo
  20 =begin Pod::Coverage
  21
  22   enviroment
  23
  24 =end Pod::Coverage
  25
  26 =cut
  27
  28 *enviroment = \&environment;
  29
  30 my %reserved = map { sprintf('%02x', ord($_)) => 1 } split //, $URI::reserved;
  31 sub _uri_safe_unescape {
  32     my ($s) = @_;
  33     $s =~ s/%([a-fA-F0-9]{2})/$reserved{lc($1)} ? "%$1" : pack('C', hex($1))/ge;
  34     $s
  35 }
  36
  37 sub new {
  38     my $class   = shift;
  39     my $request = shift;
  40
  41     unless ( @_ % 2 == 0 && eval { $request->isa('HTTP::Request') } ) {
  42         croak(qq/usage: $class->new( \$request [, key => value] )/);
  43     }
  44
  45     my $self = $class->SUPER::new( { restored => 0, setuped => 0 } );
  46     $self->request($request);
  47     $self->stdin( IO::File->new_tmpfile );
  48     $self->stdout( IO::File->new_tmpfile );
  49
  50     my $host = $request->header('Host');
  51     my $uri  = $request->uri->clone;
  52     $uri->scheme('http')    unless $uri->scheme;
  53     $uri->host('localhost') unless $uri->host;
  54     $uri->port(80)          unless $uri->port;
  55     $uri->host_port($host)  unless !$host || ( $host eq $uri->host_port );
  56
  57     $uri = $uri->canonical;
  58
  59     my $environment = {
  60         GATEWAY_INTERFACE => 'CGI/1.1',
  61         HTTP_HOST         => $uri->host_port,
  62         HTTPS             => ( $uri->scheme eq 'https' ) ? 'ON' : 'OFF',  # not in RFC 3875
  63         PATH_INFO         => $uri->path,
  64         QUERY_STRING      => $uri->query || '',
  65         SCRIPT_NAME       => '/',
  66         SERVER_NAME       => $uri->host,
  67         SERVER_PORT       => $uri->port,
  68         SERVER_PROTOCOL   => $request->protocol || 'HTTP/1.1',
  69         SERVER_SOFTWARE   => "HTTP-Request-AsCGI/$VERSION",
  70         REMOTE_ADDR       => '127.0.0.1',
  71         REMOTE_HOST       => 'localhost',
  72         REMOTE_PORT       => int( rand(64000) + 1000 ),                   # not in RFC 3875
  73         REQUEST_URI       => $uri->path_query,                            # not in RFC 3875
  74         REQUEST_METHOD    => $request->method,
  75         @_
  76     };
  77
  78     $environment->{PATH_INFO} = _uri_safe_unescape($environment->{PATH_INFO});
  79
  80     foreach my $field ( $request->headers->header_field_names ) {
  81
  82         my $key = uc("HTTP_$field");
  83         $key =~ tr/-/_/;
  84         $key =~ s/^HTTP_// if $field =~ /^Content-(Length|Type)$/;
  85
  86         unless ( exists $environment->{$key} ) {
  87             $environment->{$key} = $request->headers->header($field);
  88         }
  89     }
  90
  91     unless ( $environment->{SCRIPT_NAME} eq '/' && $environment->{PATH_INFO} ) {
  92         $environment->{PATH_INFO} =~ s/^\Q$environment->{SCRIPT_NAME}\E/\//;
  93         $environment->{PATH_INFO} =~ s/^\/+/\//;
  94     }
  95
  96     $self->environment($environment);
  97
  98     return $self;
  99 }
 100
 101 sub setup {
 102     my $self = shift;
 103
 104     $self->{restore}->{environment} = {%ENV};
 105
 106     binmode( $self->stdin );
 107
 108     if ( $self->request->content_length ) {
 109
 110         $self->stdin->print($self->request->content)
 111           or croak("Can't write request content to stdin handle: $!");
 112
 113         $self->stdin->seek(0, SEEK_SET)
 114           or croak("Can't seek stdin handle: $!");
 115
 116         $self->stdin->flush
 117           or croak("Can't flush stdin handle: $!");
 118     }
 119
 120     open( $self->{restore}->{stdin}, '<&'. STDIN->fileno )
 121       or croak("Can't dup stdin: $!");
 122
 123     open( STDIN, '<&='. $self->stdin->fileno )
 124       or croak("Can't open stdin: $!");
 125
 126     binmode( STDIN );
 127
 128     if ( $self->stdout ) {
 129
 130         open( $self->{restore}->{stdout}, '>&'. STDOUT->fileno )
 131           or croak("Can't dup stdout: $!");
 132
 133         open( STDOUT, '>&='. $self->stdout->fileno )
 134           or croak("Can't open stdout: $!");
 135
 136         binmode( $self->stdout );
 137         binmode( STDOUT);
 138     }
 139
 140     if ( $self->stderr ) {
 141
 142         open( $self->{restore}->{stderr}, '>&'. STDERR->fileno )
 143           or croak("Can't dup stderr: $!");
 144
 145         open( STDERR, '>&='. $self->stderr->fileno )
 146           or croak("Can't open stderr: $!");
 147
 148         binmode( $self->stderr );
 149         binmode( STDERR );
 150     }
 151
 152     {
 153         no warnings 'uninitialized';
 154         %ENV = %{ $self->environment };
 155     }
 156
 157     if ( $INC{'CGI.pm'} ) {
 158         CGI::initialize_globals();
 159     }
 160
 161     $self->{setuped}++;
 162
 163     return $self;
 164 }
 165
 166 sub response {
 167     my ( $self, $callback ) = @_;
 168
 169     return undef unless $self->stdout;
 170
 171     seek( $self->stdout, 0, SEEK_SET )
 172       or croak("Can't seek stdout handle: $!");
 173
 174     my $headers;
 175     while ( my $line = $self->stdout->getline ) {
 176         $headers .= $line;
 177         last if $headers =~ /\x0d?\x0a\x0d?\x0a$/;
 178     }
 179
 180     unless ( defined $headers ) {
 181         $headers = "HTTP/1.1 500 Internal Server Error\x0d\x0a";
 182     }
 183
 184     unless ( $headers =~ /^HTTP/ ) {
 185         $headers = "HTTP/1.1 200 OK\x0d\x0a" . $headers;
 186     }
 187
 188     my $response = HTTP::Response->parse($headers);
 189     $response->date( time() ) unless $response->date;
 190
 191     my $message = $response->message;
 192     my $status  = $response->header('Status');
 193
 194     if ( $message && $message =~ /^(.+)\x0d$/ ) {
 195         $response->message($1);
 196     }
 197
 198     if ( $status && $status =~ /^(\d\d\d)\s?(.+)?$/ ) {
 199
 200         my $code    = $1;
 201         my $message = $2 || HTTP::Status::status_message($code);
 202
 203         $response->code($code);
 204         $response->message($message);
 205     }
 206
 207     my $length = ( stat( $self->stdout ) )[7] - tell( $self->stdout );
 208
 209     if ( $response->code == 500 && !$length ) {
 210
 211         $response->content( $response->error_as_HTML );
 212         $response->content_type('text/html');
 213
 214         return $response;
 215     }
 216
 217     if ($callback) {
 218
 219         my $handle = $self->stdout;
 220
 221         $response->content( sub {
 222
 223             if ( $handle->read( my $buffer, 4096 ) ) {
 224                 return $buffer;
 225             }
 226
 227             return undef;
 228         });
 229     }
 230     else {
 231
 232         my $length = 0;
 233
 234         while ( $self->stdout->read( my $buffer, 4096 ) ) {
 235             $length += length($buffer);
 236             $response->add_content($buffer);
 237         }
 238
 239         if ( $length && !$response->content_length ) {
 240             $response->content_length($length);
 241         }
 242     }
 243
 244     return $response;
 245 }
 246
 247 sub restore {
 248     my $self = shift;
 249
 250     {
 251         no warnings 'uninitialized';
 252         %ENV = %{ $self->{restore}->{environment} };
 253     }
 254
 255     open( STDIN, '<&'. fileno($self->{restore}->{stdin}) )
 256       or croak("Can't restore stdin: $!");
 257
 258     sysseek( $self->stdin, 0, SEEK_SET )
 259       or croak("Can't seek stdin: $!");
 260
 261     if ( $self->{restore}->{stdout} ) {
 262
 263         STDOUT->flush
 264           or croak("Can't flush stdout: $!");
 265
 266         open( STDOUT, '>&'. fileno($self->{restore}->{stdout}) )
 267           or croak("Can't restore stdout: $!");
 268
 269         sysseek( $self->stdout, 0, SEEK_SET )
 270           or croak("Can't seek stdout: $!");
 271     }
 272
 273     if ( $self->{restore}->{stderr} ) {
 274
 275         STDERR->flush
 276           or croak("Can't flush stderr: $!");
 277
 278         open( STDERR, '>&'. fileno($self->{restore}->{stderr}) )
 279           or croak("Can't restore stderr: $!");
 280
 281         sysseek( $self->stderr, 0, SEEK_SET )
 282           or croak("Can't seek stderr: $!");
 283     }
 284
 285     $self->{restored}++;
 286
 287     return $self;
 288 }
 289
 290 sub DESTROY {
 291     my $self = shift;
 292     $self->restore if $self->{setuped} && !$self->{restored};
 293 }
 294
 295 1;
 296
 297 __END__
 298
 299 =head1 SYNOPSIS
 300
 301     use CGI;
 302     use HTTP::Request;
 303     use HTTP::Request::AsCGI;
 304
 305     my $request = HTTP::Request->new( GET => 'http://www.host.com/' );
 306     my $stdout;
 307
 308     {
 309         my $c = HTTP::Request::AsCGI->new($request)->setup;
 310         my $q = CGI->new;
 311
 312         print $q->header,
 313               $q->start_html('Hello World'),
 314               $q->h1('Hello World'),
 315               $q->end_html;
 316
 317         $stdout = $c->stdout;
 318
 319         # environment and descriptors will automatically be restored
 320         # when $c is destructed.
 321     }
 322
 323     while ( my $line = $stdout->getline ) {
 324         print $line;
 325     }
 326
 327 =head1 DESCRIPTION
 328
 329 Provides a convenient way of setting up an CGI environment from an HTTP::Request.
 330
 331 =head1 METHODS
 332
 333 =over 4
 334
 335 =item new ( $request [, key => value ] )
 336
 337 Constructor.  The first argument must be a instance of HTTP::Request, followed
 338 by optional pairs of environment key and value.
 339
 340 =item environment
 341
 342 Returns a hashref containing the environment that will be used in setup.
 343 Changing the hashref after setup has been called will have no effect.
 344
 345 =item setup
 346
 347 Sets up the environment and descriptors.
 348
 349 =item restore
 350
 351 Restores the environment and descriptors. Can only be called after setup.
 352
 353 =item request
 354
 355 Returns the request given to constructor.
 356
 357 =item response
 358
 359 Returns a HTTP::Response. Can only be called after restore.
 360
 361 =item stdin
 362
 363 Accessor for handle that will be used for STDIN, must be a real seekable
 364 handle with an file descriptor. Defaults to a tempoary IO::File instance.
 365
 366 =item stdout
 367
 368 Accessor for handle that will be used for STDOUT, must be a real seekable
 369 handle with an file descriptor. Defaults to a tempoary IO::File instance.
 370
 371 =item stderr
 372
 373 Accessor for handle that will be used for STDERR, must be a real seekable
 374 handle with an file descriptor.
 375
 376 =back
 377
 378 =head1 SEE ALSO
 379
 380 =over 4
 381
 382 =item examples directory in this distribution.
 383
 384 =item L<WWW::Mechanize::CGI>
 385
 386 =item L<Test::WWW::Mechanize::CGI>
 387
 388 =back
 389
 390 =head1 THANKS TO
 391
 392 Thomas L. Shinnick for his valuable win32 testing.
 393
 394 =cut