lib/Gitalist/Controller/Root.pm

   1 package Gitalist::Controller::Root;
   2 use Moose;
   3 use namespace::autoclean;
   4
   5 BEGIN { extends 'Catalyst::Controller' }
   6
   7 #
   8 # Sets the actions in this controller to be registered with no prefix
   9 # so they function identically to actions created in MyApp.pm
  10 #
  11 __PACKAGE__->config->{namespace} = '';
  12
  13 =head1 NAME
  14
  15 Gitalist::Controller::Root - Root Controller for Gitalist
  16
  17 =head1 DESCRIPTION
  18
  19 [enter your description here]
  20
  21 =head1 METHODS
  22
  23 =cut
  24
  25 =head2 index
  26
  27 =cut
  28
  29 use IO::Capture::Stdout;
  30
  31 =head2 run_gitweb
  32
  33 The C<gitweb> shim. It should now only be explicitly accessible by
  34 modifying the URL.
  35
  36 =cut
  37
  38 sub run_gitweb {
  39   my ( $self, $c ) = @_;
  40
  41   # XXX A slippery slope to be sure.
  42   if($c->req->param('a')) {
  43     my $capture = IO::Capture::Stdout->new();
  44     $capture->start();
  45     eval {
  46       my $action = gitweb::main($c);
  47       $action->();
  48     };
  49     $capture->stop();
  50
  51     use Data::Dumper;
  52     die Dumper($@)
  53       if $@;
  54
  55     my $output = join '', $capture->read;
  56     $c->stash->{gitweb_output} = $output;
  57     $c->stash->{template} = 'gitweb.tt2';
  58   }
  59 }
  60
  61 sub _get_object {
  62   my($self, $c, $haveh) = @_;
  63
  64   my $h = $haveh || $c->req->param('h') || '';
  65   my $f = $c->req->param('f');
  66
  67   my $m = $c->stash->{Project};
  68   my $pd = $m->path;
  69
  70   # Either use the provided h(ash) parameter, the f(ile) parameter or just use HEAD.
  71   my $hash = ($h =~ /[^a-f0-9]/ ? $m->head_hash($h) : $h)
  72           || ($f && $m->hash_by_path($f))
  73           || $m->head_hash
  74           # XXX This could definitely use more context.
  75           || Carp::croak("Couldn't find a hash for the commit object!");
  76
  77   my $commit = $m->get_object($hash)
  78     or Carp::croak("Couldn't find a commit object for '$hash' in '$pd'!");
  79
  80   return $commit;
  81 }
  82
  83 =head2 index
  84
  85 Provides the project listing.
  86
  87 =cut
  88
  89 sub index :Path :Args(0) {
  90   my ( $self, $c ) = @_;
  91
  92   $c->detach($c->req->param('a'))
  93     if $c->req->param('a');
  94
  95   my @list = @{ $c->model()->projects };
  96   die 'No projects found in '. $c->model->repo_dir
  97     unless @list;
  98
  99   my $search = $c->req->param('s') || '';
 100   if($search) {
 101     @list = grep {
 102          index($_->name, $search) > -1
 103       or ( $_->description !~ /^Unnamed repository/ and index($_->description, $search) > -1 )
 104     } @list
 105   }
 106
 107   $c->stash(
 108     search_text => $search,
 109     projects    => \@list,
 110     action      => 'index',
 111   );
 112 }
 113
 114 =head2 summary
 115
 116 A summary of what's happening in the repo.
 117
 118 =cut
 119
 120 sub summary : Local {
 121   my ( $self, $c ) = @_;
 122   my $project = $c->stash->{Project};
 123   $c->detach('error_404') unless $project;
 124   my $commit = $self->_get_object($c);
 125   my @heads  = @{$project->heads};
 126   my $maxitems = Gitalist->config->{paging}{summary} || 10;
 127   $c->stash(
 128     commit    => $commit,
 129     info      => $project->info,
 130     log_lines => [$project->list_revs(
 131         sha1 => $commit->sha1,
 132         count => $maxitems,
 133     )],
 134     refs      => $project->references,
 135     heads     => [ @heads[0 .. ($#heads < $maxitems ? $#heads : $maxitems)] ],
 136     action    => 'summary',
 137   );
 138 }
 139
 140 =head2 heads
 141
 142 The current list of heads (aka branches) in the repo.
 143
 144 =cut
 145
 146 sub heads : Local {
 147   my ( $self, $c ) = @_;
 148   my $project = $c->stash->{Project};
 149   $c->stash(
 150     commit => $self->_get_object($c),
 151     heads  => $project->heads,
 152     action => 'heads',
 153   );
 154 }
 155
 156 =head2 blob
 157
 158 The blob action i.e the contents of a file.
 159
 160 =cut
 161
 162 sub blob : Local {
 163   my ( $self, $c ) = @_;
 164   my $project = $c->stash->{Project};
 165   my $h  = $c->req->param('h')
 166        || $project->hash_by_path($c->req->param('hb'), $c->req->param('f'))
 167        || die "No file or sha1 provided.";
 168   my $hb = $c->req->param('hb')
 169        || $project->head_hash
 170        || die "Couldn't discern the corresponding head.";
 171
 172   my $filename = $c->req->param('f') || '';
 173
 174   $c->stash(
 175     blob     => $project->get_object($h)->content,
 176     head     => $project->get_object($hb),
 177     filename => $filename,
 178     # XXX Hack hack hack, see View::SyntaxHighlight
 179     language => ($filename =~ /\.p[lm]$/ ? 'Perl' : ''),
 180     action   => 'blob',
 181   );
 182
 183   $c->forward('View::SyntaxHighlight');
 184 }
 185
 186 =head2 blobdiff
 187
 188 Exposes a given diff of a blob.
 189
 190 =cut
 191
 192 sub blobdiff : Local {
 193   my ( $self, $c ) = @_;
 194   my $commit = $self->_get_object($c, $c->req->param('hb'));
 195   my $filename = $c->req->param('f')
 196               || croak("No file specified!");
 197   my($tree, $patch) = $c->stash->{Project}->diff(
 198     commit => $commit,
 199     parent => $c->req->param('hpb') || '',
 200     file   => $filename,
 201     patch  => 1,
 202   );
 203   $c->stash(
 204     commit    => $commit,
 205     diff      => $patch,
 206     # XXX Hack hack hack, see View::SyntaxHighlight
 207     blobs     => [$patch->[0]->{diff}],
 208     language  => 'Diff',
 209     action    => 'blobdiff',
 210   );
 211
 212   $c->forward('View::SyntaxHighlight');
 213 }
 214
 215 =head2 commit
 216
 217 Exposes a given commit.
 218
 219 =cut
 220
 221 sub commit : Local {
 222   my ( $self, $c ) = @_;
 223   my $project = $c->stash->{Project};
 224   my $commit = $self->_get_object($c);
 225   $c->stash(
 226       commit      => $commit,
 227       diff_tree   => ($project->diff(commit => $commit))[0],
 228       refs      => $project->references,
 229       action      => 'commit',
 230   );
 231 }
 232
 233 =head2 commitdiff
 234
 235 Exposes a given diff of a commit.
 236
 237 =cut
 238
 239 sub commitdiff : Local {
 240   my ( $self, $c ) = @_;
 241   my $commit = $self->_get_object($c);
 242   my($tree, $patch) = $c->stash->{Project}->diff(
 243       commit => $commit,
 244       parent => $c->req->param('hp') || undef,
 245       patch  => 1,
 246   );
 247   $c->stash(
 248     commit    => $commit,
 249     diff_tree => $tree,
 250     diff      => $patch,
 251     # XXX Hack hack hack, see View::SyntaxHighlight
 252     blobs     => [map $_->{diff}, @$patch],
 253     language  => 'Diff',
 254     action    => 'commitdiff',
 255   );
 256
 257   $c->forward('View::SyntaxHighlight');
 258 }
 259
 260 =head2 shortlog
 261
 262 Expose an abbreviated log of a given sha1.
 263
 264 =cut
 265
 266 sub shortlog : Local {
 267   my ( $self, $c ) = @_;
 268   my $project = $c->stash->{Project};
 269   my $commit  = $self->_get_object($c);
 270   my %logargs = (
 271       sha1   => $commit->sha1,
 272       count  => Gitalist->config->{paging}{log} || 25,
 273       ($c->req->param('f') ? (file => $c->req->param('f')) : ())
 274   );
 275
 276   my $page = $c->req->param('pg') || 0;
 277   $logargs{skip} = $c->req->param('pg') * $logargs{count}
 278     if $c->req->param('pg');
 279
 280   $c->stash(
 281       commit    => $commit,
 282       log_lines => [$project->list_revs(%logargs)],
 283       refs      => $project->references,
 284       action    => 'shortlog',
 285       page      => $page,
 286   );
 287 }
 288
 289 =head2 log
 290
 291 Calls shortlog internally. Perhaps that should be reversed ...
 292
 293 =cut
 294 sub log : Local {
 295     $_[0]->shortlog($_[1]);
 296     $_[1]->stash->{action} = 'log';
 297 }
 298
 299 =head2 tree
 300
 301 The tree of a given commit.
 302
 303 =cut
 304
 305 sub tree : Local {
 306   my ( $self, $c ) = @_;
 307   my $project = $c->stash->{Project};
 308   my $commit  = $self->_get_object($c, $c->req->param('hb'));
 309   my $tree    = $self->_get_object($c, $c->req->param('h') || $commit->tree_sha1);
 310   $c->stash(
 311       commit    => $commit,
 312       tree      => $tree,
 313       tree_list => [$project->list_tree($tree->sha1)],
 314       path      => $c->req->param('f') || '',
 315       action    => 'tree',
 316   );
 317 }
 318
 319 =head2 reflog
 320
 321 Expose the local reflog. This may go away.
 322
 323 =cut
 324
 325 sub reflog : Local {
 326   my ( $self, $c ) = @_;
 327   my @log = $c->stash->{Project}->reflog(
 328       '--since=yesterday'
 329   );
 330
 331   $c->stash(
 332       log    => \@log,
 333       action => 'reflog',
 334   );
 335 }
 336
 337 sub search : Local {
 338   my($self, $c) = @_;
 339   $c->stash(current_action => 'GitRepos');
 340   my $project = $c->stash->{Project};
 341   my $commit  = $self->_get_object($c);
 342   # Lifted from /shortlog.
 343   my %logargs = (
 344     sha1   => $commit->sha1,
 345     count  => Gitalist->config->{paging}{log},
 346     ($c->req->param('f') ? (file => $c->req->param('f')) : ()),
 347         search => {
 348           type   => $c->req->param('type'),
 349           text   => $c->req->param('text'),
 350           regexp => $c->req->param('regexp') || 0,
 351     }
 352   );
 353
 354   $c->stash(
 355       commit  => $commit,
 356       results => [$project->list_revs(%logargs)],
 357       action  => 'search',
 358           # This could be added - page      => $page,
 359   );
 360 }
 361
 362 sub search_help : Local {
 363     # FIXME - implement search_help
 364     Carp::croak "Not implemented.";
 365 }
 366
 367 sub atom : Local {
 368     # FIXME - implement atom
 369     Carp::croak "Not implemented.";
 370 }
 371
 372 sub rss : Local {
 373     # FIXME - implement rss
 374     Carp::croak "Not implemented.";
 375 }
 376
 377 sub blobdiff_plain : Local {
 378     # FIXME - implement blobdiff_plain
 379     Carp::croak "Not implemented.";
 380 }
 381
 382 sub blob_plain : Local {
 383     # FIXME - implement blobdiff_plain
 384     Carp::croak "Not implemented.";
 385 }
 386
 387 sub patch : Local {
 388     # FIXME - implement patches
 389     Carp::croak "Not implemented.";
 390 }
 391
 392 sub patches : Local {
 393     # FIXME - implement patches
 394     Carp::croak "Not implemented.";
 395 }
 396
 397 sub snapshot : Local {
 398     # FIXME - implement snapshot
 399     Carp::croak "Not implemented.";
 400 }
 401
 402 sub commitdiff_plain : Local {
 403     # FIXME - implement commitdiff_plain
 404     Carp::croak "Not implemented.";
 405 }
 406
 407 =head2 auto
 408
 409 Populate the header and footer. Perhaps not the best location.
 410
 411 =cut
 412
 413 sub auto : Private {
 414   my($self, $c) = @_;
 415
 416   # XXX Move these to a plugin!
 417   $c->stash(
 418     time_since => sub {
 419       return 'never' unless $_[0];
 420       return age_string(time - $_[0]->epoch);
 421     },
 422     short_cmt => sub {
 423       my $cmt = shift;
 424       my($line) = split /\n/, $cmt;
 425       $line =~ s/^(.{70,80}\b).*/$1 …/;
 426       return $line;
 427     },
 428     abridged_description => sub {
 429         join(' ', grep { defined } (split / /, shift)[0..10]);
 430     },
 431   );
 432
 433   # Yes, this is hideous.
 434   $self->header($c);
 435   $self->footer($c);
 436 }
 437
 438 # XXX This could probably be dropped altogether.
 439 use Gitalist::Util qw(to_utf8);
 440 # Formally git_header_html
 441 sub header {
 442   my($self, $c) = @_;
 443
 444   my $title = $c->config->{sitename};
 445
 446   my $project   = $c->req->param('project')  || $c->req->param('p');
 447   my $action    = $c->req->param('action')   || $c->req->param('a');
 448   my $file_name = $c->req->param('filename') || $c->req->param('f');
 449   if(defined $project) {
 450     $title .= " - " . to_utf8($project);
 451     if (defined $action) {
 452       $title .= "/$action";
 453       if (defined $file_name) {
 454         $title .= " - " . $file_name;
 455         if ($action eq "tree" && $file_name !~ m|/$|) {
 456           $title .= "/";
 457         }
 458       }
 459     }
 460   }
 461
 462   $c->stash->{version}     = $Gitalist::VERSION;
 463   # check git's version by running it on the first project in the list.
 464   $c->stash->{title}       = $title;
 465
 466   $c->stash->{stylesheet} = $c->config->{stylesheet} || 'gitweb.css';
 467
 468   $c->stash->{project} = $project;
 469   my @links;
 470   if($project) {
 471     my %href_params = $self->feed_info($c);
 472     $href_params{'-title'} ||= 'log';
 473
 474     foreach my $format qw(RSS Atom) {
 475       my $type = lc($format);
 476       push @links, {
 477         rel   => 'alternate',
 478         title => "$project - $href_params{'-title'} - $format feed",
 479
 480         # XXX A bit hacky and could do with using gitweb::href() features
 481         href  => "?a=$type;p=$project",
 482         type  => "application/$type+xml"
 483         }, {
 484         rel   => 'alternate',
 485
 486         # XXX This duplication also feels a bit awkward
 487         title => "$project - $href_params{'-title'} - $format feed (no merges)",
 488         href  => "?a=$type;p=$project;opt=--no-merges",
 489         type  => "application/$type+xml"
 490         };
 491     }
 492   } else {
 493     push @links, {
 494       rel => "alternate",
 495       title => $c->config->{sitename}." projects list",
 496       href => '?a=project_index',
 497       type => "text/plain; charset=utf-8"
 498       }, {
 499       rel => "alternate",
 500       title => $c->config->{sitename}." projects feeds",
 501       href => '?a=opml',
 502       type => "text/plain; charset=utf-8"
 503       };
 504   }
 505
 506   $c->stash->{favicon} = $c->config->{favicon};
 507
 508   # </head><body>
 509
 510   $c->stash(
 511     logo_url      => $c->config->{logo_url},
 512     logo_label    => $c->config->{logo_label},
 513     logo_img      => $c->config->{logo},
 514     home_link     => $c->config->{home_link},
 515     home_link_str => $c->config->{home_link_str},
 516     );
 517
 518   if (defined $project) {
 519       eval {
 520           $c->stash(Project => $c->model('GitRepos')->project($project));
 521       };
 522       if ($@) {
 523           $c->detach('error_404');
 524       }
 525       $c->stash(
 526           search_text => ( $c->req->param('s') ||
 527                                $c->req->param('searchtext') || ''),
 528           search_hash => ( $c->req->param('hb') || $c->req->param('hashbase')
 529                                || $c->req->param('h')  || $c->req->param('hash')
 530                                    || 'HEAD' ),
 531       );
 532   }
 533   my $a_project = $c->stash->{Project} || $c->model()->projects->[0];
 534   $c->stash->{git_version} = $a_project->run_cmd('--version');
 535 }
 536
 537 # Formally git_footer_html
 538 sub footer {
 539   my($self, $c) = @_;
 540
 541   my $feed_class = 'rss_logo';
 542
 543   my @feeds;
 544   my $project = $c->req->param('project')  || $c->req->param('p');
 545   if(defined $project) {
 546     (my $pstr = $project) =~ s[/?\.git$][];
 547     my $descr = $c->stash->{project_description}
 548             = $c->stash->{Project} ? $c->stash->{Project}->description : '';
 549
 550     my %href_params = $self->feed_info($c);
 551     if (!%href_params) {
 552       $feed_class .= ' generic';
 553     }
 554     $href_params{'-title'} ||= 'log';
 555
 556     @feeds = [
 557       map +{
 558         class => $feed_class,
 559         title => "$href_params{'-title'} $_ feed",
 560         href  => "/?p=$project;a=\L$_",
 561         name  => lc $_,
 562         }, qw(RSS Atom)
 563       ];
 564   } else {
 565     @feeds = [
 566       map {
 567         class => $feed_class,
 568           title => '',
 569           href  => "/?a=$_->[0]",
 570           name  => $_->[1],
 571         }, [opml=>'OPML'],[project_index=>'TXT'],
 572       ];
 573   }
 574 }
 575
 576 # XXX This feels wrong here, should probably be refactored.
 577 # returns hash to be passed to href to generate gitweb URL
 578 # in -title key it returns description of link
 579 sub feed_info {
 580   my($self, $c) = @_;
 581
 582   my $format = shift || 'Atom';
 583   my %res = (action => lc($format));
 584
 585   # feed links are possible only for project views
 586   return unless $c->req->param('project');
 587
 588   # some views should link to OPML, or to generic project feed,
 589   # or don't have specific feed yet (so they should use generic)
 590   return if $c->req->param('action') =~ /^(?:tags|heads|forks|tag|search)$/x;
 591
 592   my $branch;
 593   my $hash = $c->req->param('h')  || $c->req->param('hash');
 594   my $hash_base = $c->req->param('hb') || $c->req->param('hashbase');
 595
 596   # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
 597   # from tag links; this also makes possible to detect branch links
 598   if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
 599     (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
 600     $branch = $1;
 601   }
 602
 603   # find log type for feed description (title)
 604   my $type = 'log';
 605   my $file_name = $c->req->param('f') || $c->req->param('filename');
 606   if (defined $file_name) {
 607     $type  = "history of $file_name";
 608     $type .= "/" if $c->req->param('action') eq 'tree';
 609     $type .= " on '$branch'" if (defined $branch);
 610   } else {
 611     $type = "log of $branch" if (defined $branch);
 612   }
 613
 614   $res{-title} = $type;
 615   $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
 616   $res{'file_name'} = $file_name;
 617
 618   return %res;
 619 }
 620
 621 =head2 end
 622
 623 Attempt to render a view, if needed.
 624
 625 =cut
 626
 627 sub end : ActionClass('RenderView') {
 628     my ($self, $c) = @_;
 629     # Give project views the current HEAD.
 630     if ($c->stash->{Project}) {
 631         $c->stash->{HEAD} = $c->stash->{Project}->head_hash;
 632     }
 633 }
 634
 635 sub error_404 :Private {
 636     my ($self, $c) = @_;
 637     $c->response->status(404);
 638     $c->stash(
 639         title => 'Page not found',
 640         content => 'Page not found',
 641     );
 642 }
 643
 644 sub age_string {
 645         my $age = shift;
 646         my $age_str;
 647
 648         if ($age > 60*60*24*365*2) {
 649                 $age_str = (int $age/60/60/24/365);
 650                 $age_str .= " years ago";
 651         } elsif ($age > 60*60*24*(365/12)*2) {
 652                 $age_str = int $age/60/60/24/(365/12);
 653                 $age_str .= " months ago";
 654         } elsif ($age > 60*60*24*7*2) {
 655                 $age_str = int $age/60/60/24/7;
 656                 $age_str .= " weeks ago";
 657         } elsif ($age > 60*60*24*2) {
 658                 $age_str = int $age/60/60/24;
 659                 $age_str .= " days ago";
 660         } elsif ($age > 60*60*2) {
 661                 $age_str = int $age/60/60;
 662                 $age_str .= " hours ago";
 663         } elsif ($age > 60*2) {
 664                 $age_str = int $age/60;
 665                 $age_str .= " min ago";
 666         } elsif ($age > 2) {
 667                 $age_str = int $age;
 668                 $age_str .= " sec ago";
 669         } else {
 670                 $age_str .= " right now";
 671         }
 672         return $age_str;
 673 }
 674
 675 =head1 AUTHOR
 676
 677 Dan Brook
 678
 679 =head1 LICENSE
 680
 681 This library is free software. You can redistribute it and/or modify
 682 it under the same terms as Perl itself.
 683
 684 =cut
 685
 686 __PACKAGE__->meta->make_immutable;