lib/HTML/Zoom/FilterBuilder.pm

   1 package HTML::Zoom::FilterBuilder;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5 use HTML::Zoom::CodeStream;
   6
   7 sub new { bless({}, shift) }
   8
   9 sub _stream_from_code {
  10   HTML::Zoom::CodeStream->new({ code => $_[1] })
  11 }
  12
  13 sub _stream_from_array {
  14   shift; # lose $self
  15   HTML::Zoom::CodeStream->from_array(@_)
  16 }
  17
  18 sub _stream_from_proto {
  19   my ($self, $proto) = @_;
  20   my $ref = ref $proto;
  21   if (not $ref) {
  22     return $self->_stream_from_array({ type => 'TEXT', raw => $proto });
  23   } elsif ($ref eq 'ARRAY') {
  24     return $self->_stream_from_array(@$proto);
  25   } elsif ($ref eq 'CODE') {
  26     return $proto->();
  27   } elsif ($ref eq 'SCALAR') {
  28     require HTML::Zoom::Parser::BuiltIn;
  29     return HTML::Zoom::Parser::BuiltIn->html_to_stream($$proto);
  30   }
  31   die "Don't know how to turn $proto (ref $ref) into a stream";
  32 }
  33
  34 sub _stream_concat {
  35   shift->_stream_from_array(@_)->flatten;
  36 }
  37
  38 sub set_attribute {
  39   my ($self, $args) = @_;
  40   my ($name, $value) = @{$args}{qw(name value)};
  41   sub {
  42     my $a = (my $evt = $_[0])->{attrs};
  43     my $e = exists $a->{$name};
  44     +{ %$evt, raw => undef, raw_attrs => undef,
  45        attrs => { %$a, $name => $value },
  46       ($e # add to name list if not present
  47         ? ()
  48         : (attr_names => [ @{$evt->{attr_names}}, $name ]))
  49      }
  50    };
  51 }
  52
  53 sub add_attribute {
  54   my ($self, $args) = @_;
  55   my ($name, $value) = @{$args}{qw(name value)};
  56   sub {
  57     my $a = (my $evt = $_[0])->{attrs};
  58     my $e = exists $a->{$name};
  59     +{ %$evt, raw => undef, raw_attrs => undef,
  60        attrs => {
  61          %$a,
  62          $name => join(' ', ($e ? $a->{$name} : ()), $value)
  63       },
  64       ($e # add to name list if not present
  65         ? ()
  66         : (attr_names => [ @{$evt->{attr_names}}, $name ]))
  67     }
  68   };
  69 }
  70
  71 sub remove_attribute {
  72   my ($self, $args) = @_;
  73   my $name = $args->{name};
  74   sub {
  75     my $a = (my $evt = $_[0])->{attrs};
  76     return $evt unless exists $a->{$name};
  77     $a = { %$a }; delete $a->{$name};
  78     +{ %$evt, raw => undef, raw_attrs => undef,
  79        attrs => $a,
  80        attr_names => [ grep $_ ne $name, @{$evt->{attr_names}} ]
  81     }
  82   };
  83 }
  84
  85 sub collect {
  86   my ($self, $options) = @_;
  87   my ($into, $passthrough, $inside) = @{$options}{qw(into passthrough inside)};
  88   sub {
  89     my ($evt, $stream) = @_;
  90     # We wipe the contents of @$into here so that other actions depending
  91     # on this (such as a repeater) can be invoked multiple times easily.
  92     # I -suspect- it's better for that state reset to be managed here; if it
  93     # ever becomes painful the decision should be revisited
  94     if ($into) {
  95       @$into = $inside ? () : ($evt);
  96     }
  97     if ($evt->{is_in_place_close}) {
  98       return $evt if $passthrough || $inside;
  99       return;
 100     }
 101     my $name = $evt->{name};
 102     my $depth = 1;
 103     my $_next = $inside ? 'peek' : 'next';
 104     my $collector = $self->_stream_from_code(sub {
 105       return unless $stream;
 106       while (my ($evt) = $stream->$_next) {
 107         $depth++ if ($evt->{type} eq 'OPEN');
 108         $depth-- if ($evt->{type} eq 'CLOSE');
 109         unless ($depth) {
 110           undef $stream;
 111           return if $inside;
 112           push(@$into, $evt) if $into;
 113           return $evt if $passthrough;
 114           return;
 115         }
 116         push(@$into, $evt) if $into;
 117         $stream->next if $inside;
 118         return $evt if $passthrough;
 119       }
 120       die "Never saw closing </${name}> before end of source";
 121     });
 122     return ($passthrough||$inside) ? [ $evt, $collector ] : $collector;
 123   };
 124 }
 125
 126 sub add_before {
 127   my ($self, $events) = @_;
 128   sub { return $self->_stream_from_array(@$events, $_[0]) };
 129 }
 130
 131 sub add_after {
 132   my ($self, $events) = @_;
 133   my $coll_proto = $self->collect({ passthrough => 1 });
 134   sub {
 135     my ($evt) = @_;
 136     my $emit = $self->_stream_from_array(@$events);
 137     my $coll = &$coll_proto;
 138     return ref($coll) eq 'HASH' # single event, no collect
 139       ? [ $coll, $emit ]
 140       : [ $coll->[0], $self->_stream_concat($coll->[1], $emit) ];
 141   };
 142 }
 143
 144 sub prepend_inside {
 145   my ($self, $events) = @_;
 146   sub {
 147     my ($evt) = @_;
 148     if ($evt->{is_in_place_close}) {
 149       $evt = { %$evt }; delete @{$evt}{qw(raw is_in_place_close)};
 150       return [ $evt, $self->_stream_from_array(
 151         @$events, { type => 'CLOSE', name => $evt->{name} }
 152       ) ];
 153     }
 154     return $self->_stream_from_array($evt, @$events);
 155   };
 156 }
 157
 158 sub append_inside {
 159   my ($self, $events) = @_;
 160   my $coll_proto = $self->collect({ passthrough => 1, inside => 1 });
 161   sub {
 162     my ($evt) = @_;
 163     if ($evt->{is_in_place_close}) {
 164       $evt = { %$evt }; delete @{$evt}{qw(raw is_in_place_close)};
 165       return [ $evt, $self->_stream_from_array(
 166         @$events, { type => 'CLOSE', name => $evt->{name} }
 167       ) ];
 168     }
 169     my $coll = &$coll_proto;
 170     my $emit = $self->_stream_from_array(@$events);
 171     return [ $coll->[0], $self->_stream_concat($coll->[1], $emit) ];
 172   };
 173 }
 174
 175 sub replace {
 176   my ($self, $replace_with, $options) = @_;
 177   my $coll_proto = $self->collect($options);
 178   sub {
 179     my ($evt, $stream) = @_;
 180     my $emit = $self->_stream_from_proto($replace_with);
 181     my $coll = &$coll_proto;
 182     # For a straightforward replace operation we can, in fact, do the emit
 183     # -before- the collect, and my first cut did so. However in order to
 184     # use the captured content in generating the new content, we need
 185     # the collect stage to happen first - and it seems highly unlikely
 186     # that in normal operation the collect phase will take long enough
 187     # for the difference to be noticeable
 188     return
 189       ($coll
 190         ? (ref $coll eq 'ARRAY'
 191             ? [ $coll->[0], $self->_stream_concat($coll->[1], $emit) ]
 192             : $self->_stream_concat($coll, $emit)
 193           )
 194         : $emit
 195       );
 196   };
 197 }
 198
 199 sub repeat {
 200   my ($self, $repeat_for, $options) = @_;
 201   $options->{into} = \my @into;
 202   my $map_repeat = sub {
 203     local $_ = $self->_stream_from_array(@into);
 204     $_[0]->($_)
 205   };
 206   my $repeater = sub {
 207     $self->_stream_from_proto($repeat_for)
 208          ->map($map_repeat)
 209          ->flatten
 210   };
 211   $self->replace($repeater, $options);
 212 }
 213
 214 1;