t/02git_Repository.t

   1 use FindBin qw/$Bin/;
   2 BEGIN {
   3     my $env = "$FindBin::Bin/../script/env";
   4     if (-r $env) {
   5         do $env or die $@;
   6     }
   7 }
   8
   9 use strict;
  10 use warnings;
  11 use Test::More qw/no_plan/;
  12 use Test::Exception;
  13 use Test::utf8;
  14 use Encode qw/decode_utf8/;
  15 use Data::Dumper;
  16 use Scalar::Util qw/set_prototype/;
  17
  18 BEGIN {
  19     # Mocking to allow testing regardless of the user's locale
  20     require I18N::Langinfo if $^O ne 'MSWin32';
  21     no warnings 'redefine';
  22     my $stub = sub {
  23         return "UTF-8" if $_[0] == I18N::Langinfo::CODESET();
  24     };
  25     set_prototype \&$stub, ($] <= 5.008009) ? '$' : '_';
  26     *I18N::Langinfo::langinfo = $stub;
  27     *CORE::GLOBAL::getpwuid = sub {
  28         wantarray
  29             ? ("test", "x", "1000", "1000", "", "", "T\x{c3}\x{a9}st", "/home/test", "/bin/bash")
  30             : "test";
  31     };
  32 }
  33
  34 BEGIN { use_ok 'Gitalist::Git::Repository' }
  35
  36 dies_ok {
  37     my $proj = Gitalist::Git::Repository->new();
  38 } 'New repository with no args';
  39
  40 use Path::Class;
  41 my $gitdir = dir("$Bin/lib/repositories/repo1");
  42
  43 my $proj = Gitalist::Git::Repository->new($gitdir);
  44 isa_ok($proj, 'Gitalist::Git::Repository');
  45 is($proj->path, $gitdir, 'repository path is set');
  46 isa_ok($proj->path, 'Path::Class::Dir', 'repository path');
  47 is($proj->name, qw/repo1/, 'repository name is set');
  48 is($proj->description, qq/some test repository/, 'repository description loaded');
  49 isa_ok($proj->last_change, 'DateTime', 'last_change');
  50
  51 my %references = %{$proj->references};
  52 ok(keys %references >= 2, '->references hash has elements');
  53 is($references{'36c6c6708b8360d7023e8a1649c45bcf9b3bd818'}->[0], 'tags/0.01', 'reference looks ok');
  54 my @heads = @{$proj->heads};
  55 ok(scalar @heads > 1, '->heads list has more than one element');
  56 my $head = $heads[1];
  57 isa_ok($head, 'Gitalist::Git::Head');
  58 is($proj->head_hash, 'd6ddf8b26be63066e01d96a0922c87cd8d6e2270', 'head_hash for HEAD is correct');
  59 is($proj->head_hash('refs/heads/master'), 'd6ddf8b26be63066e01d96a0922c87cd8d6e2270', 'head_hash for refs/heads/master is correct');
  60 is($proj->head_hash('rafs/head/mister'), undef, 'head_hash for rafs/head/mister is undef');
  61
  62 ok(scalar @{$proj->tags} == 1, '->tags list has one element');
  63
  64 # Return an ::Object from a sha1
  65 my $obj1 = $proj->get_object('729a7c3f6ba5453b42d16a43692205f67fb23bc1');
  66 isa_ok($obj1, 'Gitalist::Git::Object::Tree');
  67
  68 my $obj3 = $proj->get_object($proj->head_hash);
  69 isa_ok($obj3, 'Gitalist::Git::Object::Commit');
  70
  71 my $obj2 = $obj3->sha_by_path('dir1/file2');
  72 isa_ok($obj2, 'Gitalist::Git::Object::Blob');
  73 is($obj2->type, 'blob', 'sha_by_path obj is a blob');
  74 is($obj2->content, "foo\n", 'sha_by_path obj content is correct');
  75
  76
  77 like($proj->head_hash('HEAD'), qr/^([0-9a-fA-F]{40})$/, 'head_hash');
  78
  79 {
  80     my @tree = @{$obj3->tree};
  81     is(scalar @tree, 1, "tree array contains one entry.");
  82     isa_ok($tree[0], 'Gitalist::Git::Object', 'tree element 0');
  83 }
  84
  85 $proj->{owner} = decode_utf8("T\x{c3}\x{a9}st") if $^O eq 'MSWin32';
  86
  87 my $owner = $proj->owner;
  88 is_flagged_utf8($owner, "Owner name is flagged as utf8");
  89 is_sane_utf8($owner, "Owner name is not double-encoded");
  90 is($owner, decode_utf8("T\x{c3}\x{a9}st"),  "Owner name is correct");
  91
  92 is_deeply $proj->pack,  {
  93     __CLASS__   => 'Gitalist::Git::Repository',
  94     description => 'some test repository',
  95     heads       => [
  96         {
  97             __CLASS__   => 'Gitalist::Git::Head',
  98             committer   => 'Dan Brook <broq@cpan.org>',
  99             last_change => '2011-06-05T23:00:44Z',
 100             name        => 'master',
 101             sha1        => 'd6ddf8b26be63066e01d96a0922c87cd8d6e2270',
 102         },
 103         {
 104             __CLASS__   => 'Gitalist::Git::Head',
 105             committer   => 'Zachary Stevens <zts@cryptocracy.com>',
 106             last_change => '2009-11-12T19:00:34Z',
 107             name        => 'branch1',
 108             sha1        => '0710a7c8ee11c73e8098d08f9384c2a839c65e4e'
 109         },
 110     ],
 111     is_bare     => 1,
 112     last_change => '2011-06-05T23:00:44Z',
 113     name        => 'repo1',
 114     owner       => "T\351st",
 115     references  => {
 116         "d6ddf8b26be63066e01d96a0922c87cd8d6e2270" => ['heads/master'],
 117         "36c6c6708b8360d7023e8a1649c45bcf9b3bd818" => ['tags/0.01'],
 118         "0710a7c8ee11c73e8098d08f9384c2a839c65e4e" => [ 'heads/branch1' ]
 119     },
 120     tags        => [ {
 121         __CLASS__
 122              => 'Gitalist::Git::Tag',
 123         committer
 124              => 'Florian Ragwitz <rafl@debian.org>',
 125         last_change
 126              => '2007-03-06T20:44:35Z',
 127         name    => 0.01,
 128         sha1    => '36c6c6708b8360d7023e8a1649c45bcf9b3bd818',
 129         type    => 'commit'
 130     } ]
 131 }, 'Serialized correctly';