lib/Gitalist/Git/CollectionOfRepositories/FromDirectoryRecursive.pm

   1 use MooseX::Declare;
   2
   3 class Gitalist::Git::CollectionOfRepositories::FromDirectoryRecursive
   4     with Gitalist::Git::CollectionOfRepositories {
   5     use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
   6     use MooseX::Types::Path::Class qw/Dir/;
   7
   8     has repo_dir => (
   9         isa => Dir,
  10         is => 'ro',
  11         required => 1,
  12         coerce => 1,
  13     );
  14
  15     method BUILD {
  16         # Make sure repo_dir is an absolute path so that
  17         # ->contains() works correctly.
  18         $self->repo_dir->resolve;
  19     }
  20
  21     method _get_path_for_repository_name (NonEmptySimpleStr $name) {
  22       my $path = $self->repo_dir->subdir($name)->resolve;
  23       die "Directory traversal prohibited"
  24           unless $self->repo_dir->contains($path);
  25       return $path;
  26     }
  27
  28     ## Builders
  29     method _build_repositories {
  30       my @ret;
  31       my @git_dirs; #don't recurse in here
  32       $self->repo_dir->recurse(
  33         callback => sub {
  34           my ( $dir ) = @_;
  35           if ( $dir->is_dir ) {
  36             for my $already_gitted ( @git_dirs ) {
  37               # no need to go further if parent is git dir
  38               # never have a git repo in a git repo?
  39               return if ( $already_gitted->contains( $dir ) );
  40             }
  41             eval {
  42               # slight hack since get_repo expects string
  43               my @list = $dir->dir_list();
  44               my $p = $self->get_repository($list[$#list]);
  45               push @ret, $p;
  46               push @git_dirs, $dir;
  47             };
  48           }
  49           return;
  50         }
  51       );
  52       return \@ret;
  53     }
  54
  55 }                                # end class
  56
  57 __END__
  58
  59 =head1 NAME
  60
  61 Gitalist::Git::CollectionOfRepositories::FromDirectoryRecursive - Model of recursive directories containing git repositories
  62
  63 =head1 SYNOPSIS
  64
  65     my $repo = Gitalist::Git::CollectionOfRepositories::FromDirectoryRecursive->new( repo_dir => $Dir );
  66     my $repository_list = $repo->repositories;
  67     my $first_repository = $repository_list->[0];
  68     my $named_repository = $repo->get_repository('Gitalist');
  69
  70 =head1 DESCRIPTION
  71
  72 This class provides a list of Repositories recursively found in the given directory.
  73
  74 =head1 ATTRIBUTES
  75
  76 =head2 repo_dir (C<Path::Class::Dir>)
  77
  78 The filesystem root of the C<Repo>.
  79
  80 =head1 SEE ALSO
  81
  82 L<Gitalist::Git::CollectionOfRepositories>, L<Gitalist::Git::Repository>
  83
  84 =head1 AUTHORS
  85
  86 See L<Gitalist> for authors.
  87
  88 =head1 LICENSE
  89
  90 See L<Gitalist> for the license.
  91
  92 =cut