local-lib5/lib/perl5/Moose/Meta/Method/Augmented.pm

   1 package Moose::Meta::Method::Augmented;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION   = '0.93';
   7 $VERSION = eval $VERSION;
   8 our $AUTHORITY = 'cpan:STEVAN';
   9
  10 use base 'Moose::Meta::Method';
  11
  12 sub new {
  13     my ( $class, %args ) = @_;
  14
  15     # the package can be overridden by roles
  16     # it is really more like body's compilation stash
  17     # this is where we need to override the definition of super() so that the
  18     # body of the code can call the right overridden version
  19     my $name = $args{name};
  20     my $meta = $args{class};
  21
  22     my $super = $meta->find_next_method_by_name($name);
  23
  24     (defined $super)
  25         || $meta->throw_error("You cannot augment '$name' because it has no super method", data => $name);
  26
  27     my $_super_package = $super->package_name;
  28     # BUT!,... if this is an overridden method ....
  29     if ($super->isa('Moose::Meta::Method::Overridden')) {
  30         # we need to be sure that we actually
  31         # find the next method, which is not
  32         # an 'override' method, the reason is
  33         # that an 'override' method will not
  34         # be the one calling inner()
  35         my $real_super = $meta->_find_next_method_by_name_which_is_not_overridden($name);
  36         $_super_package = $real_super->package_name;
  37     }
  38
  39     my $super_body = $super->body;
  40
  41     my $method = $args{method};
  42
  43     my $body = sub {
  44         local $Moose::INNER_ARGS{$_super_package} = [ @_ ];
  45         local $Moose::INNER_BODY{$_super_package} = $method;
  46         $super_body->(@_);
  47     };
  48
  49     # FIXME store additional attrs
  50     $class->wrap(
  51         $body,
  52         package_name => $meta->name,
  53         name         => $name
  54     );
  55 }
  56
  57 1;
  58
  59 __END__
  60
  61 =pod
  62
  63 =head1 NAME
  64
  65 Moose::Meta::Method::Augmented - A Moose Method metaclass for augmented methods
  66
  67 =head1 DESCRIPTION
  68
  69 This class implements method augmentation logic for the L<Moose>
  70 C<augment> keyword.
  71
  72 The augmentation subroutine reference will be invoked explicitly using
  73 the C<inner> keyword from the parent class's method definition.
  74
  75 =head1 INHERITANCE
  76
  77 C<Moose::Meta::Method::Augmented> is a subclass of L<Moose::Meta::Method>.
  78
  79 =head1 METHODS
  80
  81 =over 4
  82
  83 =item B<< Moose::Meta::Method::Augmented->new(%options) >>
  84
  85 This constructs a new object. It accepts the following options:
  86
  87 =over 8
  88
  89 =item * class
  90
  91 The metaclass object for the class in which the augmentation is being
  92 declared. This option is required.
  93
  94 =item * name
  95
  96 The name of the method which we are augmenting. This method must exist
  97 in one of the class's superclasses. This option is required.
  98
  99 =item * method
 100
 101 The subroutine reference which implements the augmentation. This
 102 option is required.
 103
 104 =back
 105
 106 =back
 107
 108 =head1 BUGS
 109
 110 All complex software has bugs lurking in it, and this module is no
 111 exception. If you find a bug please either email me, or add the bug
 112 to cpan-RT.
 113
 114 =head1 AUTHOR
 115
 116 Yuval Kogman E<lt>nothingmuch@cpan.orgE<gt>
 117
 118 =head1 COPYRIGHT AND LICENSE
 119
 120 Copyright 2006-2009 by Infinity Interactive, Inc.
 121
 122 L<http://www.iinteractive.com>
 123
 124 This library is free software; you can redistribute it and/or modify
 125 it under the same terms as Perl itself.
 126
 127 =cut