lib/Gitalist/Model/CollectionOfRepos.pm

   1 package Gitalist::Model::CollectionOfRepos;
   2
   3 use Moose;
   4 use MooseX::Types::Moose qw/Undef Maybe ArrayRef Str/;
   5 use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
   6 use MooseX::Types::LoadableClass qw/ LoadableClass /;
   7 use Gitalist::Git::Types qw/ ArrayRefOfDirs Dir DirOrUndef /;
   8 use Moose::Util::TypeConstraints;
   9 use Moose::Autobox;
  10 use Path::Class qw/ dir /;
  11 use namespace::autoclean;
  12
  13 extends 'Catalyst::Model';
  14
  15 with 'Catalyst::Component::ApplicationAttribute';
  16 with 'Catalyst::Component::InstancePerContext';
  17
  18 has class => (
  19     isa => LoadableClass,
  20     is  => 'ro',
  21     lazy => 1,
  22     coerce => 1,
  23     builder => '_build_class',
  24 );
  25
  26 sub _build_class {
  27     my ($self) = @_;
  28
  29     if($self->whitelist && -f $self->whitelist) {
  30         return 'Gitalist::Git::CollectionOfRepositories::FromDirectory::WhiteList';
  31     }
  32     elsif($self->search_recursively) {
  33         return 'Gitalist::Git::CollectionOfRepositories::FromDirectoryRecursive';
  34     }
  35     elsif ($self->repos) {
  36         return 'Gitalist::Git::CollectionOfRepositories::FromListOfDirectories';
  37     }
  38     elsif ($self->repos_dir) {
  39         return 'Gitalist::Git::CollectionOfRepositories::FromDirectory';
  40     }
  41     else {
  42         return "Don't know where to get repositores from. Try a --repos_dir option, or setting up config";
  43     }
  44 }
  45
  46 has args => (
  47     isa     => 'HashRef',
  48     is      => 'ro',
  49     default => sub { {} },
  50 );
  51
  52 has search_recursively => (
  53     is      => 'ro',
  54     isa     => 'Bool',
  55     default => 0,
  56 );
  57
  58 ## XX What is this for?
  59 has export_ok => (
  60     is  => 'ro',
  61     isa => 'Str',
  62 );
  63
  64 has whitelist => (
  65     is  => 'ro',
  66     isa => 'Str',
  67     predicate => '_has_whitelist',
  68 );
  69
  70 # Simple directory of repositories (for list)
  71 has repos_dir => (
  72     is => 'ro',
  73     isa => DirOrUndef,
  74     coerce => 1,
  75     builder => '_build_repos_dir',
  76     lazy => 1,
  77 );
  78
  79 # Directory containing list of one or more repositories
  80 has repos => (
  81     is => 'ro',
  82     isa => ArrayRefOfDirs,
  83     coerce => 1,
  84 );
  85
  86 sub _build_repos_dir {
  87     my $self = shift;
  88     my $dir = $self->_application->run_options->{repo_dir} || $ENV{GITALIST_REPO_DIR } || undef;
  89 }
  90
  91 sub BUILD {
  92     my $self = shift;
  93     $self->class();
  94     if ($self->repos_dir) { $self->repos_dir->resolve }
  95 }
  96
  97 sub build_per_context_instance {
  98     my ($self, $app) = @_;
  99
 100     my %args = (
 101         export_ok => $self->export_ok || '',
 102         $self->_has_whitelist ? (whitelist => $self->whitelist) : (),
 103         repos => $self->repos,
 104         repo_dir => $self->repos_dir,
 105         %{ $self->args }
 106     );
 107
 108     return $self->class->new(%args);
 109 }
 110
 111 __PACKAGE__->meta->make_immutable;
 112
 113 __END__
 114
 115 =encoding UTF-8
 116
 117 =head1 NAME
 118
 119 Gitalist::Model::CollectionOfRepos - Model::CollectionOfRepos module for Gitalist
 120
 121 =head1 DESCRIPTION
 122
 123 This Model is a factory for an object implementing the L<Gitalist::Git::CollectionOfRepositories>
 124 interface.
 125
 126 The simple options passed on the command line (like C<--repos_dir>), a class will by picked by default
 127 L<Gitalist::Git::CollectionOfRepositories::FromDirectory>.
 128
 129 This can be overridden from config by explicitly passing in a class name and args for that class
 130 in config:
 131
 132     <Model::CollectionOfRepos>
 133         class MyClassName
 134         <args>
 135             ...
 136         </args>
 137     </Model::CollectionOfRepos>
 138
 139 =head1 AUTHORS
 140
 141 See L<Gitalist> for authors.
 142
 143 =head1 LICENSE
 144
 145 See L<Gitalist> for the license.
 146
 147 =cut