lib/Gitalist/Git/Repository.pm

   1 use MooseX::Declare;
   2
   3 class Gitalist::Git::Repository with Gitalist::Git::HasUtils {
   4     # FIXME, use Types::Path::Class and coerce
   5     use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
   6     use MooseX::Types::Moose qw/Str Maybe Bool HashRef ArrayRef/;
   7     use Gitalist::Git::Types qw/SHA1 DateTime Dir/;
   8     use Moose::Autobox;
   9     use List::MoreUtils qw/any zip/;
  10     use aliased 'DateTime' => 'DT';
  11     use Encode qw/decode/;
  12     use I18N::Langinfo qw/langinfo CODESET/;
  13     use Gitalist::Git::Object::Blob;
  14     use Gitalist::Git::Object::Tree;
  15     use Gitalist::Git::Object::Commit;
  16     use Gitalist::Git::Object::Tag;
  17
  18     with 'Gitalist::Serializeable';
  19
  20     our $SHA1RE = qr/[0-9a-fA-F]{40}/;
  21
  22     around BUILDARGS (ClassName $class: Dir $dir) {
  23         # Allows us to be called as Repository->new($dir)
  24         # Last path component becomes $self->name
  25         # Full path to git objects becomes $self->path
  26         my $name = $dir->dir_list(-1);
  27         $dir = $dir->subdir('.git') if (-f $dir->file('.git', 'HEAD'));
  28         confess("Can't find a git repository at " . $dir)
  29             unless ( -f $dir->file('HEAD') );
  30         return $class->$orig(name => $name,
  31                              path => $dir);
  32     }
  33
  34     has name => ( isa => NonEmptySimpleStr,
  35                   is => 'ro', required => 1 );
  36
  37     has path => ( isa => Dir,
  38                   is => 'ro', required => 1,
  39                   traits => [qw/ DoNotSerialize /] );
  40
  41     has description => ( isa => Str,
  42                          is => 'ro',
  43                          lazy_build => 1,
  44                      );
  45
  46     has owner => ( isa => NonEmptySimpleStr,
  47                    is => 'ro',
  48                    lazy_build => 1,
  49                );
  50
  51     has last_change => ( isa => Maybe[DateTime],
  52                          is => 'ro',
  53                          lazy_build => 1,
  54                      );
  55
  56     has is_bare => ( isa => Bool,
  57                      is => 'ro',
  58                      lazy => 1,
  59                      default => sub {
  60                          -d $_[0]->path->parent->subdir($_[0]->name)
  61                              ? 1 : 0
  62                          },
  63                      );
  64     has heads => ( isa => ArrayRef[HashRef],
  65                    is => 'ro',
  66                    lazy_build => 1,
  67                    traits => [qw/ DoNotSerialize /],
  68                    );
  69     has tags => ( isa => ArrayRef[HashRef],
  70                    is => 'ro',
  71                    lazy_build => 1);
  72     has references => ( isa => HashRef[ArrayRef[Str]],
  73                         is => 'ro',
  74                         lazy_build => 1 );
  75
  76     method BUILD {
  77         $self->$_() for qw/last_change owner description /; # Ensure to build early.
  78     }
  79
  80     ## Public methods
  81
  82     method get_object_or_head (NonEmptySimpleStr $ref) {
  83         my $sha1 = is_SHA1($ref) ? $ref : $self->head_hash($ref);
  84         $self->get_object($sha1);
  85     }
  86
  87     method head_hash (Str $head?) {
  88         my $output = $self->run_cmd(qw/rev-parse --verify/, $head || 'HEAD' );
  89         confess("No such head: " . $head) unless defined $output;
  90
  91         my($sha1) = $output =~ /^($SHA1RE)$/;
  92         return $sha1;
  93     }
  94
  95     method list_tree (SHA1 $sha1?) {
  96         $sha1 ||= $self->head_hash;
  97         my $object = $self->get_object($sha1);
  98         return @{$object->tree};
  99     }
 100
 101     method get_object (NonEmptySimpleStr $sha1) {
 102         unless (is_SHA1($sha1)) {
 103             $sha1 = $self->head_hash($sha1);
 104         }
 105         my $type = $self->run_cmd('cat-file', '-t', $sha1);
 106         chomp($type);
 107         my $class = 'Gitalist::Git::Object::' . ucfirst($type);
 108         $class->new(
 109             repository => $self,
 110             sha1 => $sha1,
 111             type => $type,
 112         );
 113     }
 114
 115     method hash_by_path ($base, $path = '', $type?) {
 116         $path =~ s{/+$}();
 117         # FIXME should this really just take the first result?
 118         my @paths = $self->run_cmd('ls-tree', $base, '--', $path)
 119             or return;
 120         my $line = $paths[0];
 121
 122         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
 123         $line =~ m/^([0-9]+) (.+) ($SHA1RE)\t/;
 124         return defined $type && $type ne $2
 125             ? ()
 126                 : $3;
 127     }
 128
 129     method list_revs ( NonEmptySimpleStr :$sha1!,
 130                        Int :$count?,
 131                        Int :$skip?,
 132                        HashRef :$search?,
 133                        NonEmptySimpleStr :$file? ) {
 134         $sha1 = $self->head_hash($sha1)
 135             if !$sha1 || $sha1 !~ $SHA1RE;
 136
 137         my @search_opts;
 138         if ($search and exists $search->{text}) {
 139             $search->{type} = 'grep'
 140                 if $search->{type} eq 'commit';
 141             @search_opts = (
 142                 # This seems a little fragile ...
 143                 qq[--$search->{type}=$search->{text}],
 144                 '--regexp-ignore-case',
 145                 $search->{regexp} ? '--extended-regexp' : '--fixed-strings'
 146             );
 147         }
 148
 149         my $output = $self->run_cmd(
 150             'rev-list',
 151             '--header',
 152             (defined $count ? "--max-count=$count" : ()),
 153             (defined $skip ? "--skip=$skip"       : ()),
 154             @search_opts,
 155             $sha1,
 156             '--',
 157             ($file ? $file : ()),
 158         );
 159         return unless $output;
 160
 161         my @revs = $self->_parse_rev_list($output);
 162
 163         return @revs;
 164     }
 165
 166     method snapshot (NonEmptySimpleStr :$sha1,
 167                  NonEmptySimpleStr :$format
 168                ) {
 169         # TODO - only valid formats are 'tar' and 'zip'
 170         my $formats = { tgz => 'tar', zip => 'zip' };
 171         unless ($formats->exists($format)) {
 172             die("No such format: $format");
 173         }
 174         $format = $formats->{$format};
 175         my $name = $self->name;
 176         $name =~ s,([^/])/*\.git$,$1,;
 177         my $filename = $name;
 178         $filename .= "-$sha1.$format";
 179         $name =~ s/\047/\047\\\047\047/g;
 180
 181         my @cmd = ('archive', "--format=$format", "--prefix=$name/", $sha1);
 182         return ($filename, $self->run_cmd_fh(@cmd));
 183         # TODO - support compressed archives
 184     }
 185
 186     method reflog (@logargs) {
 187         my @entries
 188             =  $self->run_cmd(qw(log -g), @logargs)
 189                 =~ /(^commit.+?(?:(?=^commit)|(?=\z)))/msg;
 190
 191         #  commit 02526fc15beddf2c64798a947fecdd8d11bf993d
 192         #  Reflog: HEAD@{14} (The Git Server <git@git.dev.venda.com>)
 193         #  Reflog message: push
 194         #  Author: Foo Barsby <fbarsby@example.com>
 195         #  Date:   Thu Sep 17 12:26:05 2009 +0100
 196         #
 197         #      Merge branch 'abc123'
 198
 199         return map {
 200             # XXX Stuff like this makes me want to switch to Git::PurePerl
 201             my($sha1, $type, $author, $date)
 202                 = m{
 203                        ^ commit \s+ ($SHA1RE)$
 204                        .*?
 205                        Reflog[ ]message: \s+ (.+?)$ \s+
 206                      Author: \s+ ([^<]+) <.*?$ \s+
 207                    Date: \s+ (.+?)$
 208                }xms;
 209
 210             pos($_) = index($_, $date) + length $date;
 211
 212             # Yeah, I just did that.
 213             my($msg) = /\G\s+(\S.*)/sg;
 214             {
 215                 hash    => $sha1,
 216                 type    => $type,
 217                 author  => $author,
 218
 219                 # XXX Add DateTime goodness.
 220                 date    => $date,
 221                 message => $msg,
 222             }
 223             ;
 224         } @entries;
 225     }
 226
 227     ## BUILDERS
 228     method _build_util {
 229         Gitalist::Git::Util->new(
 230             repository => $self,
 231         );
 232     }
 233
 234     method _build_description {
 235         my $description = "";
 236         eval {
 237             $description = $self->path->file('description')->slurp;
 238             chomp $description;
 239         };
 240         $description = "Unnamed repository, edit the .git/description file to set a description"
 241             if $description eq "Unnamed repository; edit this file 'description' to name the repository.";
 242         return $description;
 243     }
 244
 245     method _build_owner {
 246         my ($gecos, $name) = map { decode(langinfo(CODESET), $_) } (getpwuid $self->path->stat->uid)[6,0];
 247         $gecos =~ s/,+$//;
 248         return length($gecos) ? $gecos : $name;
 249     }
 250
 251     method _build_last_change {
 252         my $last_change;
 253         my $output = $self->run_cmd(
 254             qw{ for-each-ref --format=%(committer)
 255                 --sort=-committerdate --count=1 refs/heads
 256           });
 257         if (my ($epoch, $tz) = $output =~ /\s(\d+)\s+([+-]\d+)$/) {
 258             my $dt = DT->from_epoch(epoch => $epoch);
 259             $dt->set_time_zone($tz);
 260             $last_change = $dt;
 261         }
 262         return $last_change;
 263     }
 264
 265     method _build_heads {
 266         my @revlines = $self->run_cmd_list(qw/for-each-ref --sort=-committerdate /, '--format=%(objectname)%00%(refname)%00%(committer)', 'refs/heads');
 267         my @ret;
 268         for my $line (@revlines) {
 269             my ($rev, $head, $commiter) = split /\0/, $line, 3;
 270             $head =~ s!^refs/heads/!!;
 271
 272             push @ret, { sha1 => $rev, name => $head };
 273
 274             #FIXME: That isn't the time I'm looking for..
 275             if (my ($epoch, $tz) = $line =~ /\s(\d+)\s+([+-]\d+)$/) {
 276                 my $dt = DT->from_epoch(epoch => $epoch);
 277                 $dt->set_time_zone($tz);
 278                 $ret[-1]->{last_change} = $dt;
 279             }
 280         }
 281
 282         return \@ret;
 283     }
 284
 285     method _build_tags {
 286         my @revlines = $self->run_cmd_list('for-each-ref',
 287           '--sort=-creatordate',
 288           '--format=%(objectname) %(objecttype) %(refname) %(*objectname) %(*objecttype) %(subject)%00%(creator)',
 289           'refs/tags'
 290         );
 291         my @ret;
 292         for my $line (@revlines) {
 293             my($refinfo, $creatorinfo) = split /\0/, $line;
 294             my($rev, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
 295             my($creator, $epoch, $tz) = ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
 296             $name =~ s!^refs/tags/!!;
 297
 298             push @ret, { sha1 => $rev, name => $name };
 299
 300             #FIXME: That isn't the time I'm looking for..
 301             if($epoch and $tz) {
 302                 my $dt = DT->from_epoch(epoch => $epoch);
 303                 $dt->set_time_zone($tz);
 304                 $ret[-1]->{last_change} = $dt;
 305             }
 306         }
 307
 308         return \@ret;
 309     }
 310
 311     method _build_references {
 312         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
 313         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
 314         my @reflist = $self->run_cmd_list(qw(show-ref --dereference))
 315             or return;
 316         my %refs;
 317         for (@reflist) {
 318             push @{$refs{$1}}, $2
 319                 if m!^($SHA1RE)\srefs/(.*)$!;
 320         }
 321
 322         return \%refs;
 323     }
 324
 325     ## Private methods
 326     method _parse_rev_list ($output) {
 327         return
 328             map  $self->get_gpp_object($_),
 329                 grep is_SHA1($_),
 330                     map  split(/\n/, $_, 6), split /\0/, $output;
 331     }
 332
 333 } # end class
 334
 335 __END__
 336
 337 =head1 NAME
 338
 339 Gitalist::Git::Repository - Model of a git repository
 340
 341 =head1 SYNOPSIS
 342
 343     my $gitrepo = dir('/repo/base/Gitalist');
 344     my $repository = Gitalist::Git::Repository->new($gitrepo);
 345      $repository->name;        # 'Gitalist'
 346      $repository->path;        # '/repo/base/Gitalist/.git'
 347      $repository->description; # 'Unnamed repository.'
 348
 349 =head1 DESCRIPTION
 350
 351 This class models a git repository, referred to in Gitalist
 352 as a "Repository".
 353
 354
 355 =head1 ATTRIBUTES
 356
 357 =head2 name
 358
 359 The name of the Repository.  If unspecified, this will be derived from the path to the git repository.
 360
 361 =head2 path
 362
 363 L<Path::Class:Dir> for the filesystem path to the git repository.
 364
 365 =head2 description
 366
 367 The contents of .git/description.
 368
 369 =head2 owner
 370
 371 Owner of the files on the filesystem.
 372
 373 =head2 last_change
 374
 375 The L<DateTime> of the last modification of the repository.  This will be C<undef> if the repository has never been used.
 376
 377 =head2 is_bare
 378
 379 True if this is a bare git repository.
 380
 381 =head2 heads
 382
 383 =head2 tags
 384
 385 An array of the name and sha1 of all heads/tags in the repository.
 386
 387 =head2 references
 388
 389 Hashref of ArrayRefs for each reference.
 390
 391
 392 =head1 METHODS
 393
 394 =head2 head_hash ($head?)
 395
 396 Return the sha1 for HEAD, or any specified head.
 397
 398 =head2 list_tree ($sha1?)
 399
 400 Return an array of contents for a given tree.
 401 The tree is specified by sha1, and defaults to HEAD.
 402 Each item is a L<Gitalist::Git::Object>.
 403
 404 =head2 get_object ($sha1)
 405
 406 Return an appropriate subclass of L<Gitalist::Git::Object> for the given sha1.
 407
 408 =head2 hash_by_path ($sha1, $path, $type?)
 409
 410 Returns the sha1 for a given path, optionally limited by type.
 411
 412 =head2 list_revs ($sha1, $count?, $skip?, \%search?, $file?)
 413
 414 Returns a list of revs for the given head ($sha1).
 415
 416 =head2 snapshot ($sha1, $format)
 417
 418 Generate an archived snapshot of the repository.
 419 $sha1 should be a commit or tree.
 420 Returns a filehandle to read from.
 421
 422 =head2 diff ($commit, $patch?, $parent?, $file?)
 423
 424 Generate a diff from a given L<Gitalist::Git::Object>.
 425
 426 =head2 reflog (@lorgargs)
 427
 428 Return a list of hashes representing each reflog entry.
 429
 430 FIXME Should this return objects?
 431
 432
 433 =head1 SEE ALSO
 434
 435 L<Gitalist::Git::Util> L<Gitalist::Git::Object>
 436
 437
 438 =head1 AUTHORS
 439
 440 See L<Gitalist> for authors.
 441
 442 =head1 LICENSE
 443
 444 See L<Gitalist> for the license.
 445
 446 =cut