lib/Gitalist/Git/CollectionOfRepositories/FromDirectory.pm

   1 use MooseX::Declare;
   2
   3 class Gitalist::Git::CollectionOfRepositories::FromDirectory
   4     with Gitalist::Git::CollectionOfRepositories {
   5     use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
   6     use MooseX::Types::Path::Class qw/Dir/;
   7
   8     has repo_dir => (
   9         isa => Dir,
  10         is => 'ro',
  11         required => 1,
  12         coerce => 1,
  13     );
  14
  15     method BUILD {
  16         # Make sure repo_dir is an absolute path so that
  17         # ->contains() works correctly.
  18         $self->repo_dir->resolve;
  19     }
  20
  21     method _get_path_for_repository_name (NonEmptySimpleStr $name) {
  22         my $path = $self->repo_dir->subdir($name)->resolve;
  23         die "Directory traversal prohibited"
  24             unless $self->repo_dir->contains($path);
  25         return $path;
  26     }
  27
  28     method _get_repo_from_name (NonEmptySimpleStr $name) {
  29         return Gitalist::Git::Repository->new($self->_get_path_for_repository_name($name));
  30     }
  31
  32     ## Builders
  33     method _build_repositories {
  34         my $dh = $self->repo_dir->open || die "Could not open repo_dir";
  35         my @ret;
  36         while (my $dir_entry = $dh->read) {
  37             # try to get a repository for each entry in repo_dir
  38              eval {
  39                  my $p = $self->get_repository($dir_entry);
  40                  push @ret, $p;
  41             };
  42          }
  43         return \@ret;
  44     }
  45 }                               # end class
  46
  47 __END__
  48
  49 =head1 NAME
  50
  51 Gitalist::Git::CollectionOfRepositories::FromDirectory - Model of a directory containing git repositories
  52
  53 =head1 SYNOPSIS
  54
  55     my $repo = Gitalist::Git::CollectionOfRepositories::FromDirectory->new( repo_dir => $Dir );
  56     my $repository_list = $repo->repositories;
  57     my $first_repository = $repository_list->[0];
  58     my $named_repository = $repo->get_repository('Gitalist');
  59
  60 =head1 DESCRIPTION
  61
  62 This class provides a list of Repositories found in the given directory.
  63
  64 =head1 ATTRIBUTES
  65
  66 =head2 repo_dir (C<Path::Class::Dir>)
  67
  68 The filesystem root of the C<Repo>.
  69
  70 =head1 SEE ALSO
  71
  72 L<Gitalist::Git::CollectionOfRepositories>, L<Gitalist::Git::Repository>
  73
  74 =head1 AUTHORS
  75
  76 See L<Gitalist> for authors.
  77
  78 =head1 LICENSE
  79
  80 See L<Gitalist> for the license.
  81
  82 =cut