Add built local::lib
[catagits/Gitalist.git] / local-lib5 / lib / perl5 / Tree / Simple / Visitor / CreateDirectoryTree.pm
1
2 package Tree::Simple::Visitor::CreateDirectoryTree;
3
4 use strict;
5 use warnings;
6
7 our $VERSION = '0.02';
8
9 use File::Spec;
10 use Scalar::Util qw(blessed);
11
12 use base qw(Tree::Simple::Visitor);
13
14 sub new {
15     my ($_class) = @_;
16     my $class = ref($_class) || $_class;
17     my $visitor = {};
18     bless($visitor, $class);
19     $visitor->_init();
20     return $visitor;
21 }
22
23 sub _init {
24     my ($self) = @_;
25     $self->{file_handler} = sub {        
26         my ($filepath) = @_;
27         open(FILE, ">", $filepath) || die "IO Error : Cannot create file ($filepath) : $!";
28         close(FILE);    
29     };
30     $self->{dir_handler} = sub {
31         my ($dirpath) = @_;
32         mkdir($dirpath) || die "IO Error : Cannot make directory ($dirpath) : $!";
33     };
34     $self->SUPER::_init();    
35 }
36
37 sub visit {
38         my ($self, $tree) = @_;
39         (blessed($tree) && $tree->isa("Tree::Simple"))
40                 || die "Insufficient Arguments : You must supply a valid Tree::Simple object"; 
41     # pass on to our recursive subroutine
42     $self->_createDirectoryStructure($tree);
43 }
44
45 sub setFileHandler {
46     my ($self, $file_handler) = @_;
47     (defined($file_handler) && ref($file_handler) eq 'CODE')
48         || die "Insufficient Arguments : file handler must be a subroutine reference";
49     $self->{file_handler} = $file_handler;
50 }
51
52 sub setDirectoryHandler {
53     my ($self, $dir_handler) = @_;
54     (defined($dir_handler) && ref($dir_handler) eq 'CODE')
55         || die "Insufficient Arguments : directory handler must be a subroutine reference";
56     $self->{dir_handler} = $dir_handler;    
57 }
58
59 sub _createDirectoryStructure {
60     my ($self, $tree, @path) = @_;
61     my $node = $tree->getNodeValue();
62     # filter the nodes if need be
63     my $filter_function = $self->getNodeFilter();
64     $node = $filter_function->($node) if $filter_function;
65     # if its a leaf and it 
66     # doesn't end with a /
67     # then its a file
68     if ($tree->isLeaf() && $node !~ /\/|\\$/) {
69         $self->{file_handler}->(File::Spec->catfile(@path, $node));
70     }       
71     # otherwise we are going 
72     # to treat it as a directory
73     else {
74         $node =~ s/\/|\\$//;
75         $self->{dir_handler}->(File::Spec->catdir(@path, $node));
76         foreach my $child ($tree->getAllChildren()) {
77             $self->_createDirectoryStructure($child, (@path, $node));
78         }
79     }
80 }
81
82 1;
83
84 __END__
85
86 =head1 NAME
87
88 Tree::Simple::Visitor::CreateDirectoryTree - A Visitor for create a set of directories and files from a Tree::Simple object
89
90 =head1 SYNOPSIS
91
92   use Tree::Simple::Visitor::CreateDirectoryTree;
93   
94   # create a Tree::Simple object which
95   # represents a directory heirarchy
96   my $tree = Tree::Simple->new("www/")
97                     ->addChildren(
98                         Tree::Simple->new("conf/")
99                             ->addChildren(
100                                 Tree::Simple->new("startup.pl"),
101                                 Tree::Simple->new("httpd.conf")
102                             ),                            
103                         Tree::Simple->new("cgi-bin/"),
104                         Tree::Simple->new("ht_docs/"),
105                         Tree::Simple->new("logs/")
106                             ->addChildren(
107                                 Tree::Simple->new("error.log"),
108                                 Tree::Simple->new("access.log")
109                             ),                            
110                     );
111
112   # create an instance of our visitor
113   my $visitor = Tree::Simple::Visitor::CreateDirectoryTree->new();
114   
115   # pass the visitor to a Tree::Simple object
116   $tree->accept($visitor);
117   
118   # the www/ directory now mirrors the structure of the tree 
119
120 =head1 DESCRIPTION
121
122 This visitor can be used to create a set of directories and files from a Tree::Simple object hierarchy.
123
124 =head1 METHODS
125
126 =over 4
127
128 =item B<new>
129
130 There are no arguments to the constructor the object will be in its default state. You can use the C<setNodeFilter>, C<setFileHandler> and C<setDirectoryHandler> methods to customize its behavior.
131
132 =item B<setNodeFilter ($filter_function)>
133
134 This method accepts a CODE reference as its C<$filter_function> argument and throws an exception if it is not a code reference. This code reference is used to filter the tree nodes as they are used to create the directory tree, it can be basically used as a node pre-processor. An example usage of this might be to enforce the C<8.3> naming rules of DOS, or the 32 character limit of older macintoshes.   
135
136 =item B<setFileHandler ($file_handler)>
137
138 This method accepts a CODE reference as its C<$file_handler> argument and throws an exception if it is not a CODE reference. This method can be used to create custom file creation behavior. The default behavior is to just create the file and nothing else, but by using this method it is possible to implement some other custom behavior, such as creating a file based on a template. The function is passed the full path of the file to be created (as built by File::Spec).
139
140 =item B<setDirectoryHandler ($dir_handler)>
141
142 This method accepts a CODE reference as its C<$dir_handler> argument and throws an exception if it is not a CODE reference. This method can be used to create custom directory creation behavior. The default behavior is to just create the directory and nothing else, but by using this method it is possible to implement some other custom behavior, such as creating a directory on a remote server. The function is passed the full path of the directory to be created (as built by File::Spec).
143
144 =item B<visit ($tree)>
145
146 This is the method that is used by Tree::Simple's C<accept> method. It can also be used on its own, it requires the C<$tree> argument to be a Tree::Simple object (or derived from a Tree::Simple object), and will throw and exception otherwise.
147
148 The tree is processed as follows:
149
150 =over 4
151
152 =item Any node which is not a leaf is considered a directory.
153
154 Obviously since files themselves are leaf nodes, this makes sense that non-leaves will be directories.
155
156 =item Any node (including leaf nodes) which ends in either the character C</> or C<\> is considered a directory.
157
158 I think it is a pretty standard convention to have directory names ending in a seperator. The seperator itself is stripped off before the directory name is passed to File::Spec where the platform specific directory path is created. This means that it does not matter which one you use, it will be completely cross platform (at least as cross-platform as File::Spec is).
159
160 =item All other nodes are considered to be files.
161
162 =back
163
164 =back
165
166 =head1 BUGS
167
168 None that I am aware of. Of course, if you find a bug, let me know, and I will be sure to fix it. 
169
170 =head1 CODE COVERAGE
171
172 See the B<CODE COVERAGE> section in L<Tree::Simple::VisitorFactory> for more inforamtion.
173
174 =head1 SEE ALSO
175
176 These Visitor classes are all subclasses of B<Tree::Simple::Visitor>, which can be found in the B<Tree::Simple> module, you should refer to that module for more information.
177
178 =head1 AUTHOR
179
180 stevan little, E<lt>stevan@iinteractive.comE<gt>
181
182 =head1 COPYRIGHT AND LICENSE
183
184 Copyright 2004, 2005 by Infinity Interactive, Inc.
185
186 L<http://www.iinteractive.com>
187
188 This library is free software; you can redistribute it and/or modify
189 it under the same terms as Perl itself. 
190
191 =cut
192