lib/HTML/Zoom/FilterBuilder.pm

   1 package HTML::Zoom::FilterBuilder;
   2
   3 use Devel::Dwarn;
   4
   5 use strict;
   6 use warnings FATAL => 'all';
   7 use HTML::Zoom::CodeStream;
   8
   9 sub new { bless({}, shift) }
  10
  11 sub _stream_from_code {
  12   HTML::Zoom::CodeStream->new({ code => $_[1] })
  13 }
  14
  15 sub _stream_from_array {
  16   shift; # lose $self
  17   HTML::Zoom::CodeStream->from_array(@_)
  18 }
  19
  20 sub _stream_concat {
  21   shift; # lose $self
  22   my @streams = @_;
  23   my $cur_stream = shift(@streams) or die "No streams passed";
  24   HTML::Zoom::CodeStream->new({
  25     code => sub {
  26       return unless $cur_stream;
  27       my $evt;
  28       until (($evt) = $cur_stream->next) {
  29         return unless $cur_stream = shift(@streams);
  30       }
  31       return $evt;
  32     }
  33   });
  34 }
  35
  36 sub set_attribute {
  37   my ($self, $args) = @_;
  38   my ($name, $value) = @{$args}{qw(name value)};
  39   sub {
  40     my $a = (my $evt = $_[0])->{attrs};
  41     my $e = exists $a->{$name};
  42     +{ %$evt, raw => undef, raw_attrs => undef,
  43        attrs => { %$a, $name => $value },
  44       ($e # add to name list if not present
  45         ? ()
  46         : (attr_names => [ @{$evt->{attr_names}}, $name ]))
  47      }
  48    };
  49 }
  50
  51 sub add_attribute {
  52   my ($self, $args) = @_;
  53   my ($name, $value) = @{$args}{qw(name value)};
  54   sub {
  55     my $a = (my $evt = $_[0])->{attrs};
  56     my $e = exists $a->{$name};
  57     +{ %$evt, raw => undef, raw_attrs => undef,
  58        attrs => {
  59          %$a,
  60          $name => join(' ', ($e ? $a->{$name} : ()), $value)
  61       },
  62       ($e # add to name list if not present
  63         ? ()
  64         : (attr_names => [ @{$evt->{attr_names}}, $name ]))
  65     }
  66   };
  67 }
  68
  69 sub remove_attribute {
  70   my ($self, $args) = @_;
  71   my $name = $args->{name};
  72   sub {
  73     my $a = (my $evt = $_[0])->{attrs};
  74     return $evt unless exists $a->{$name};
  75     $a = { %$a }; delete $a->{$name};
  76     +{ %$evt, raw => undef, raw_attrs => undef,
  77        attrs => $a,
  78        attr_names => [ grep $_ ne $name, @{$evt->{attr_names}} ]
  79     }
  80   };
  81 }
  82
  83 sub collect {
  84   my ($self, $options) = @_;
  85   my ($into, $passthrough, $inside) = @{$options}{qw(into passthrough inside)};
  86   sub {
  87     my ($evt, $stream) = @_;
  88     push(@$into, $evt) if $into && !$inside;
  89     if ($evt->{is_in_place_close}) {
  90       return $evt if $passthrough || $inside;
  91       return;
  92     }
  93     my $name = $evt->{name};
  94     my $depth = 1;
  95     my $_next = $inside ? 'peek' : 'next';
  96     my $collector = $self->_stream_from_code(sub {
  97       return unless $stream;
  98       while (my ($evt) = $stream->$_next) {
  99         $depth++ if ($evt->{type} eq 'OPEN');
 100         $depth-- if ($evt->{type} eq 'CLOSE');
 101         unless ($depth) {
 102           undef $stream;
 103           return if $inside;
 104           push(@$into, $evt) if $into;
 105           return $evt if $passthrough;
 106           return;
 107         }
 108         push(@$into, $evt) if $into;
 109         $stream->next if $inside;
 110         return $evt if $passthrough;
 111       }
 112       die "Never saw closing </${name}> before end of source";
 113     });
 114     return ($passthrough||$inside) ? [ $evt, $collector ] : $collector;
 115   };
 116 }
 117
 118 sub add_before {
 119   my ($self, $events) = @_;
 120   sub { return $self->_stream_from_array(@$events, $_[0]) };
 121 }
 122
 123 sub add_after {
 124   my ($self, $events) = @_;
 125   sub {
 126     my ($evt) = @_;
 127     my $emit = $self->_stream_from_array(@$events);
 128     my $coll = $self->collect({ passthrough => 1 })->(@_);
 129     return ref($coll) eq 'HASH' # single event, no collect
 130       ? [ $coll, $emit ]
 131       : [ $coll->[0], $self->_stream_concat($coll->[1], $emit) ];
 132   };
 133 }
 134
 135 sub prepend_inside {
 136   my ($self, $events) = @_;
 137   sub {
 138     my ($evt) = @_;
 139     if ($evt->{is_in_place_close}) {
 140       $evt = { %$evt }; delete @{$evt}{qw(raw is_in_place_close)};
 141       return [ $evt, $self->_stream_from_array(
 142         @$events, { type => 'CLOSE', name => $evt->{name} }
 143       ) ];
 144     }
 145     return $self->_stream_from_array($evt, @$events);
 146   };
 147 }
 148
 149 sub append_inside {
 150   my ($self, $events) = @_;
 151   sub {
 152     my ($evt) = @_;
 153     if ($evt->{is_in_place_close}) {
 154       $evt = { %$evt }; delete @{$evt}{qw(raw is_in_place_close)};
 155       return [ $evt, $self->_stream_from_array(
 156         @$events, { type => 'CLOSE', name => $evt->{name} }
 157       ) ];
 158     }
 159     my $coll = $self->collect({ passthrough => 1, inside => 1 })->(@_);
 160     my $emit = $self->_stream_from_array(@$events);
 161     return [ $coll->[0], $self->_stream_concat($coll->[1], $emit) ];
 162   };
 163 }
 164
 165 sub replace {
 166   my ($self, $events, $options) = @_;
 167   sub {
 168     my ($evt, $stream) = @_;
 169     my $emit = $self->_stream_from_array(@$events);
 170     my $coll = $self->collect($options)->(@_);
 171     # For a straightforward replace operation we can, in fact, do the emit
 172     # -before- the collect, and my first cut did so. However in order to
 173     # use the captured content in generating the new content, we need
 174     # the collect stage to happen first - and it seems highly unlikely
 175     # that in normal operation the collect phase will take long enough
 176     # for the difference to be noticeable
 177     return
 178       ($coll
 179         ? (ref $coll eq 'ARRAY'
 180             ? [ $coll->[0], $self->_stream_concat($coll->[1], $emit) ]
 181             : $self->_stream_concat($coll, $emit)
 182           )
 183         : $emit
 184       );
 185   };
 186 }
 187
 188 1;