lib/Gitalist/Controller/Root.pm

   1 package Gitalist::Controller::Root;
   2 use Moose;
   3 use namespace::autoclean;
   4
   5 BEGIN { extends 'Catalyst::Controller' }
   6
   7 #
   8 # Sets the actions in this controller to be registered with no prefix
   9 # so they function identically to actions created in MyApp.pm
  10 #
  11 __PACKAGE__->config->{namespace} = '';
  12
  13 use IO::Capture::Stdout;
  14 use XML::Atom::Feed;
  15 use XML::Atom::Entry;
  16 use Sys::Hostname ();
  17
  18 =head1 NAME
  19
  20 Gitalist::Controller::Root - Root Controller for Gitalist
  21
  22 =head1 DESCRIPTION
  23
  24 [enter your description here]
  25
  26 =head1 METHODS
  27
  28 =cut
  29
  30 =head2 index
  31
  32 =cut
  33
  34 =head2 run_gitweb
  35
  36 The C<gitweb> shim. It should now only be explicitly accessible by
  37 modifying the URL.
  38
  39 =cut
  40
  41 sub run_gitweb {
  42   my ( $self, $c ) = @_;
  43
  44   # XXX A slippery slope to be sure.
  45   if($c->req->param('a')) {
  46     my $capture = IO::Capture::Stdout->new();
  47     $capture->start();
  48     eval {
  49       my $action = gitweb::main($c);
  50       $action->();
  51     };
  52     $capture->stop();
  53
  54     use Data::Dumper;
  55     die Dumper($@)
  56       if $@;
  57
  58     my $output = join '', $capture->read;
  59     $c->stash->{gitweb_output} = $output;
  60     $c->stash->{template} = 'gitweb.tt2';
  61   }
  62 }
  63
  64 sub _get_object {
  65   my($self, $c, $haveh) = @_;
  66
  67   my $h = $haveh || $c->req->param('h') || '';
  68   my $f = $c->req->param('f');
  69
  70   my $m = $c->stash->{Project};
  71   my $pd = $m->path;
  72
  73   # Either use the provided h(ash) parameter, the f(ile) parameter or just use HEAD.
  74   my $hash = ($h =~ /[^a-f0-9]/ ? $m->head_hash($h) : $h)
  75           || ($f && $m->hash_by_path($f))
  76           || $m->head_hash
  77           # XXX This could definitely use more context.
  78           || Carp::croak("Couldn't find a hash for the commit object!");
  79
  80   my $commit = $m->get_object($hash)
  81     or Carp::croak("Couldn't find a commit object for '$hash' in '$pd'!");
  82
  83   return $commit;
  84 }
  85
  86 =head2 index
  87
  88 Provides the project listing.
  89
  90 =cut
  91
  92 sub index :Path :Args(0) {
  93   my ( $self, $c ) = @_;
  94
  95   $c->detach($c->req->param('a'))
  96     if $c->req->param('a');
  97
  98   my @list = @{ $c->model()->projects };
  99   die 'No projects found in '. $c->model->repo_dir
 100     unless @list;
 101
 102   my $search = $c->req->param('s') || '';
 103   if($search) {
 104     @list = grep {
 105          index($_->name, $search) > -1
 106       or ( $_->description !~ /^Unnamed repository/ and index($_->description, $search) > -1 )
 107     } @list
 108   }
 109
 110   $c->stash(
 111     search_text => $search,
 112     projects    => \@list,
 113     action      => 'index',
 114   );
 115 }
 116
 117 =head2 summary
 118
 119 A summary of what's happening in the repo.
 120
 121 =cut
 122
 123 sub summary : Local {
 124   my ( $self, $c ) = @_;
 125   my $project = $c->stash->{Project};
 126   $c->detach('error_404') unless $project;
 127   my $commit = $self->_get_object($c);
 128   my @heads  = @{$project->heads};
 129   my $maxitems = Gitalist->config->{paging}{summary} || 10;
 130   $c->stash(
 131     commit    => $commit,
 132     log_lines => [$project->list_revs(
 133         sha1 => $commit->sha1,
 134         count => $maxitems,
 135     )],
 136     refs      => $project->references,
 137     heads     => [ @heads[0 .. ($#heads < $maxitems ? $#heads : $maxitems)] ],
 138     action    => 'summary',
 139   );
 140 }
 141
 142 =head2 heads
 143
 144 The current list of heads (aka branches) in the repo.
 145
 146 =cut
 147
 148 sub heads : Local {
 149   my ( $self, $c ) = @_;
 150   my $project = $c->stash->{Project};
 151   $c->stash(
 152     commit => $self->_get_object($c),
 153     heads  => $project->heads,
 154     action => 'heads',
 155   );
 156 }
 157
 158 =head2 blob
 159
 160 The blob action i.e the contents of a file.
 161
 162 =cut
 163
 164 sub blob : Local {
 165   my ( $self, $c ) = @_;
 166   my $project = $c->stash->{Project};
 167   my $h  = $c->req->param('h')
 168        || $project->hash_by_path($c->req->param('hb'), $c->req->param('f'))
 169        || die "No file or sha1 provided.";
 170   my $hb = $c->req->param('hb')
 171        || $project->head_hash
 172        || die "Couldn't discern the corresponding head.";
 173
 174   my $filename = $c->req->param('f') || '';
 175
 176   $c->stash(
 177     blob     => $project->get_object($h)->content,
 178     head     => $project->get_object($hb),
 179     filename => $filename,
 180     # XXX Hack hack hack, see View::SyntaxHighlight
 181     language => ($filename =~ /\.p[lm]$/ ? 'Perl' : ''),
 182     action   => 'blob',
 183   );
 184
 185   $c->forward('View::SyntaxHighlight')
 186     unless $c->stash->{no_wrapper};
 187 }
 188
 189 sub blob_plain : Local {
 190   my($self, $c) = @_;
 191
 192   $c->stash(no_wrapper => 1);
 193   $c->response->content_type('text/plain; charset=utf-8');
 194
 195   $c->forward('blob');
 196 }
 197
 198 sub blobdiff_plain : Local {
 199   my($self, $c) = @_;
 200
 201   $c->stash(no_wrapper => 1);
 202   $c->response->content_type('text/plain; charset=utf-8');
 203
 204   $c->forward('blobdiff');
 205
 206 }
 207
 208 =head2 blobdiff
 209
 210 Exposes a given diff of a blob.
 211
 212 =cut
 213
 214 sub blobdiff : Local {
 215   my ( $self, $c ) = @_;
 216   my $commit = $self->_get_object($c, $c->req->param('hb'));
 217   my $filename = $c->req->param('f')
 218               || croak("No file specified!");
 219   my($tree, $patch) = $c->stash->{Project}->diff(
 220     commit => $commit,
 221     patch  => 1,
 222     parent => $c->req->param('hpb') || undef,
 223     file   => $filename,
 224   );
 225   $c->stash(
 226     commit    => $commit,
 227     diff      => $patch,
 228     # XXX Hack hack hack, see View::SyntaxHighlight
 229     blobs     => [$patch->[0]->{diff}],
 230     language  => 'Diff',
 231     action    => 'blobdiff',
 232   );
 233
 234   $c->forward('View::SyntaxHighlight')
 235     unless $c->stash->{no_wrapper};
 236 }
 237
 238 =head2 commit
 239
 240 Exposes a given commit.
 241
 242 =cut
 243
 244 sub commit : Local {
 245   my ( $self, $c ) = @_;
 246   my $project = $c->stash->{Project};
 247   my $commit = $self->_get_object($c);
 248   $c->stash(
 249       commit      => $commit,
 250       diff_tree   => ($project->diff(commit => $commit))[0],
 251       refs      => $project->references,
 252       action      => 'commit',
 253   );
 254 }
 255
 256 =head2 commitdiff
 257
 258 Exposes a given diff of a commit.
 259
 260 =cut
 261
 262 sub commitdiff : Local {
 263   my ( $self, $c ) = @_;
 264   my $commit = $self->_get_object($c);
 265   my($tree, $patch) = $c->stash->{Project}->diff(
 266       commit => $commit,
 267       parent => $c->req->param('hp') || undef,
 268       patch  => 1,
 269   );
 270   $c->stash(
 271     commit    => $commit,
 272     diff_tree => $tree,
 273     diff      => $patch,
 274     # XXX Hack hack hack, see View::SyntaxHighlight
 275     blobs     => [map $_->{diff}, @$patch],
 276     language  => 'Diff',
 277     action    => 'commitdiff',
 278   );
 279
 280   $c->forward('View::SyntaxHighlight')
 281     unless $c->stash->{no_wrapper};
 282 }
 283
 284 sub commitdiff_plain : Local {
 285   my($self, $c) = @_;
 286
 287   $c->stash(no_wrapper => 1);
 288   $c->response->content_type('text/plain; charset=utf-8');
 289
 290   $c->forward('commitdiff');
 291 }
 292
 293 =head2 shortlog
 294
 295 Expose an abbreviated log of a given sha1.
 296
 297 =cut
 298
 299 sub shortlog : Local {
 300   my ( $self, $c ) = @_;
 301   my $project = $c->stash->{Project};
 302   my $commit  = $self->_get_object($c);
 303   my %logargs = (
 304       sha1   => $commit->sha1,
 305       count  => Gitalist->config->{paging}{log} || 25,
 306       ($c->req->param('f') ? (file => $c->req->param('f')) : ())
 307   );
 308
 309   my $page = $c->req->param('pg') || 0;
 310   $logargs{skip} = $c->req->param('pg') * $logargs{count}
 311     if $c->req->param('pg');
 312
 313   $c->stash(
 314       commit    => $commit,
 315       log_lines => [$project->list_revs(%logargs)],
 316       refs      => $project->references,
 317       action    => 'shortlog',
 318       page      => $page,
 319   );
 320 }
 321
 322 =head2 log
 323
 324 Calls shortlog internally. Perhaps that should be reversed ...
 325
 326 =cut
 327 sub log : Local {
 328     $_[0]->shortlog($_[1]);
 329     $_[1]->stash->{action} = 'log';
 330 }
 331
 332 # For legacy support.
 333 sub history : Local {
 334   $_[0]->shortlog(@_[1 .. $#_]);
 335 }
 336
 337 =head2 tree
 338
 339 The tree of a given commit.
 340
 341 =cut
 342
 343 sub tree : Local {
 344   my ( $self, $c ) = @_;
 345   my $project = $c->stash->{Project};
 346   my $commit  = $self->_get_object($c, $c->req->param('hb'));
 347   my $tree    = $self->_get_object($c, $c->req->param('h') || $commit->tree_sha1);
 348   $c->stash(
 349       commit    => $commit,
 350       tree      => $tree,
 351       tree_list => [$project->list_tree($tree->sha1)],
 352       path      => $c->req->param('f') || '',
 353       action    => 'tree',
 354   );
 355 }
 356
 357 =head2 reflog
 358
 359 Expose the local reflog. This may go away.
 360
 361 =cut
 362
 363 sub reflog : Local {
 364   my ( $self, $c ) = @_;
 365   my @log = $c->stash->{Project}->reflog(
 366       '--since=yesterday'
 367   );
 368
 369   $c->stash(
 370       log    => \@log,
 371       action => 'reflog',
 372   );
 373 }
 374
 375 sub search : Local {
 376   my($self, $c) = @_;
 377   $c->stash(current_action => 'GitRepos');
 378   my $project = $c->stash->{Project};
 379   my $commit  = $self->_get_object($c);
 380   # Lifted from /shortlog.
 381   my %logargs = (
 382     sha1   => $commit->sha1,
 383     count  => Gitalist->config->{paging}{log},
 384     ($c->req->param('f') ? (file => $c->req->param('f')) : ()),
 385     search => {
 386       type   => $c->req->param('type'),
 387       text   => $c->req->param('text'),
 388       regexp => $c->req->param('regexp') || 0,
 389     },
 390   );
 391
 392   $c->stash(
 393       commit  => $commit,
 394       results => [$project->list_revs(%logargs)],
 395       action  => 'search',
 396           # This could be added - page      => $page,
 397   );
 398 }
 399
 400 sub search_help : Local {
 401     my ($self, $c) = @_;
 402     $c->stash(template => 'search_help.tt2');
 403 }
 404
 405 sub atom : Local {
 406   my($self, $c) = @_;
 407
 408   my $feed = XML::Atom::Feed->new;
 409
 410   my $host = lc Sys::Hostname::hostname();
 411   $feed->title($host . ' - ' . Gitalist->config->{name});
 412   $feed->updated(~~DateTime->now);
 413
 414   my $project = $c->stash->{Project};
 415   my %logargs = (
 416       sha1   => $project->head_hash,
 417       count  => Gitalist->config->{paging}{log} || 25,
 418       ($c->req->param('f') ? (file => $c->req->param('f')) : ())
 419   );
 420
 421   my $mk_title = $c->stash->{short_cmt};
 422   for my $commit ($project->list_revs(%logargs)) {
 423     my $entry = XML::Atom::Entry->new;
 424     $entry->title( $mk_title->($commit->comment) );
 425     $entry->id($c->uri_for('commit', {h=>$commit->sha1}));
 426     # XXX Needs work ...
 427     $entry->content($commit->comment);
 428     $feed->add_entry($entry);
 429   }
 430
 431   $c->stash(
 432     feed       => $feed->as_xml,
 433     no_wrapper => 1,
 434   );
 435   $c->response->content_type('application/atom+xml')
 436 }
 437
 438 sub rss : Local {
 439     # FIXME - implement rss
 440     Carp::croak "Not implemented.";
 441 }
 442
 443 sub patch : Local {
 444     my ($self, $c) = @_;
 445     my $commit = $self->_get_object($c);
 446     my $parent = $c->req->param('hp') || undef;
 447     my $patch = $commit->patch( $parent );
 448     $c->response->body($patch);
 449     $c->response->content_type('text/plain');
 450     $c->response->status(200);
 451
 452 }
 453
 454 sub patches : Local {
 455     # FIXME - implement patches
 456     Carp::croak "Not implemented.";
 457 }
 458
 459 sub snapshot : Local {
 460     # FIXME - implement snapshot
 461     Carp::croak "Not implemented.";
 462 }
 463
 464 =head2 auto
 465
 466 Populate the header and footer. Perhaps not the best location.
 467
 468 =cut
 469
 470 sub auto : Private {
 471   my($self, $c) = @_;
 472
 473   # XXX Move these to a plugin!
 474   $c->stash(
 475     time_since => sub {
 476       return 'never' unless $_[0];
 477       return age_string(time - $_[0]->epoch);
 478     },
 479     short_cmt => sub {
 480       my $cmt = shift;
 481       my($line) = split /\n/, $cmt;
 482       $line =~ s/^(.{70,80}\b).*/$1 …/;
 483       return $line;
 484     },
 485     abridged_description => sub {
 486         join(' ', grep { defined } (split / /, shift)[0..10]);
 487     },
 488   );
 489
 490   # Yes, this is hideous.
 491   $self->header($c);
 492   $self->footer($c);
 493 }
 494
 495 # XXX This could probably be dropped altogether.
 496 use Gitalist::Util qw(to_utf8);
 497 # Formally git_header_html
 498 sub header {
 499   my($self, $c) = @_;
 500
 501   my $title = $c->config->{sitename};
 502
 503   my $project   = $c->req->param('project')  || $c->req->param('p');
 504   my $action    = $c->req->param('action')   || $c->req->param('a');
 505   my $file_name = $c->req->param('filename') || $c->req->param('f');
 506   if(defined $project) {
 507     $title .= " - " . to_utf8($project);
 508     if (defined $action) {
 509       $title .= "/$action";
 510       if (defined $file_name) {
 511         $title .= " - " . $file_name;
 512         if ($action eq "tree" && $file_name !~ m|/$|) {
 513           $title .= "/";
 514         }
 515       }
 516     }
 517   }
 518
 519   $c->stash->{version}     = $Gitalist::VERSION;
 520   # check git's version by running it on the first project in the list.
 521   $c->stash->{title}       = $title;
 522
 523   $c->stash->{stylesheet} = $c->config->{stylesheet} || 'gitweb.css';
 524
 525   $c->stash->{project} = $project;
 526   my @links;
 527   if($project) {
 528     my %href_params = $self->feed_info($c);
 529     $href_params{'-title'} ||= 'log';
 530
 531     foreach my $format qw(RSS Atom) {
 532       my $type = lc($format);
 533       push @links, {
 534         rel   => 'alternate',
 535         title => "$project - $href_params{'-title'} - $format feed",
 536
 537         # XXX A bit hacky and could do with using gitweb::href() features
 538         href  => "?a=$type;p=$project",
 539         type  => "application/$type+xml"
 540         }, {
 541         rel   => 'alternate',
 542
 543         # XXX This duplication also feels a bit awkward
 544         title => "$project - $href_params{'-title'} - $format feed (no merges)",
 545         href  => "?a=$type;p=$project;opt=--no-merges",
 546         type  => "application/$type+xml"
 547         };
 548     }
 549   } else {
 550     push @links, {
 551       rel => "alternate",
 552       title => $c->config->{sitename}." projects list",
 553       href => '?a=project_index',
 554       type => "text/plain; charset=utf-8"
 555       }, {
 556       rel => "alternate",
 557       title => $c->config->{sitename}." projects feeds",
 558       href => '?a=opml',
 559       type => "text/plain; charset=utf-8"
 560       };
 561   }
 562
 563   $c->stash->{favicon} = $c->config->{favicon};
 564
 565   # </head><body>
 566
 567   $c->stash(
 568     logo_url      => $c->config->{logo_url},
 569     logo_label    => $c->config->{logo_label},
 570     logo_img      => $c->config->{logo},
 571     home_link     => $c->config->{home_link},
 572     home_link_str => $c->config->{home_link_str},
 573     );
 574
 575   if (defined $project) {
 576       eval {
 577           $c->stash(Project => $c->model('GitRepos')->project($project));
 578       };
 579       if ($@) {
 580           $c->detach('error_404');
 581       }
 582       $c->stash(
 583           search_text => ( $c->req->param('s') ||
 584                                $c->req->param('searchtext') || ''),
 585           search_hash => ( $c->req->param('hb') || $c->req->param('hashbase')
 586                                || $c->req->param('h')  || $c->req->param('hash')
 587                                    || 'HEAD' ),
 588       );
 589   }
 590   my $a_project = $c->stash->{Project} || $c->model()->projects->[0];
 591   $c->stash->{git_version} = $a_project->run_cmd('--version');
 592 }
 593
 594 # Formally git_footer_html
 595 sub footer {
 596   my($self, $c) = @_;
 597
 598   my $feed_class = 'rss_logo';
 599
 600   my @feeds;
 601   my $project = $c->req->param('project')  || $c->req->param('p');
 602   if(defined $project) {
 603     (my $pstr = $project) =~ s[/?\.git$][];
 604     my $descr = $c->stash->{project_description}
 605             = $c->stash->{Project} ? $c->stash->{Project}->description : '';
 606
 607     my %href_params = $self->feed_info($c);
 608     if (!%href_params) {
 609       $feed_class .= ' generic';
 610     }
 611     $href_params{'-title'} ||= 'log';
 612
 613     @feeds = [
 614       map +{
 615         class => $feed_class,
 616         title => "$href_params{'-title'} $_ feed",
 617         href  => "/?p=$project;a=\L$_",
 618         name  => lc $_,
 619         }, qw(RSS Atom)
 620       ];
 621   } else {
 622     @feeds = [
 623       map {
 624         class => $feed_class,
 625           title => '',
 626           href  => "/?a=$_->[0]",
 627           name  => $_->[1],
 628         }, [opml=>'OPML'],[project_index=>'TXT'],
 629       ];
 630   }
 631 }
 632
 633 # XXX This feels wrong here, should probably be refactored.
 634 # returns hash to be passed to href to generate gitweb URL
 635 # in -title key it returns description of link
 636 sub feed_info {
 637   my($self, $c) = @_;
 638
 639   my $format = shift || 'Atom';
 640   my %res = (action => lc($format));
 641
 642   # feed links are possible only for project views
 643   return unless $c->req->param('project');
 644
 645   # some views should link to OPML, or to generic project feed,
 646   # or don't have specific feed yet (so they should use generic)
 647   return if $c->req->param('action') =~ /^(?:tags|heads|forks|tag|search)$/x;
 648
 649   my $branch;
 650   my $hash = $c->req->param('h')  || $c->req->param('hash');
 651   my $hash_base = $c->req->param('hb') || $c->req->param('hashbase');
 652
 653   # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
 654   # from tag links; this also makes possible to detect branch links
 655   if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
 656     (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
 657     $branch = $1;
 658   }
 659
 660   # find log type for feed description (title)
 661   my $type = 'log';
 662   my $file_name = $c->req->param('f') || $c->req->param('filename');
 663   if (defined $file_name) {
 664     $type  = "history of $file_name";
 665     $type .= "/" if $c->req->param('action') eq 'tree';
 666     $type .= " on '$branch'" if (defined $branch);
 667   } else {
 668     $type = "log of $branch" if (defined $branch);
 669   }
 670
 671   $res{-title} = $type;
 672   $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
 673   $res{'file_name'} = $file_name;
 674
 675   return %res;
 676 }
 677
 678 =head2 end
 679
 680 Attempt to render a view, if needed.
 681
 682 =cut
 683
 684 sub end : ActionClass('RenderView') {
 685     my ($self, $c) = @_;
 686     # Give project views the current HEAD.
 687     if ($c->stash->{Project}) {
 688         $c->stash->{HEAD} = $c->stash->{Project}->head_hash;
 689     }
 690 }
 691
 692 sub error_404 :Private {
 693     my ($self, $c) = @_;
 694     $c->response->status(404);
 695     $c->stash(
 696         title => 'Page not found',
 697         content => 'Page not found',
 698     );
 699 }
 700
 701 sub age_string {
 702         my $age = shift;
 703         my $age_str;
 704
 705         if ($age > 60*60*24*365*2) {
 706                 $age_str = (int $age/60/60/24/365);
 707                 $age_str .= " years ago";
 708         } elsif ($age > 60*60*24*(365/12)*2) {
 709                 $age_str = int $age/60/60/24/(365/12);
 710                 $age_str .= " months ago";
 711         } elsif ($age > 60*60*24*7*2) {
 712                 $age_str = int $age/60/60/24/7;
 713                 $age_str .= " weeks ago";
 714         } elsif ($age > 60*60*24*2) {
 715                 $age_str = int $age/60/60/24;
 716                 $age_str .= " days ago";
 717         } elsif ($age > 60*60*2) {
 718                 $age_str = int $age/60/60;
 719                 $age_str .= " hours ago";
 720         } elsif ($age > 60*2) {
 721                 $age_str = int $age/60;
 722                 $age_str .= " min ago";
 723         } elsif ($age > 2) {
 724                 $age_str = int $age;
 725                 $age_str .= " sec ago";
 726         } else {
 727                 $age_str .= " right now";
 728         }
 729         return $age_str;
 730 }
 731
 732 =head1 AUTHOR
 733
 734 Dan Brook
 735
 736 =head1 LICENSE
 737
 738 This library is free software. You can redistribute it and/or modify
 739 it under the same terms as Perl itself.
 740
 741 =cut
 742
 743 __PACKAGE__->meta->make_immutable;