lib/Gitalist/Model/CollectionOfRepos.pm

   1 package Gitalist::Model::CollectionOfRepos;
   2
   3 use Moose;
   4 use Gitalist::Git::CollectionOfRepositories::FromDirectoryRecursive;
   5 use Gitalist::Git::CollectionOfRepositories::FromListOfDirectories;
   6 use Gitalist::Git::CollectionOfRepositories::FromDirectory::WhiteList;
   7 use MooseX::Types::Moose qw/Maybe ArrayRef/;
   8 use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
   9 use Moose::Util::TypeConstraints;
  10 use Moose::Autobox;
  11 use namespace::autoclean;
  12
  13 extends 'Catalyst::Model';
  14
  15 with 'Catalyst::Component::InstancePerContext';
  16
  17 my $repo_dir_t = subtype NonEmptySimpleStr,
  18     where { -d $_ },
  19     message { 'Cannot find repository dir: "' . $_ . '", please set up gitalist.conf, or set GITALIST_REPO_DIR environment or pass the --repo_dir parameter when starting the application' };
  20
  21 my $arrayof_repos_dir_t = subtype ArrayRef[$repo_dir_t],
  22     where { 1 },
  23     message { 'Cannot find repository directories listed in config - these are invalid directories: ' . join(', ', $_->flatten) };
  24
  25 coerce $arrayof_repos_dir_t,
  26     from NonEmptySimpleStr,
  27     via { [ $_ ] };
  28
  29 has config_repo_dir => (
  30     isa => NonEmptySimpleStr,
  31     is => 'ro',
  32     init_arg => 'repo_dir',
  33     predicate => 'has_config_repo_dir',
  34 );
  35
  36 has repo_dir => (
  37     isa => $repo_dir_t,
  38     is => 'ro',
  39     lazy_build => 1
  40 );
  41
  42 has repos => (
  43     isa => $arrayof_repos_dir_t,
  44     is => 'ro',
  45     default => sub { [] },
  46     traits => ['Array'],
  47     handles => {
  48         _repos_count => 'count',
  49     },
  50     coerce => 1,
  51 );
  52
  53
  54 has search_recursively => (
  55     is      => 'ro',
  56     isa     => 'Bool',
  57     default => 0,
  58 );
  59
  60 has export_ok => (
  61     is  => 'ro',
  62     isa => 'Str',
  63 );
  64
  65 has whitelist => (
  66     is  => 'ro',
  67     isa => 'Str',
  68 );
  69
  70 sub _build_repo_dir {
  71     my $self = shift;
  72     $ENV{GITALIST_REPO_DIR} ?
  73         $ENV{GITALIST_REPO_DIR}
  74       : $self->has_config_repo_dir
  75       ? $self->config_repo_dir
  76         : '';
  77 }
  78
  79 after BUILD => sub {
  80     my $self = shift;
  81     # Explode loudly at app startup time if there is no list of
  82     # repositories or repos dir, rather than on first hit
  83     $self->_repos_count || $self->repo_dir;
  84 };
  85
  86 sub build_per_context_instance {
  87     my ($self, $app) = @_;
  88
  89     my %args = (export_ok => $self->export_ok || '');
  90     my $class;
  91     if($self->whitelist && -f $self->whitelist) {
  92         $class = 'Gitalist::Git::CollectionOfRepositories::FromDirectory::WhiteList';
  93         $args{repo_dir}  = $self->repo_dir;
  94         $args{whitelist} = $self->whitelist;
  95     } elsif ($self->_repos_count && !$self->search_recursively) {
  96         $class = 'Gitalist::Git::CollectionOfRepositories::FromListOfDirectories';
  97         $args{repos} = $self->repos;
  98     } elsif($self->search_recursively) {
  99         $class = 'Gitalist::Git::CollectionOfRepositories::FromDirectoryRecursive';
 100         $args{repo_dir} = $self->repo_dir;
 101     } else {
 102         $class = 'Gitalist::Git::CollectionOfRepositories::FromDirectory';
 103         $args{repo_dir} = $self->repo_dir;
 104     }
 105
 106     return $class->new(%args);
 107 }
 108
 109 __PACKAGE__->meta->make_immutable;
 110
 111 __END__
 112
 113 =head1 AUTHORS
 114
 115 See L<Gitalist> for authors.
 116
 117 =head1 LICENSE
 118
 119 See L<Gitalist> for the license.
 120
 121 =cut