lib/HTML/Zoom/FilterBuilder.pm

   1 package HTML::Zoom::FilterBuilder;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5 use HTML::Zoom::CodeStream;
   6
   7 sub new { bless({}, shift) }
   8
   9 sub _stream_from_code {
  10   HTML::Zoom::CodeStream->new({ code => $_[1] })
  11 }
  12
  13 sub _stream_from_array {
  14   shift; # lose $self
  15   HTML::Zoom::CodeStream->from_array(@_)
  16 }
  17
  18 sub _stream_from_proto {
  19   my ($self, $proto) = @_;
  20   my $ref = ref $proto;
  21   if (not $ref) {
  22     return $self->_stream_from_array({ type => 'TEXT', raw => $proto });
  23   } elsif ($ref eq 'ARRAY') {
  24     return $self->_stream_from_array(@$proto);
  25   } elsif ($ref eq 'CODE') {
  26     return $proto->();
  27   } elsif ($ref eq 'SCALAR') {
  28     require HTML::Zoom::Parser::BuiltIn;
  29     return HTML::Zoom::Parser::BuiltIn->html_to_stream($$proto);
  30   }
  31   die "Don't know how to turn $proto (ref $ref) into a stream";
  32 }
  33
  34 sub _stream_concat {
  35   shift->_stream_from_array(@_)->flatten;
  36 }
  37
  38 sub set_attribute {
  39   my ($self, $args) = @_;
  40   my ($name, $value) = @{$args}{qw(name value)};
  41   sub {
  42     my $a = (my $evt = $_[0])->{attrs};
  43     my $e = exists $a->{$name};
  44     +{ %$evt, raw => undef, raw_attrs => undef,
  45        attrs => { %$a, $name => $value },
  46       ($e # add to name list if not present
  47         ? ()
  48         : (attr_names => [ @{$evt->{attr_names}}, $name ]))
  49      }
  50    };
  51 }
  52
  53 sub add_attribute {
  54   my ($self, $args) = @_;
  55   my ($name, $value) = @{$args}{qw(name value)};
  56   sub {
  57     my $a = (my $evt = $_[0])->{attrs};
  58     my $e = exists $a->{$name};
  59     +{ %$evt, raw => undef, raw_attrs => undef,
  60        attrs => {
  61          %$a,
  62          $name => join(' ', ($e ? $a->{$name} : ()), $value)
  63       },
  64       ($e # add to name list if not present
  65         ? ()
  66         : (attr_names => [ @{$evt->{attr_names}}, $name ]))
  67     }
  68   };
  69 }
  70
  71 sub remove_attribute {
  72   my ($self, $args) = @_;
  73   my $name = $args->{name};
  74   sub {
  75     my $a = (my $evt = $_[0])->{attrs};
  76     return $evt unless exists $a->{$name};
  77     $a = { %$a }; delete $a->{$name};
  78     +{ %$evt, raw => undef, raw_attrs => undef,
  79        attrs => $a,
  80        attr_names => [ grep $_ ne $name, @{$evt->{attr_names}} ]
  81     }
  82   };
  83 }
  84
  85 sub collect {
  86   my ($self, $options) = @_;
  87   my ($into, $passthrough, $content, $filter) =
  88     @{$options}{qw(into passthrough content filter)};
  89   sub {
  90     my ($evt, $stream) = @_;
  91     # We wipe the contents of @$into here so that other actions depending
  92     # on this (such as a repeater) can be invoked multiple times easily.
  93     # I -suspect- it's better for that state reset to be managed here; if it
  94     # ever becomes painful the decision should be revisited
  95     if ($into) {
  96       @$into = $content ? () : ($evt);
  97     }
  98     if ($evt->{is_in_place_close}) {
  99       return $evt if $passthrough || $content;
 100       return;
 101     }
 102     my $name = $evt->{name};
 103     my $depth = 1;
 104     my $_next = $content ? 'peek' : 'next';
 105     $stream = $filter->($stream) if $filter;
 106     my $collector = $self->_stream_from_code(sub {
 107       return unless $stream;
 108       while (my ($evt) = $stream->$_next) {
 109         $depth++ if ($evt->{type} eq 'OPEN');
 110         $depth-- if ($evt->{type} eq 'CLOSE');
 111         unless ($depth) {
 112           undef $stream;
 113           return if $content;
 114           push(@$into, $evt) if $into;
 115           return $evt if $passthrough;
 116           return;
 117         }
 118         push(@$into, $evt) if $into;
 119         $stream->next if $content;
 120         return $evt if $passthrough;
 121       }
 122       die "Never saw closing </${name}> before end of source";
 123     });
 124     return ($passthrough||$content) ? [ $evt, $collector ] : $collector;
 125   };
 126 }
 127
 128 sub collect_content {
 129   my ($self, $options) = @_;
 130   $self->collect({ %{$options||{}}, content => 1 })
 131 }
 132
 133 sub add_before {
 134   my ($self, $events) = @_;
 135   sub { return $self->_stream_from_array(@$events, $_[0]) };
 136 }
 137
 138 sub add_after {
 139   my ($self, $events) = @_;
 140   my $coll_proto = $self->collect({ passthrough => 1 });
 141   sub {
 142     my ($evt) = @_;
 143     my $emit = $self->_stream_from_array(@$events);
 144     my $coll = &$coll_proto;
 145     return ref($coll) eq 'HASH' # single event, no collect
 146       ? [ $coll, $emit ]
 147       : [ $coll->[0], $self->_stream_concat($coll->[1], $emit) ];
 148   };
 149 }
 150
 151 sub prepend_content {
 152   my ($self, $events) = @_;
 153   sub {
 154     my ($evt) = @_;
 155     if ($evt->{is_in_place_close}) {
 156       $evt = { %$evt }; delete @{$evt}{qw(raw is_in_place_close)};
 157       return [ $evt, $self->_stream_from_array(
 158         @$events, { type => 'CLOSE', name => $evt->{name} }
 159       ) ];
 160     }
 161     return $self->_stream_from_array($evt, @$events);
 162   };
 163 }
 164
 165 sub append_content {
 166   my ($self, $events) = @_;
 167   my $coll_proto = $self->collect({ passthrough => 1, content => 1 });
 168   sub {
 169     my ($evt) = @_;
 170     if ($evt->{is_in_place_close}) {
 171       $evt = { %$evt }; delete @{$evt}{qw(raw is_in_place_close)};
 172       return [ $evt, $self->_stream_from_array(
 173         @$events, { type => 'CLOSE', name => $evt->{name} }
 174       ) ];
 175     }
 176     my $coll = &$coll_proto;
 177     my $emit = $self->_stream_from_array(@$events);
 178     return [ $coll->[0], $self->_stream_concat($coll->[1], $emit) ];
 179   };
 180 }
 181
 182 sub replace {
 183   my ($self, $replace_with, $options) = @_;
 184   my $coll_proto = $self->collect($options);
 185   sub {
 186     my ($evt, $stream) = @_;
 187     my $emit = $self->_stream_from_proto($replace_with);
 188     my $coll = &$coll_proto;
 189     # For a straightforward replace operation we can, in fact, do the emit
 190     # -before- the collect, and my first cut did so. However in order to
 191     # use the captured content in generating the new content, we need
 192     # the collect stage to happen first - and it seems highly unlikely
 193     # that in normal operation the collect phase will take long enough
 194     # for the difference to be noticeable
 195     return
 196       ($coll
 197         ? (ref $coll eq 'ARRAY'
 198             ? [ $coll->[0], $self->_stream_concat($coll->[1], $emit) ]
 199             : $self->_stream_concat($coll, $emit)
 200           )
 201         : $emit
 202       );
 203   };
 204 }
 205
 206 sub replace_content {
 207   my ($self, $replace_with, $options) = @_;
 208   $self->replace($replace_with, { %{$options||{}}, content => 1 })
 209 }
 210
 211 sub repeat {
 212   my ($self, $repeat_for, $options) = @_;
 213   $options->{into} = \my @into;
 214   my $map_repeat = sub {
 215     local $_ = $self->_stream_from_array(@into);
 216     $_[0]->($_)
 217   };
 218   my $repeater = sub {
 219     $self->_stream_from_proto($repeat_for)
 220          ->map($map_repeat)
 221          ->flatten
 222   };
 223   $self->replace($repeater, $options);
 224 }
 225
 226 sub repeat_content {
 227   my ($self, $repeat_for, $options) = @_;
 228   $self->repeat($repeat_for, { %{$options||{}}, content => 1 })
 229 }
 230
 231 1;