lib/HTTP/Request/AsCGI.pm

   1 package HTTP::Request::AsCGI;
   2 # ABSTRACT: Set up a CGI environment from an HTTP::Request
   3 use strict;
   4 use warnings;
   5 use bytes;
   6 use base 'Class::Accessor::Fast';
   7
   8 use Carp;
   9 use HTTP::Response;
  10 use IO::Handle;
  11 use IO::File;
  12
  13 __PACKAGE__->mk_accessors(qw[ environment request stdin stdout stderr ]);
  14
  15 # old typo
  16 =begin Pod::Coverage
  17
  18   enviroment
  19
  20 =end Pod::Coverage
  21
  22 =cut
  23
  24 *enviroment = \&environment;
  25
  26 sub new {
  27     my $class   = shift;
  28     my $request = shift;
  29
  30     unless ( @_ % 2 == 0 && eval { $request->isa('HTTP::Request') } ) {
  31         croak(qq/usage: $class->new( \$request [, key => value] )/);
  32     }
  33
  34     my $self = $class->SUPER::new( { restored => 0, setuped => 0 } );
  35     $self->request($request);
  36     $self->stdin( IO::File->new_tmpfile );
  37     $self->stdout( IO::File->new_tmpfile );
  38
  39     my $host = $request->header('Host');
  40     my $uri  = $request->uri->clone;
  41     $uri->scheme('http')    unless $uri->scheme;
  42     $uri->host('localhost') unless $uri->host;
  43     $uri->port(80)          unless $uri->port;
  44     $uri->host_port($host)  unless !$host || ( $host eq $uri->host_port );
  45
  46     $uri = $uri->canonical;
  47
  48     my $environment = {
  49         GATEWAY_INTERFACE => 'CGI/1.1',
  50         HTTP_HOST         => $uri->host_port,
  51         HTTPS             => ( $uri->scheme eq 'https' ) ? 'ON' : 'OFF',  # not in RFC 3875
  52         PATH_INFO         => $uri->path,
  53         QUERY_STRING      => $uri->query || '',
  54         SCRIPT_NAME       => '/',
  55         SERVER_NAME       => $uri->host,
  56         SERVER_PORT       => $uri->port,
  57         SERVER_PROTOCOL   => $request->protocol || 'HTTP/1.1',
  58         SERVER_SOFTWARE   => "HTTP-Request-AsCGI/$VERSION",
  59         REMOTE_ADDR       => '127.0.0.1',
  60         REMOTE_HOST       => 'localhost',
  61         REMOTE_PORT       => int( rand(64000) + 1000 ),                   # not in RFC 3875
  62         REQUEST_URI       => $uri->path_query,                            # not in RFC 3875
  63         REQUEST_METHOD    => $request->method,
  64         @_
  65     };
  66
  67     foreach my $field ( $request->headers->header_field_names ) {
  68
  69         my $key = uc("HTTP_$field");
  70         $key =~ tr/-/_/;
  71         $key =~ s/^HTTP_// if $field =~ /^Content-(Length|Type)$/;
  72
  73         unless ( exists $environment->{$key} ) {
  74             $environment->{$key} = $request->headers->header($field);
  75         }
  76     }
  77
  78     unless ( $environment->{SCRIPT_NAME} eq '/' && $environment->{PATH_INFO} ) {
  79         $environment->{PATH_INFO} =~ s/^\Q$environment->{SCRIPT_NAME}\E/\//;
  80         $environment->{PATH_INFO} =~ s/^\/+/\//;
  81     }
  82
  83     $self->environment($environment);
  84
  85     return $self;
  86 }
  87
  88 sub setup {
  89     my $self = shift;
  90
  91     $self->{restore}->{environment} = {%ENV};
  92
  93     binmode( $self->stdin );
  94
  95     if ( $self->request->content_length ) {
  96
  97         $self->stdin->print($self->request->content)
  98           or croak("Can't write request content to stdin handle: $!");
  99
 100         $self->stdin->seek(0, SEEK_SET)
 101           or croak("Can't seek stdin handle: $!");
 102
 103         $self->stdin->flush
 104           or croak("Can't flush stdin handle: $!");
 105     }
 106
 107     open( $self->{restore}->{stdin}, '<&'. STDIN->fileno )
 108       or croak("Can't dup stdin: $!");
 109
 110     open( STDIN, '<&='. $self->stdin->fileno )
 111       or croak("Can't open stdin: $!");
 112
 113     binmode( STDIN );
 114
 115     if ( $self->stdout ) {
 116
 117         open( $self->{restore}->{stdout}, '>&'. STDOUT->fileno )
 118           or croak("Can't dup stdout: $!");
 119
 120         open( STDOUT, '>&='. $self->stdout->fileno )
 121           or croak("Can't open stdout: $!");
 122
 123         binmode( $self->stdout );
 124         binmode( STDOUT);
 125     }
 126
 127     if ( $self->stderr ) {
 128
 129         open( $self->{restore}->{stderr}, '>&'. STDERR->fileno )
 130           or croak("Can't dup stderr: $!");
 131
 132         open( STDERR, '>&='. $self->stderr->fileno )
 133           or croak("Can't open stderr: $!");
 134
 135         binmode( $self->stderr );
 136         binmode( STDERR );
 137     }
 138
 139     {
 140         no warnings 'uninitialized';
 141         %ENV = %{ $self->environment };
 142     }
 143
 144     if ( $INC{'CGI.pm'} ) {
 145         CGI::initialize_globals();
 146     }
 147
 148     $self->{setuped}++;
 149
 150     return $self;
 151 }
 152
 153 sub response {
 154     my ( $self, $callback ) = @_;
 155
 156     return undef unless $self->stdout;
 157
 158     seek( $self->stdout, 0, SEEK_SET )
 159       or croak("Can't seek stdout handle: $!");
 160
 161     my $headers;
 162     while ( my $line = $self->stdout->getline ) {
 163         $headers .= $line;
 164         last if $headers =~ /\x0d?\x0a\x0d?\x0a$/;
 165     }
 166
 167     unless ( defined $headers ) {
 168         $headers = "HTTP/1.1 500 Internal Server Error\x0d\x0a";
 169     }
 170
 171     unless ( $headers =~ /^HTTP/ ) {
 172         $headers = "HTTP/1.1 200 OK\x0d\x0a" . $headers;
 173     }
 174
 175     my $response = HTTP::Response->parse($headers);
 176     $response->date( time() ) unless $response->date;
 177
 178     my $message = $response->message;
 179     my $status  = $response->header('Status');
 180
 181     if ( $message && $message =~ /^(.+)\x0d$/ ) {
 182         $response->message($1);
 183     }
 184
 185     if ( $status && $status =~ /^(\d\d\d)\s?(.+)?$/ ) {
 186
 187         my $code    = $1;
 188         my $message = $2 || HTTP::Status::status_message($code);
 189
 190         $response->code($code);
 191         $response->message($message);
 192     }
 193
 194     my $length = ( stat( $self->stdout ) )[7] - tell( $self->stdout );
 195
 196     if ( $response->code == 500 && !$length ) {
 197
 198         $response->content( $response->error_as_HTML );
 199         $response->content_type('text/html');
 200
 201         return $response;
 202     }
 203
 204     if ($callback) {
 205
 206         my $handle = $self->stdout;
 207
 208         $response->content( sub {
 209
 210             if ( $handle->read( my $buffer, 4096 ) ) {
 211                 return $buffer;
 212             }
 213
 214             return undef;
 215         });
 216     }
 217     else {
 218
 219         my $length = 0;
 220
 221         while ( $self->stdout->read( my $buffer, 4096 ) ) {
 222             $length += length($buffer);
 223             $response->add_content($buffer);
 224         }
 225
 226         if ( $length && !$response->content_length ) {
 227             $response->content_length($length);
 228         }
 229     }
 230
 231     return $response;
 232 }
 233
 234 sub restore {
 235     my $self = shift;
 236
 237     {
 238         no warnings 'uninitialized';
 239         %ENV = %{ $self->{restore}->{environment} };
 240     }
 241
 242     open( STDIN, '<&'. fileno($self->{restore}->{stdin}) )
 243       or croak("Can't restore stdin: $!");
 244
 245     sysseek( $self->stdin, 0, SEEK_SET )
 246       or croak("Can't seek stdin: $!");
 247
 248     if ( $self->{restore}->{stdout} ) {
 249
 250         STDOUT->flush
 251           or croak("Can't flush stdout: $!");
 252
 253         open( STDOUT, '>&'. fileno($self->{restore}->{stdout}) )
 254           or croak("Can't restore stdout: $!");
 255
 256         sysseek( $self->stdout, 0, SEEK_SET )
 257           or croak("Can't seek stdout: $!");
 258     }
 259
 260     if ( $self->{restore}->{stderr} ) {
 261
 262         STDERR->flush
 263           or croak("Can't flush stderr: $!");
 264
 265         open( STDERR, '>&'. fileno($self->{restore}->{stderr}) )
 266           or croak("Can't restore stderr: $!");
 267
 268         sysseek( $self->stderr, 0, SEEK_SET )
 269           or croak("Can't seek stderr: $!");
 270     }
 271
 272     $self->{restored}++;
 273
 274     return $self;
 275 }
 276
 277 sub DESTROY {
 278     my $self = shift;
 279     $self->restore if $self->{setuped} && !$self->{restored};
 280 }
 281
 282 1;
 283
 284 __END__
 285
 286 =head1 SYNOPSIS
 287
 288     use CGI;
 289     use HTTP::Request;
 290     use HTTP::Request::AsCGI;
 291
 292     my $request = HTTP::Request->new( GET => 'http://www.host.com/' );
 293     my $stdout;
 294
 295     {
 296         my $c = HTTP::Request::AsCGI->new($request)->setup;
 297         my $q = CGI->new;
 298
 299         print $q->header,
 300               $q->start_html('Hello World'),
 301               $q->h1('Hello World'),
 302               $q->end_html;
 303
 304         $stdout = $c->stdout;
 305
 306         # environment and descriptors will automatically be restored
 307         # when $c is destructed.
 308     }
 309
 310     while ( my $line = $stdout->getline ) {
 311         print $line;
 312     }
 313
 314 =head1 DESCRIPTION
 315
 316 Provides a convenient way of setting up an CGI environment from an HTTP::Request.
 317
 318 =head1 METHODS
 319
 320 =over 4
 321
 322 =item new ( $request [, key => value ] )
 323
 324 Constructor.  The first argument must be a instance of HTTP::Request, followed
 325 by optional pairs of environment key and value.
 326
 327 =item environment
 328
 329 Returns a hashref containing the environment that will be used in setup.
 330 Changing the hashref after setup has been called will have no effect.
 331
 332 =item setup
 333
 334 Sets up the environment and descriptors.
 335
 336 =item restore
 337
 338 Restores the environment and descriptors. Can only be called after setup.
 339
 340 =item request
 341
 342 Returns the request given to constructor.
 343
 344 =item response
 345
 346 Returns a HTTP::Response. Can only be called after restore.
 347
 348 =item stdin
 349
 350 Accessor for handle that will be used for STDIN, must be a real seekable
 351 handle with an file descriptor. Defaults to a tempoary IO::File instance.
 352
 353 =item stdout
 354
 355 Accessor for handle that will be used for STDOUT, must be a real seekable
 356 handle with an file descriptor. Defaults to a tempoary IO::File instance.
 357
 358 =item stderr
 359
 360 Accessor for handle that will be used for STDERR, must be a real seekable
 361 handle with an file descriptor.
 362
 363 =back
 364
 365 =head1 SEE ALSO
 366
 367 =over 4
 368
 369 =item examples directory in this distribution.
 370
 371 =item L<WWW::Mechanize::CGI>
 372
 373 =item L<Test::WWW::Mechanize::CGI>
 374
 375 =back
 376
 377 =head1 THANKS TO
 378
 379 Thomas L. Shinnick for his valuable win32 testing.
 380
 381 =cut