lib/Gitalist/URIStructure/Ref.pm

   1 package Gitalist::URIStructure::Ref;
   2 use MooseX::MethodAttributes::Role;
   3 use Moose::Autobox;
   4 use namespace::autoclean;
   5
   6 requires 'base';
   7
   8 with qw/
   9     Gitalist::URIStructure::WithLog
  10 /;
  11
  12 after 'base' => sub {
  13     my ($self, $c) = @_;
  14     confess("No repository in the stash")
  15         unless $c->stash->{Repository};
  16 };
  17
  18 sub find : Chained('base') PathPart('') CaptureArgs(1) {
  19     my ($self, $c, $sha1part) = @_;
  20     # FIXME - Should not be here!
  21     $c->stash->{Commit} = $c->stash->{Repository}->get_object_or_head($sha1part)
  22         or $c->detach('/error404', "Couldn't find a object for '$sha1part' in XXXX!");
  23 }
  24
  25 sub diff : Chained('find') CaptureArgs(0) {}
  26
  27 sub diff_fancy : Chained('diff') PathPart('') Args() {
  28     my($self, $c, $comparison, @rest) = @_;
  29     # FIXME - This ain't pretty
  30     $c->stash->{parent}   = $comparison
  31       if $comparison;
  32     $c->stash->{filename} = $rest[0]
  33       if @rest;
  34 }
  35
  36 sub diff_plain : Chained('diff') PathPart('plain') Args(0) {
  37     my($self, $c) = @_;
  38     $c->stash->{no_wrapper} = 1;
  39 }
  40
  41 sub commit : Chained('find') PathPart('commit') Args(0) {}
  42
  43 sub tree : Chained('find') Does('FilenameArgs') Args() {}
  44
  45 sub find_blob : Action {
  46     my ($self, $c) = @_;
  47     my($repo, $object) = @{$c->{stash}}{qw(Repository Commit)};
  48     # FIXME - Eugh!
  49     my $h  = $object->isa('Gitalist::Git::Object::Commit')
  50            ? $repo->hash_by_path($object->sha1, $c->stash->{filename})
  51            : $object->isa('Gitalist::Git::Object::Blob')
  52              ? $object->sha1
  53              : die "Unknown object type for '${\$object->sha1}'";
  54     die "No file or sha1 provided."
  55         unless $h;
  56     $c->stash(blob => $repo->get_object($h)->content);
  57 }
  58
  59 sub blob : Chained('find') Does('FilenameArgs') Args() {
  60     my ($self, $c) = @_;
  61     $c->forward('find_blob');
  62 }
  63
  64 sub blame : Chained('find') Does('FilenameArgs') Args() {}
  65
  66 sub history : Chained('find') Does('FilenameArgs') Args() {}
  67
  68 1;