lib/Gitalist/Controller/Root.pm

   1 package Gitalist::Controller::Root;
   2
   3 use Moose;
   4 use Moose::Autobox;
   5 use Sys::Hostname ();
   6 use XML::Atom::Feed;
   7 use XML::Atom::Entry;
   8 use XML::RSS;
   9 use XML::OPML::SimpleGen;
  10
  11 use Gitalist::Utils qw/ age_string /;
  12
  13 use namespace::autoclean;
  14
  15 BEGIN { extends 'Catalyst::Controller' }
  16
  17 __PACKAGE__->config->{namespace} = '';
  18
  19 sub root : Chained('/') PathPart('') CaptureArgs(0) {}
  20
  21 sub _get_object {
  22   my($self, $c, $haveh) = @_;
  23
  24   my $h = $haveh || $c->req->param('h') || '';
  25   my $f = $c->req->param('f');
  26
  27   my $m = $c->stash->{Repository};
  28   my $pd = $m->path;
  29
  30   # Either use the provided h(ash) parameter, the f(ile) parameter or just use HEAD.
  31   my $hash = ($h =~ /[^a-f0-9]/ ? $m->head_hash($h) : $h)
  32           || ($f && $m->hash_by_path($f))
  33           || $m->head_hash
  34           # XXX This could definitely use more context.
  35           || Carp::croak("Couldn't find a hash for the commit object!");
  36
  37   my $obj = $m->get_object($hash)
  38     or Carp::croak("Couldn't find a object for '$hash' in '$pd'!");
  39
  40   return $obj;
  41 }
  42
  43 sub index : Chained('base') PathPart('') Args(0) {
  44   my ( $self, $c ) = @_;
  45
  46   $c->detach($c->req->param('a'))
  47     if $c->req->param('a');
  48
  49   my @list = @{ $c->model()->repositories };
  50   die 'No repositories found in '. $c->model->repo_dir
  51     unless @list;
  52
  53   my $search = $c->req->param('s') || '';
  54   if($search) {
  55     @list = grep {
  56          index($_->name, $search) > -1
  57       or ( $_->description !~ /^Unnamed repository/ and index($_->description, $search) > -1 )
  58     } @list
  59   }
  60
  61   $c->stash(
  62     search_text => $search,
  63     repositories    => \@list,
  64     action      => 'index',
  65   );
  66 }
  67
  68 # FIXME - WTF is this for?
  69 sub repository_index : Chained('base') Args(0) {
  70   my ( $self, $c ) = @_;
  71
  72   my @list = @{ $c->model()->repositories };
  73   die 'No repositories found in '. $c->model->repo_dir
  74     unless @list;
  75
  76   $c->response->content_type('text/plain');
  77   $c->response->body(
  78     join "\n", map $_->name, @list
  79   );
  80   $c->response->status(200);
  81 }
  82 # FIXME - maintain compatibility with previous URI
  83 sub project_index : Chained('base') Args(0) {
  84     my ( $self, $c) = @_;
  85     $c->detach('repository_index');
  86 }
  87
  88 =head2 summary
  89
  90 A summary of what's happening in the repo.
  91
  92 =cut
  93
  94 sub summary : Chained('base') Args(0) {
  95   my ( $self, $c ) = @_;
  96   my $repository = $c->stash->{Repository};
  97   $c->detach('error_404') unless $repository;
  98   my $commit = $self->_get_object($c);
  99   my @heads  = @{$repository->heads};
 100   my $maxitems = Gitalist->config->{paging}{summary} || 10;
 101   $c->stash(
 102     commit    => $commit,
 103     log_lines => [$repository->list_revs(
 104         sha1 => $commit->sha1,
 105         count => $maxitems,
 106     )],
 107     refs      => $repository->references,
 108     heads     => [ @heads[0 .. ($#heads < $maxitems ? $#heads : $maxitems)] ],
 109     action    => 'summary',
 110   );
 111 }
 112
 113 =head2 heads
 114
 115 The current list of heads (aka branches) in the repo.
 116
 117 =cut
 118
 119 sub heads : Chained('base') Args(0) {
 120   my ( $self, $c ) = @_;
 121   my $repository = $c->stash->{Repository};
 122   $c->stash(
 123     commit => $self->_get_object($c),
 124     heads  => $repository->heads,
 125     action => 'heads',
 126   );
 127 }
 128
 129 =head2 tags
 130
 131 The current list of tags in the repo.
 132
 133 =cut
 134
 135 sub tags : Chained('base') Args(0) {
 136   my ( $self, $c ) = @_;
 137   my $repository = $c->stash->{Repository};
 138   $c->stash(
 139     commit => $self->_get_object($c),
 140     tags   => $repository->tags,
 141     action => 'tags',
 142   );
 143 }
 144
 145 sub blame : Chained('base') Args(0) {
 146   my($self, $c) = @_;
 147
 148   my $repository = $c->stash->{Repository};
 149   my $h  = $c->req->param('h')
 150        || $repository->hash_by_path($c->req->param('hb'), $c->req->param('f'))
 151        || die "No file or sha1 provided.";
 152   my $hb = $c->req->param('hb')
 153        || $repository->head_hash
 154        || die "Couldn't discern the corresponding head.";
 155   my $filename = $c->req->param('f') || '';
 156
 157   my $blame = $repository->get_object($hb)->blame($filename, $h);
 158   $c->stash(
 159     blame    => $blame,
 160     head     => $repository->get_object($hb),
 161     filename => $filename,
 162
 163     # XXX Hack hack hack, see View::SyntaxHighlight
 164     language => ($filename =~ /\.p[lm]$/i ? 'Perl' : ''),
 165     blob     => join("\n", map $_->{line}, @$blame),
 166   );
 167
 168   $c->forward('View::SyntaxHighlight')
 169     unless $c->stash->{no_wrapper};
 170 }
 171
 172 sub _blob_objs {
 173   my ( $self, $c ) = @_;
 174   my $repository = $c->stash->{Repository};
 175   my $h  = $c->req->param('h')
 176        || $repository->hash_by_path($c->req->param('hb'), $c->req->param('f'))
 177        || die "No file or sha1 provided.";
 178   my $hb = $c->req->param('hb')
 179        || $repository->head_hash
 180        || die "Couldn't discern the corresponding head.";
 181
 182   my $filename = $c->req->param('f') || '';
 183
 184   my $blob = $repository->get_object($h);
 185   $blob = $repository->get_object(
 186     $repository->hash_by_path($h || $hb, $filename)
 187   ) if $blob->type ne 'blob';
 188
 189   return $blob, $repository->get_object($hb), $filename;
 190 }
 191
 192 =head2 blob
 193
 194 The blob action i.e the contents of a file.
 195
 196 =cut
 197
 198 sub blob : Chained('base') Args(0) {
 199   my ( $self, $c ) = @_;
 200
 201   my($blob, $head, $filename) = $self->_blob_objs($c);
 202   $c->stash(
 203     blob     => $blob->content,
 204     head     => $head,
 205     filename => $filename,
 206     # XXX Hack hack hack, see View::SyntaxHighlight
 207     language => ($filename =~ /\.p[lm]$/i ? 'Perl' : ''),
 208     action   => 'blob',
 209   );
 210
 211   $c->forward('View::SyntaxHighlight')
 212     unless $c->stash->{no_wrapper};
 213 }
 214
 215 =head2 blob_plain
 216
 217 The plain text version of blob, where file is rendered as is.
 218
 219 =cut
 220
 221 sub blob_plain : Chained('base') Args(0) {
 222   my($self, $c) = @_;
 223
 224   my($blob) = $self->_blob_objs($c);
 225   $c->response->content_type('text/plain; charset=utf-8');
 226   $c->response->body($blob->content);
 227   $c->response->status(200);
 228 }
 229
 230 =head2 blobdiff_plain
 231
 232 The plain text version of blobdiff.
 233
 234 =cut
 235
 236 sub blobdiff_plain : Chained('base') Args(0) {
 237   my($self, $c) = @_;
 238
 239   $c->stash(no_wrapper => 1);
 240   $c->response->content_type('text/plain; charset=utf-8');
 241
 242   $c->forward('blobdiff');
 243 }
 244
 245 =head2 blobdiff
 246
 247 Exposes a given diff of a blob.
 248
 249 =cut
 250
 251 sub blobdiff : Chained('base') Args(0) {
 252   my ( $self, $c ) = @_;
 253   my $commit = $self->_get_object($c, $c->req->param('hb'));
 254   my $filename = $c->req->param('f')
 255               || croak("No file specified!");
 256   my($tree, $patch) = $c->stash->{Repository}->diff(
 257     commit => $commit,
 258     patch  => 1,
 259     parent => $c->req->param('hpb') || undef,
 260     file   => $filename,
 261   );
 262   $c->stash(
 263     commit    => $commit,
 264     diff      => $patch,
 265     filename  => $filename,
 266     # XXX Hack hack hack, see View::SyntaxHighlight
 267     blobs     => [$patch->[0]->{diff}],
 268     language  => 'Diff',
 269     action    => 'blobdiff',
 270   );
 271
 272   $c->forward('View::SyntaxHighlight')
 273     unless $c->stash->{no_wrapper};
 274 }
 275
 276 =head2 commit
 277
 278 Exposes a given commit.
 279
 280 =cut
 281
 282 sub commit : Chained('base') Args(0) {
 283   my ( $self, $c ) = @_;
 284   my $repository = $c->stash->{Repository};
 285   my $commit = $self->_get_object($c);
 286   $c->stash(
 287       commit      => $commit,
 288       diff_tree   => ($repository->diff(commit => $commit))[0],
 289       refs      => $repository->references,
 290       action      => 'commit',
 291   );
 292 }
 293
 294 =head2 commitdiff
 295
 296 Exposes a given diff of a commit.
 297
 298 =cut
 299
 300 sub commitdiff : Chained('base') Args(0) {
 301   my ( $self, $c ) = @_;
 302   my $commit = $self->_get_object($c);
 303   my($tree, $patch) = $c->stash->{Repository}->diff(
 304       commit => $commit,
 305       parent => $c->req->param('hp') || undef,
 306       patch  => 1,
 307   );
 308   $c->stash(
 309     commit    => $commit,
 310     diff_tree => $tree,
 311     diff      => $patch,
 312     # XXX Hack hack hack, see View::SyntaxHighlight
 313     blobs     => [map $_->{diff}, @$patch],
 314     language  => 'Diff',
 315     action    => 'commitdiff',
 316   );
 317
 318   $c->forward('View::SyntaxHighlight')
 319     unless $c->stash->{no_wrapper};
 320 }
 321
 322 sub commitdiff_plain : Chained('base') Args(0) {
 323   my($self, $c) = @_;
 324
 325   $c->stash(no_wrapper => 1);
 326   $c->response->content_type('text/plain; charset=utf-8');
 327
 328   $c->forward('commitdiff');
 329 }
 330
 331 =head2 shortlog
 332
 333 Expose an abbreviated log of a given sha1.
 334
 335 =cut
 336
 337 sub shortlog : Chained('base') Args(0) {
 338   my ( $self, $c ) = @_;
 339
 340   my $repository  = $c->stash->{Repository};
 341   my $commit   = $self->_get_object($c, $c->req->param('hb'));
 342   my $filename = $c->req->param('f') || '';
 343
 344   my %logargs = (
 345       sha1   => $commit->sha1,
 346       count  => Gitalist->config->{paging}{log} || 25,
 347       ($filename ? (file => $filename) : ())
 348   );
 349
 350   my $page = $c->req->param('pg') || 0;
 351   $logargs{skip} = $c->req->param('pg') * $logargs{count}
 352     if $c->req->param('pg');
 353
 354   $c->stash(
 355       commit    => $commit,
 356       log_lines => [$repository->list_revs(%logargs)],
 357       refs      => $repository->references,
 358       page      => $page,
 359       filename  => $filename,
 360       action    => 'shortlog',
 361   );
 362 }
 363
 364 =head2 log
 365
 366 Calls shortlog internally. Perhaps that should be reversed ...
 367
 368 =cut
 369
 370 sub log : Chained('base') Args(0) {
 371     $_[0]->shortlog($_[1]);
 372     $_[1]->stash->{action} = 'log';
 373 }
 374
 375 # For legacy support.
 376 sub history : Chained('base') Args(0) {
 377     my ( $self, $c ) = @_;
 378     $self->shortlog($c);
 379     my $repository = $c->stash->{Repository};
 380     my $file = $repository->get_object(
 381         $repository->hash_by_path(
 382             $repository->head_hash,
 383             $c->stash->{filename}
 384         )
 385     );
 386      $c->stash( action => 'history',
 387                filetype => $file->type,
 388            );
 389 }
 390
 391 =head2 tree
 392
 393 The tree of a given commit.
 394
 395 =cut
 396
 397 sub tree : Chained('base') Args(0) {
 398   my ( $self, $c ) = @_;
 399   my $repository = $c->stash->{Repository};
 400   my $commit  = $self->_get_object($c, $c->req->param('hb'));
 401   my $filename = $c->req->param('f') || '';
 402   my $tree    = $filename
 403     ? $repository->get_object($repository->hash_by_path($commit->sha1, $filename))
 404     : $repository->get_object($commit->tree_sha1)
 405   ;
 406   $c->stash(
 407       commit    => $commit,
 408       tree      => $tree,
 409       tree_list => [$repository->list_tree($tree->sha1)],
 410       path      => $c->req->param('f') || '',
 411       action    => 'tree',
 412   );
 413 }
 414
 415 =head2 reflog
 416
 417 Expose the local reflog. This may go away.
 418
 419 =cut
 420
 421 sub reflog : Chained('base') Args(0) {
 422   my ( $self, $c ) = @_;
 423   my @log = $c->stash->{Repository}->reflog(
 424       '--since=yesterday'
 425   );
 426
 427   $c->stash(
 428       log    => \@log,
 429       action => 'reflog',
 430   );
 431 }
 432
 433 =head2 search
 434
 435 The action for the search form.
 436
 437 =cut
 438
 439 sub search : Chained('base') Args(0) {
 440   my($self, $c) = @_;
 441   $c->stash(current_action => 'GitRepos');
 442   my $repository = $c->stash->{Repository};
 443   my $commit  = $self->_get_object($c);
 444   # Lifted from /shortlog.
 445   my %logargs = (
 446     sha1   => $commit->sha1,
 447     count  => Gitalist->config->{paging}{log},
 448     ($c->req->param('f') ? (file => $c->req->param('f')) : ()),
 449     search => {
 450       type   => $c->req->param('type'),
 451       text   => $c->req->param('text'),
 452       regexp => $c->req->param('regexp') || 0,
 453     },
 454   );
 455
 456   $c->stash(
 457       commit  => $commit,
 458       results => [$repository->list_revs(%logargs)],
 459       action  => 'search',
 460           # This could be added - page      => $page,
 461   );
 462 }
 463
 464 =head2 search_help
 465
 466 Provides some help for the search form.
 467
 468 =cut
 469
 470 sub search_help : Chained('base') Args(0) {
 471     my ($self, $c) = @_;
 472     $c->stash(template => 'search_help.tt2');
 473 }
 474
 475 =head2 atom
 476
 477 Provides an atom feed for a given repository.
 478
 479 =cut
 480
 481 sub atom : Chained('base') Args(0) {
 482   my($self, $c) = @_;
 483
 484   my $feed = XML::Atom::Feed->new;
 485
 486   my $host = lc Sys::Hostname::hostname();
 487   $feed->title($host . ' - ' . Gitalist->config->{name});
 488   $feed->updated(~~DateTime->now);
 489
 490   my $repository = $c->stash->{Repository};
 491   my %logargs = (
 492       sha1   => $repository->head_hash,
 493       count  => Gitalist->config->{paging}{log} || 25,
 494       ($c->req->param('f') ? (file => $c->req->param('f')) : ())
 495   );
 496
 497   my $mk_title = $c->stash->{short_cmt};
 498   for my $commit ($repository->list_revs(%logargs)) {
 499     my $entry = XML::Atom::Entry->new;
 500     $entry->title( $mk_title->($commit->comment) );
 501     $entry->id($c->uri_for('commit', {h=>$commit->sha1}));
 502     # XXX Needs work ...
 503     $entry->content($commit->comment);
 504     $feed->add_entry($entry);
 505   }
 506
 507   $c->response->body($feed->as_xml);
 508   $c->response->content_type('application/atom+xml');
 509   $c->response->status(200);
 510 }
 511
 512 =head2 rss
 513
 514 Provides an RSS feed for a given repository.
 515
 516 =cut
 517
 518 sub rss : Chained('base') Args(0) {
 519   my ($self, $c) = @_;
 520
 521   my $repository = $c->stash->{Repository};
 522
 523   my $rss = XML::RSS->new(version => '2.0');
 524   $rss->channel(
 525     title          => lc(Sys::Hostname::hostname()) . ' - ' . Gitalist->config->{name},
 526     link           => $c->uri_for('summary', {p=>$repository->name}),
 527     language       => 'en',
 528     description    => $repository->description,
 529     pubDate        => DateTime->now,
 530     lastBuildDate  => DateTime->now,
 531   );
 532
 533   my %logargs = (
 534       sha1   => $repository->head_hash,
 535       count  => Gitalist->config->{paging}{log} || 25,
 536       ($c->req->param('f') ? (file => $c->req->param('f')) : ())
 537   );
 538   my $mk_title = $c->stash->{short_cmt};
 539   for my $commit ($repository->list_revs(%logargs)) {
 540     # XXX Needs work ....
 541     $rss->add_item(
 542         title       => $mk_title->($commit->comment),
 543         permaLink   => $c->uri_for(commit => {h=>$commit->sha1}),
 544         description => $commit->comment,
 545     );
 546   }
 547
 548   $c->response->body($rss->as_string);
 549   $c->response->content_type('application/rss+xml');
 550   $c->response->status(200);
 551 }
 552
 553 sub opml : Chained('base') Args(0) {
 554   my($self, $c) = @_;
 555
 556   my $opml = XML::OPML::SimpleGen->new();
 557
 558   $opml->head(title => lc(Sys::Hostname::hostname()) . ' - ' . Gitalist->config->{name});
 559
 560   my @list = @{ $c->model()->repositories };
 561   die 'No repositories found in '. $c->model->repo_dir
 562     unless @list;
 563
 564   for my $proj ( @list ) {
 565     $opml->insert_outline(
 566       text   => $proj->name. ' - '. $proj->description,
 567       xmlUrl => $c->uri_for(rss => {p => $proj->name}),
 568     );
 569   }
 570
 571   $c->response->body($opml->as_string);
 572   $c->response->content_type('application/rss');
 573   $c->response->status(200);
 574 }
 575
 576 =head2 patch
 577
 578 A raw patch for a given commit.
 579
 580 =cut
 581
 582 sub patch : Chained('base') Args(0) {
 583     my ($self, $c) = @_;
 584     $c->detach('patches', [1]);
 585 }
 586
 587 =head2 patches
 588
 589 The patcheset for a given commit ???
 590
 591 =cut
 592
 593 sub patches : Chained('base') Args(0) {
 594     my ($self, $c, $count) = @_;
 595     $count ||= Gitalist->config->{patches}{max};
 596     my $commit = $self->_get_object($c);
 597     my $parent = $c->req->param('hp') || undef;
 598     my $patch = $commit->get_patch( $parent, $count );
 599     $c->response->body($patch);
 600     $c->response->content_type('text/plain');
 601     $c->response->status(200);
 602 }
 603
 604 =head2 snapshot
 605
 606 Provides a snapshot of a given commit.
 607
 608 =cut
 609
 610 sub snapshot : Chained('base') Args(0) {
 611     my ($self, $c) = @_;
 612     my $format = $c->req->param('sf') || 'tgz';
 613     die unless $format;
 614     my $sha1 = $c->req->param('h') || $self->_get_object($c)->sha1;
 615     my @snap = $c->stash->{Repository}->snapshot(
 616         sha1 => $sha1,
 617         format => $format
 618     );
 619     $c->response->status(200);
 620     $c->response->headers->header( 'Content-Disposition' =>
 621                                        "attachment; filename=$snap[0]");
 622     $c->response->body($snap[1]);
 623 }
 624
 625
 626 sub base : Chained('/root') PathPart('') CaptureArgs(0) {
 627   my($self, $c) = @_;
 628
 629   my $repository = $c->req->param('p');
 630   if (defined $repository) {
 631     eval {
 632       $c->stash(Repository => $c->model('GitRepos')->get_repository($repository));
 633     };
 634     if ($@) {
 635       $c->detach('/error_404');
 636     }
 637   }
 638
 639   my $a_repository = $c->stash->{Repository} || $c->model()->repositories->[0];
 640   $c->stash(
 641     git_version => $a_repository->run_cmd('--version'),
 642     version     => $Gitalist::VERSION,
 643
 644     # XXX Move these to a plugin!
 645     time_since => sub {
 646       return 'never' unless $_[0];
 647       return age_string(time - $_[0]->epoch);
 648     },
 649     short_cmt => sub {
 650       my $cmt = shift;
 651       my($line) = split /\n/, $cmt;
 652       $line =~ s/^(.{70,80}\b).*/$1 \x{2026}/;
 653       return $line;
 654     },
 655     abridged_description => sub {
 656         join(' ', grep { defined } (split / /, shift)[0..10]);
 657     },
 658   );
 659 }
 660
 661 sub end : ActionClass('RenderView') {
 662     my ($self, $c) = @_;
 663     # Give repository views the current HEAD.
 664     if ($c->stash->{Repository}) {
 665         $c->stash->{HEAD} = $c->stash->{Repository}->head_hash;
 666     }
 667 }
 668
 669 sub error_404 : Action {
 670     my ($self, $c) = @_;
 671     $c->response->status(404);
 672     $c->response->body('Page not found');
 673 }
 674
 675 __PACKAGE__->meta->make_immutable;
 676
 677 __END__
 678
 679 =head1 NAME
 680
 681 Gitalist::Controller::Root - Root controller for the application
 682
 683 =head1 DESCRIPTION
 684
 685 This controller handles all of the root level paths for the application
 686
 687 =head1 METHODS
 688
 689 =head2 root
 690
 691 Root of chained actions
 692
 693 =head2 base
 694
 695 Populate the header and footer. Perhaps not the best location.
 696
 697 =head2 index
 698
 699 Provides the repository listing.
 700
 701 =head2 end
 702
 703 Attempt to render a view, if needed.
 704
 705 =head2 blame
 706
 707 =head2 commitdiff_plain
 708
 709 =head2 error_404
 710
 711 =head2 history
 712
 713 =head2 opml
 714
 715 =head2 repository_index
 716
 717 =head1 AUTHORS
 718
 719 See L<Gitalist> for authors.
 720
 721 =head1 LICENSE
 722
 723 See L<Gitalist> for the license.
 724
 725 =cut