lib/HTTP/Request/AsCGI.pm

   1 package HTTP::Request::AsCGI;
   2
   3 use strict;
   4 use warnings;
   5 use base 'Class::Accessor::Fast';
   6
   7 use Carp;
   8 use IO::File;
   9
  10 __PACKAGE__->mk_accessors( qw[ enviroment request stdin stdout stderr ] );
  11
  12 our $VERSION = 0.1;
  13
  14 sub new {
  15     my $class   = shift;
  16     my $request = shift;
  17
  18     my $self = {
  19         request  => $request,
  20         restored => 0,
  21         setuped  => 0,
  22         stdin    => IO::File->new_tmpfile,
  23         stdout   => IO::File->new_tmpfile,
  24         stderr   => IO::File->new_tmpfile
  25     };
  26
  27     $self->{enviroment} = {
  28         GATEWAY_INTERFACE => 'CGI/1.1',
  29         HTTP_HOST         => $request->uri->host_port,
  30         QUERY_STRING      => $request->uri->query || '',
  31         SCRIPT_NAME       => $request->uri->path || '/',
  32         SERVER_NAME       => $request->uri->host,
  33         SERVER_PORT       => $request->uri->port,
  34         SERVER_PROTOCOL   => $request->protocol || 'HTTP/1.1',
  35         SERVER_SOFTWARE   => __PACKAGE__ . "/" . $VERSION,
  36         REMOTE_ADDR       => '127.0.0.1',
  37         REMOTE_HOST       => 'localhost',
  38         REMOTE_PORT       => int( rand(64000) + 1000 ),        # not in RFC 3875
  39         REQUEST_URI       => $request->uri->path || '/',       # not in RFC 3875
  40         REQUEST_METHOD    => $request->method,
  41         @_
  42     };
  43
  44     foreach my $field ( $request->headers->header_field_names ) {
  45
  46         my $key = uc($field);
  47         $key =~ tr/-/_/;
  48         $key = 'HTTP_' . $key unless $field =~ /^Content-(Length|Type)$/;
  49
  50         unless ( exists $self->{enviroment}->{$key} ) {
  51             $self->{enviroment}->{$key} = $request->headers->header($field);
  52         }
  53     }
  54
  55     return $class->SUPER::new($self);
  56 }
  57
  58 sub setup {
  59     my $self = shift;
  60
  61     open( my $stdin, '>&', STDIN->fileno )
  62       or croak("Can't dup stdin: $!");
  63
  64     open( my $stdout, '>&', STDOUT->fileno )
  65       or croak("Can't dup stdout: $!");
  66
  67     open( my $stderr, '>&', STDERR->fileno )
  68       or croak("Can't dup stderr: $!");
  69
  70     $self->{restore} = {
  71         stdin      => $stdin,
  72         stdout     => $stdout,
  73         stderr     => $stderr,
  74         enviroment => {%ENV}
  75     };
  76
  77     if ( $self->request->content_length ) {
  78
  79         $self->stdin->syswrite( $self->request->content )
  80           or croak("Can't write content to stdin: $!");
  81
  82         $self->stdin->sysseek( 0, SEEK_SET )
  83           or croak("Can't seek stdin: $!");
  84     }
  85
  86     {
  87         no warnings 'uninitialized';
  88         %ENV = %{ $self->enviroment };
  89     }
  90
  91     open( STDIN, '<&=', $self->stdin->fileno )
  92       or croak("Can't open stdin: $!");
  93
  94     open( STDOUT, '>&=', $self->stdout->fileno )
  95       or croak("Can't open stdout: $!");
  96
  97     open( STDERR, '>&=', $self->stderr->fileno )
  98       or croak("Can't open stderr: $!");
  99
 100     $self->{setuped}++;
 101
 102     return $self;
 103 }
 104
 105 sub restore {
 106     my $self = shift;
 107
 108     %ENV = %{ $self->{restore}->{enviroment} };
 109
 110     open( STDIN, '>&', $self->{restore}->{stdin} )
 111       or croak("Can't restore stdin: $!");
 112
 113     open( STDOUT, '>&', $self->{restore}->{stdout} )
 114       or croak("Can't restore stdout: $!");
 115
 116     open( STDERR, '>&', $self->{restore}->{stderr} )
 117       or croak("Can't restore stderr: $!");
 118
 119     if ( $self->stdin->fileno != STDIN->fileno ) {
 120         $self->stdin->sysseek( 0, SEEK_SET )
 121           or croak("Can't seek stdin: $!");
 122     }
 123
 124     if ( $self->stdout->fileno != STDOUT->fileno ) {
 125         $self->stdout->sysseek( 0, SEEK_SET )
 126           or croak("Can't seek stdout: $!");
 127     }
 128
 129     if ( $self->stderr->fileno != STDERR->fileno ) {
 130         $self->stderr->sysseek( 0, SEEK_SET )
 131           or croak("Can't seek stderr: $!");
 132     }
 133
 134     $self->{restored}++;
 135 }
 136
 137 sub DESTROY {
 138     my $self = shift;
 139     $self->restore if $self->{setuped} && !$self->{restored};
 140 }
 141
 142 1;
 143
 144 __END__
 145
 146 =head1 NAME
 147
 148 HTTP::Request::AsCGI - Setup a CGI enviroment from a HTTP::Request
 149
 150 =head1 SYNOPSIS
 151
 152     use CGI;
 153     use HTTP::Request;
 154     use HTTP::Request::AsCGI;
 155
 156     my $request = HTTP::Request->new( GET => 'http://www.host.com/' );
 157     my $stdout;
 158
 159     {
 160         my $c = HTTP::Request::AsCGI->new($request)->setup;
 161         my $q = CGI->new;
 162
 163         print $q->header,
 164               $q->start_html('Hello World'),
 165               $q->h1('Hello World'),
 166               $q->end_html;
 167
 168         $stdout = $c->stdout;
 169
 170         # enviroment and descriptors will automatically be restored when $c is destructed.
 171     }
 172
 173     while ( my $line = $stdout->getline ) {
 174         print $line;
 175     }
 176
 177 =head1 DESCRIPTION
 178
 179 =head1 METHODS
 180
 181 =over 4
 182
 183 =item new
 184
 185 =item enviroment
 186
 187 =item setup
 188
 189 =item restore
 190
 191 =item request
 192
 193 =item stdin
 194
 195 =item stdout
 196
 197 =item stderr
 198
 199 =back
 200
 201 =head1 BUGS
 202
 203 =head1 AUTHOR
 204
 205 Christian Hansen, C<ch@ngmedia.com>
 206
 207 =head1 LICENSE
 208
 209 This library is free software. You can redistribute it and/or modify
 210 it under the same terms as perl itself.
 211
 212 =cut