lib/Gitalist/Git/Repository.pm

   1 use MooseX::Declare;
   2
   3 class Gitalist::Git::Repository with Gitalist::Git::HasUtils {
   4     # FIXME, use Types::Path::Class and coerce
   5     use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
   6     use MooseX::Types::Path::Class qw/Dir/;
   7     use MooseX::Types::Moose qw/Str Maybe Bool HashRef ArrayRef/;
   8     use Gitalist::Git::Types qw/SHA1/;
   9     use Moose::Autobox;
  10     use List::MoreUtils qw/any zip/;
  11     use DateTime;
  12     use Encode qw/decode/;
  13     use I18N::Langinfo qw/langinfo CODESET/;
  14     use Gitalist::Git::Object::Blob;
  15     use Gitalist::Git::Object::Tree;
  16     use Gitalist::Git::Object::Commit;
  17     use Gitalist::Git::Object::Tag;
  18
  19     our $SHA1RE = qr/[0-9a-fA-F]{40}/;
  20
  21     around BUILDARGS (ClassName $class: Dir $dir) {
  22         # Allows us to be called as Repository->new($dir)
  23         # Last path component becomes $self->name
  24         # Full path to git objects becomes $self->path
  25         my $name = $dir->dir_list(-1);
  26         $dir = $dir->subdir('.git') if (-f $dir->file('.git', 'HEAD'));
  27         confess("Can't find a git repository at " . $dir)
  28             unless ( -f $dir->file('HEAD') );
  29         return $class->$orig(name => $name,
  30                              path => $dir);
  31     }
  32
  33     has name => ( isa => NonEmptySimpleStr,
  34                   is => 'ro', required => 1 );
  35
  36     has path => ( isa => Dir,
  37                   is => 'ro', required => 1);
  38
  39     has description => ( isa => Str,
  40                          is => 'ro',
  41                          lazy_build => 1,
  42                      );
  43
  44     has owner => ( isa => NonEmptySimpleStr,
  45                    is => 'ro',
  46                    lazy_build => 1,
  47                );
  48
  49     has last_change => ( isa => Maybe['DateTime'],
  50                          is => 'ro',
  51                          lazy_build => 1,
  52                      );
  53
  54     has is_bare => ( isa => Bool,
  55                      is => 'ro',
  56                      lazy => 1,
  57                      default => sub {
  58                          -d $_[0]->path->parent->subdir($_[0]->name)
  59                              ? 1 : 0
  60                          },
  61                      );
  62     has heads => ( isa => ArrayRef[HashRef],
  63                    is => 'ro',
  64                    lazy_build => 1);
  65     has tags => ( isa => ArrayRef[HashRef],
  66                    is => 'ro',
  67                    lazy_build => 1);
  68     has references => ( isa => HashRef[ArrayRef[Str]],
  69                         is => 'ro',
  70                         lazy_build => 1 );
  71
  72     method BUILD {
  73         $self->$_() for qw/last_change owner description /; # Ensure to build early.
  74     }
  75
  76     ## Public methods
  77
  78     method head_hash (Str $head?) {
  79         my $output = $self->run_cmd(qw/rev-parse --verify/, $head || 'HEAD' );
  80         confess("No such head: " . $head) unless defined $output;
  81
  82         my($sha1) = $output =~ /^($SHA1RE)$/;
  83         return $sha1;
  84     }
  85
  86     method get_object (NonEmptySimpleStr $sha1) {
  87         unless (is_SHA1($sha1)) {
  88             $sha1 = $self->head_hash($sha1);
  89         }
  90         my $type = $self->run_cmd('cat-file', '-t', $sha1);
  91         chomp($type);
  92         my $class = 'Gitalist::Git::Object::' . ucfirst($type);
  93         $class->new(
  94             repository => $self,
  95             sha1 => $sha1,
  96             type => $type,
  97         );
  98     }
  99
 100     method list_revs ( NonEmptySimpleStr :$sha1!,
 101                        Int :$count?,
 102                        Int :$skip?,
 103                        HashRef :$search?,
 104                        NonEmptySimpleStr :$file? ) {
 105         $sha1 = $self->head_hash($sha1)
 106             if !$sha1 || $sha1 !~ $SHA1RE;
 107
 108         my @search_opts;
 109         if ($search and exists $search->{text}) {
 110             $search->{type} = 'grep'
 111                 if $search->{type} eq 'commit';
 112             @search_opts = (
 113                 # This seems a little fragile ...
 114                 qq[--$search->{type}=$search->{text}],
 115                 '--regexp-ignore-case',
 116                 $search->{regexp} ? '--extended-regexp' : '--fixed-strings'
 117             );
 118         }
 119
 120         my $output = $self->run_cmd(
 121             'rev-list',
 122             '--header',
 123             (defined $count ? "--max-count=$count" : ()),
 124             (defined $skip ? "--skip=$skip"       : ()),
 125             @search_opts,
 126             $sha1,
 127             '--',
 128             ($file ? $file : ()),
 129         );
 130         return unless $output;
 131
 132         my @revs = $self->_parse_rev_list($output);
 133
 134         return @revs;
 135     }
 136
 137     method snapshot (NonEmptySimpleStr :$sha1,
 138                  NonEmptySimpleStr :$format
 139                ) {
 140         # TODO - only valid formats are 'tar' and 'zip'
 141         my $formats = { tgz => 'tar', zip => 'zip' };
 142         unless ($formats->exists($format)) {
 143             die("No such format: $format");
 144         }
 145         $format = $formats->{$format};
 146         my $name = $self->name;
 147         $name =~ s,([^/])/*\.git$,$1,;
 148         my $filename = $name;
 149         $filename .= "-$sha1.$format";
 150         $name =~ s/\047/\047\\\047\047/g;
 151
 152         my @cmd = ('archive', "--format=$format", "--prefix=$name/", $sha1);
 153         return ($filename, $self->run_cmd_fh(@cmd));
 154         # TODO - support compressed archives
 155     }
 156
 157     method reflog (@logargs) {
 158         my @entries
 159             =  $self->run_cmd(qw(log -g), @logargs)
 160                 =~ /(^commit.+?(?:(?=^commit)|(?=\z)))/msg;
 161
 162         #  commit 02526fc15beddf2c64798a947fecdd8d11bf993d
 163         #  Reflog: HEAD@{14} (The Git Server <git@git.dev.venda.com>)
 164         #  Reflog message: push
 165         #  Author: Foo Barsby <fbarsby@example.com>
 166         #  Date:   Thu Sep 17 12:26:05 2009 +0100
 167         #
 168         #      Merge branch 'abc123'
 169
 170         return map {
 171             # XXX Stuff like this makes me want to switch to Git::PurePerl
 172             my($sha1, $type, $author, $date)
 173                 = m{
 174                        ^ commit \s+ ($SHA1RE)$
 175                        .*?
 176                        Reflog[ ]message: \s+ (.+?)$ \s+
 177                      Author: \s+ ([^<]+) <.*?$ \s+
 178                    Date: \s+ (.+?)$
 179                }xms;
 180
 181             pos($_) = index($_, $date) + length $date;
 182
 183             # Yeah, I just did that.
 184             my($msg) = /\G\s+(\S.*)/sg;
 185             {
 186                 hash    => $sha1,
 187                 type    => $type,
 188                 author  => $author,
 189
 190                 # XXX Add DateTime goodness.
 191                 date    => $date,
 192                 message => $msg,
 193             }
 194             ;
 195         } @entries;
 196     }
 197
 198     ## BUILDERS
 199     method _build_util {
 200         Gitalist::Git::Util->new(
 201             repository => $self,
 202         );
 203     }
 204
 205     method _build_description {
 206         my $description = "";
 207         eval {
 208             $description = $self->path->file('description')->slurp;
 209             chomp $description;
 210         };
 211         $description = "Unnamed repository, edit the .git/description file to set a description"
 212             if $description eq "Unnamed repository; edit this file 'description' to name the repository.";
 213         return $description;
 214     }
 215
 216     method _build_owner {
 217         my ($gecos, $name) = map { decode(langinfo(CODESET), $_) } (getpwuid $self->path->stat->uid)[6,0];
 218         $gecos =~ s/,+$//;
 219         return length($gecos) ? $gecos : $name;
 220     }
 221
 222     method _build_last_change {
 223         my $last_change;
 224         my $output = $self->run_cmd(
 225             qw{ for-each-ref --format=%(committer)
 226                 --sort=-committerdate --count=1 refs/heads
 227           });
 228         if (my ($epoch, $tz) = $output =~ /\s(\d+)\s+([+-]\d+)$/) {
 229             my $dt = DateTime->from_epoch(epoch => $epoch);
 230             $dt->set_time_zone($tz);
 231             $last_change = $dt;
 232         }
 233         return $last_change;
 234     }
 235
 236     method _build_heads {
 237         my @revlines = $self->run_cmd_list(qw/for-each-ref --sort=-committerdate /, '--format=%(objectname)%00%(refname)%00%(committer)', 'refs/heads');
 238         my @ret;
 239         for my $line (@revlines) {
 240             my ($rev, $head, $commiter) = split /\0/, $line, 3;
 241             $head =~ s!^refs/heads/!!;
 242
 243             push @ret, { sha1 => $rev, name => $head };
 244
 245             #FIXME: That isn't the time I'm looking for..
 246             if (my ($epoch, $tz) = $line =~ /\s(\d+)\s+([+-]\d+)$/) {
 247                 my $dt = DateTime->from_epoch(epoch => $epoch);
 248                 $dt->set_time_zone($tz);
 249                 $ret[-1]->{last_change} = $dt;
 250             }
 251         }
 252
 253         return \@ret;
 254     }
 255
 256     method _build_tags {
 257         my @revlines = $self->run_cmd_list('for-each-ref',
 258           '--sort=-creatordate',
 259           '--format=%(objectname) %(objecttype) %(refname) %(*objectname) %(*objecttype) %(subject)%00%(creator)',
 260           'refs/tags'
 261         );
 262         my @ret;
 263         for my $line (@revlines) {
 264             my($refinfo, $creatorinfo) = split /\0/, $line;
 265             my($rev, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
 266             my($creator, $epoch, $tz) = ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
 267             $name =~ s!^refs/tags/!!;
 268
 269             push @ret, { sha1 => $rev, name => $name };
 270
 271             #FIXME: That isn't the time I'm looking for..
 272             if($epoch and $tz) {
 273                 my $dt = DateTime->from_epoch(epoch => $epoch);
 274                 $dt->set_time_zone($tz);
 275                 $ret[-1]->{last_change} = $dt;
 276             }
 277         }
 278
 279         return \@ret;
 280     }
 281
 282     method _build_references {
 283         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
 284         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
 285         my @reflist = $self->run_cmd_list(qw(show-ref --dereference))
 286             or return;
 287         my %refs;
 288         for (@reflist) {
 289             push @{$refs{$1}}, $2
 290                 if m!^($SHA1RE)\srefs/(.*)$!;
 291         }
 292
 293         return \%refs;
 294     }
 295
 296     ## Private methods
 297     method _parse_rev_list ($output) {
 298         return
 299             map  $self->get_gpp_object($_),
 300                 grep is_SHA1($_),
 301                     map  split(/\n/, $_, 6), split /\0/, $output;
 302     }
 303
 304 } # end class
 305
 306 __END__
 307
 308 =head1 NAME
 309
 310 Gitalist::Git::Repository - Model of a git repository
 311
 312 =head1 SYNOPSIS
 313
 314     my $gitrepo = dir('/repo/base/Gitalist');
 315     my $repository = Gitalist::Git::Repository->new($gitrepo);
 316      $repository->name;        # 'Gitalist'
 317      $repository->path;        # '/repo/base/Gitalist/.git'
 318      $repository->description; # 'Unnamed repository.'
 319
 320 =head1 DESCRIPTION
 321
 322 This class models a git repository, referred to in Gitalist
 323 as a "Repository".
 324
 325
 326 =head1 ATTRIBUTES
 327
 328 =head2 name
 329
 330 The name of the Repository.  If unspecified, this will be derived from the path to the git repository.
 331
 332 =head2 path
 333
 334 L<Path::Class:Dir> for the filesystem path to the git repository.
 335
 336 =head2 description
 337
 338 The contents of .git/description.
 339
 340 =head2 owner
 341
 342 Owner of the files on the filesystem.
 343
 344 =head2 last_change
 345
 346 The L<DateTime> of the last modification of the repository.  This will be C<undef> if the repository has never been used.
 347
 348 =head2 is_bare
 349
 350 True if this is a bare git repository.
 351
 352 =head2 heads
 353
 354 =head2 tags
 355
 356 An array of the name and sha1 of all heads/tags in the repository.
 357
 358 =head2 references
 359
 360 Hashref of ArrayRefs for each reference.
 361
 362
 363 =head1 METHODS
 364
 365 =head2 head_hash ($head?)
 366
 367 Return the sha1 for HEAD, or any specified head.
 368
 369 =head2 get_object ($sha1)
 370
 371 Return an appropriate subclass of L<Gitalist::Git::Object> for the given sha1.
 372
 373 =head2 list_revs ($sha1, $count?, $skip?, \%search?, $file?)
 374
 375 Returns a list of revs for the given head ($sha1).
 376
 377 =head2 snapshot ($sha1, $format)
 378
 379 Generate an archived snapshot of the repository.
 380 $sha1 should be a commit or tree.
 381 Returns a filehandle to read from.
 382
 383 =head2 diff ($commit, $patch?, $parent?, $file?)
 384
 385 Generate a diff from a given L<Gitalist::Git::Object>.
 386
 387 =head2 reflog (@lorgargs)
 388
 389 Return a list of hashes representing each reflog entry.
 390
 391 FIXME Should this return objects?
 392
 393
 394 =head1 SEE ALSO
 395
 396 L<Gitalist::Git::Util> L<Gitalist::Git::Object>
 397
 398
 399 =head1 AUTHORS
 400
 401 See L<Gitalist> for authors.
 402
 403 =head1 LICENSE
 404
 405 See L<Gitalist> for the license.
 406
 407 =cut