t/02git_Repository.t

   1 use strict;
   2 use warnings;
   3 use FindBin qw/$Bin/;
   4 use Test::More qw/no_plan/;
   5 use Test::Exception;
   6 use Test::utf8;
   7 use Encode qw/decode_utf8/;
   8 use Data::Dumper;
   9
  10 BEGIN {
  11     # Don't die on win32.
  12     eval {
  13       # Mocking to allow testing regardless of the user's locale
  14       require I18N::Langinfo;
  15       no warnings 'redefine';
  16       *I18N::Langinfo::langinfo = sub($) {
  17         return "UTF-8" if $_[0] == I18N::Langinfo::CODESET();
  18       };
  19       *CORE::GLOBAL::getpwuid = sub {
  20         wantarray
  21           ? ("test", "x", "1000", "1000", "", "", "T\x{c3}\x{a9}st", "/home/test", "/bin/bash")
  22           : "test";
  23       };
  24     };
  25 }
  26
  27 BEGIN { use_ok 'Gitalist::Git::Repository' }
  28
  29 dies_ok {
  30     my $proj = Gitalist::Git::Repository->new();
  31 } 'New repository with no args';
  32
  33 use Path::Class;
  34 my $gitdir = dir("$Bin/lib/repositories/repo1");
  35
  36 my $proj = Gitalist::Git::Repository->new($gitdir);
  37 isa_ok($proj, 'Gitalist::Git::Repository');
  38 is($proj->path, $gitdir, 'repository path is set');
  39 isa_ok($proj->path, 'Path::Class::Dir', 'repository path');
  40 is($proj->name, qw/repo1/, 'repository name is set');
  41 is($proj->description, qq/some test repository/, 'repository description loaded');
  42 isa_ok($proj->last_change, 'DateTime', 'last_change');
  43
  44 my %references = %{$proj->references};
  45 ok(keys %references >= 2, '->references hash has elements');
  46 is($references{'36c6c6708b8360d7023e8a1649c45bcf9b3bd818'}->[0], 'heads/master', 'reference looks ok');
  47 my @heads = @{$proj->heads};
  48 ok(scalar @heads > 1, '->heads list has more than one element');
  49 my %head = %{$heads[1]};
  50 ok(keys %head == 3, '->heads[1] has the right number of keys');
  51 ok(defined $head{sha1}, '->heads[1]-sha1 is defined');
  52 ok(defined $head{name}, '->heads[1]-name is defined');
  53 is($proj->head_hash, '36c6c6708b8360d7023e8a1649c45bcf9b3bd818', 'head_hash for HEAD is correct');
  54 is($proj->head_hash('refs/heads/master'), '36c6c6708b8360d7023e8a1649c45bcf9b3bd818', 'head_hash for refs/heads/master is correct');
  55 is($proj->head_hash('rafs/head/mister'), undef, 'head_hash for rafs/head/mister is undef');
  56
  57 is(scalar $proj->list_tree, 2, 'expected number of entries in tree');
  58 isa_ok(($proj->list_tree)[1], 'Gitalist::Git::Object');
  59
  60 # Return an ::Object from a sha1
  61 my $obj1 = $proj->get_object('729a7c3f6ba5453b42d16a43692205f67fb23bc1');
  62 isa_ok($obj1, 'Gitalist::Git::Object::Tree');
  63
  64 my $hbp_sha1 = $proj->hash_by_path('36c6c6708b8360d7023e8a1649c45bcf9b3bd818', 'dir1/file2');
  65 my $obj2 = $proj->get_object($hbp_sha1);
  66 isa_ok($obj2, 'Gitalist::Git::Object::Blob');
  67 is($obj2->type, 'blob', 'hash_by_path obj is a file');
  68 is($obj2->content, "foo\n", 'hash_by_path obj is a file');
  69
  70 my $obj3 = $proj->get_object($proj->head_hash);
  71 isa_ok($obj3, 'Gitalist::Git::Object::Commit');
  72
  73 like($proj->head_hash('HEAD'), qr/^([0-9a-fA-F]{40})$/, 'head_hash');
  74
  75 {
  76     my @tree = $proj->list_tree('3bc0634310b9c62222bb0e724c11ffdfb297b4ac');
  77     is(scalar @tree, 1, "tree array contains one entry.");
  78     isa_ok($tree[0], 'Gitalist::Git::Object', 'tree element 0');
  79 }
  80
  81 # Be win32 friendly. Poor poor win32.
  82 if($^O ne 'MSWin32') {
  83   my $owner = $proj->owner;
  84   is_flagged_utf8($owner, "Owner name is flagged as utf8");
  85   is_sane_utf8($owner, "Owner name is not double-encoded");
  86   is($owner, decode_utf8("T\x{c3}\x{a9}st"),  "Owner name is correct");
  87 }