lib/Gitalist/Controller/Root.pm

   1 package Gitalist::Controller::Root;
   2 use Moose;
   3 use namespace::autoclean;
   4
   5 BEGIN { extends 'Catalyst::Controller' }
   6
   7 __PACKAGE__->config->{namespace} = '';
   8
   9 use Moose::Autobox;
  10 use Sys::Hostname ();
  11 use XML::Atom::Feed;
  12 use XML::Atom::Entry;
  13 use XML::RSS;
  14 use XML::OPML::SimpleGen;
  15
  16 =head1 NAME
  17
  18 Gitalist::Controller::Root - Root Controller for Gitalist
  19
  20 =head1 DESCRIPTION
  21
  22 [enter your description here]
  23
  24 =head1 METHODS
  25
  26 =cut
  27
  28 sub _get_object {
  29   my($self, $c, $haveh) = @_;
  30
  31   my $h = $haveh || $c->req->param('h') || '';
  32   my $f = $c->req->param('f');
  33
  34   my $m = $c->stash->{Project};
  35   my $pd = $m->path;
  36
  37   # Either use the provided h(ash) parameter, the f(ile) parameter or just use HEAD.
  38   my $hash = ($h =~ /[^a-f0-9]/ ? $m->head_hash($h) : $h)
  39           || ($f && $m->hash_by_path($f))
  40           || $m->head_hash
  41           # XXX This could definitely use more context.
  42           || Carp::croak("Couldn't find a hash for the commit object!");
  43
  44   my $obj = $m->get_object($hash)
  45     or Carp::croak("Couldn't find a object for '$hash' in '$pd'!");
  46
  47   return $obj;
  48 }
  49
  50 =head2 index
  51
  52 Provides the project listing.
  53
  54 =cut
  55
  56 sub index :Path :Args(0) {
  57   my ( $self, $c ) = @_;
  58
  59   $c->detach($c->req->param('a'))
  60     if $c->req->param('a');
  61
  62   my @list = @{ $c->model()->projects };
  63   die 'No projects found in '. $c->model->repo_dir
  64     unless @list;
  65
  66   my $search = $c->req->param('s') || '';
  67   if($search) {
  68     @list = grep {
  69          index($_->name, $search) > -1
  70       or ( $_->description !~ /^Unnamed repository/ and index($_->description, $search) > -1 )
  71     } @list
  72   }
  73
  74   $c->stash(
  75     search_text => $search,
  76     projects    => \@list,
  77     action      => 'index',
  78   );
  79 }
  80
  81 sub project_index : Local {
  82   my ( $self, $c ) = @_;
  83
  84   my @list = @{ $c->model()->projects };
  85   die 'No projects found in '. $c->model->repo_dir
  86     unless @list;
  87
  88   $c->response->content_type('text/plain');
  89   $c->response->body(
  90     join "\n", map $_->name, @list
  91   );
  92   $c->response->status(200);
  93 }
  94
  95 =head2 summary
  96
  97 A summary of what's happening in the repo.
  98
  99 =cut
 100
 101 sub summary : Local {
 102   my ( $self, $c ) = @_;
 103   my $project = $c->stash->{Project};
 104   $c->detach('error_404') unless $project;
 105   my $commit = $self->_get_object($c);
 106   my @heads  = @{$project->heads};
 107   my $maxitems = Gitalist->config->{paging}{summary} || 10;
 108   $c->stash(
 109     commit    => $commit,
 110     log_lines => [$project->list_revs(
 111         sha1 => $commit->sha1,
 112         count => $maxitems,
 113     )],
 114     refs      => $project->references,
 115     heads     => [ @heads[0 .. ($#heads < $maxitems ? $#heads : $maxitems)] ],
 116     action    => 'summary',
 117   );
 118 }
 119
 120 =head2 heads
 121
 122 The current list of heads (aka branches) in the repo.
 123
 124 =cut
 125
 126 sub heads : Local {
 127   my ( $self, $c ) = @_;
 128   my $project = $c->stash->{Project};
 129   $c->stash(
 130     commit => $self->_get_object($c),
 131     heads  => $project->heads,
 132     action => 'heads',
 133   );
 134 }
 135
 136 =head2 tags
 137
 138 The current list of tags in the repo.
 139
 140 =cut
 141
 142 sub tags : Local {
 143   my ( $self, $c ) = @_;
 144   my $project = $c->stash->{Project};
 145   $c->stash(
 146     commit => $self->_get_object($c),
 147     tags   => $project->tags,
 148     action => 'tags',
 149   );
 150 }
 151
 152 sub blame : Local {
 153   my($self, $c) = @_;
 154
 155   my $project = $c->stash->{Project};
 156   my $h  = $c->req->param('h')
 157        || $project->hash_by_path($c->req->param('hb'), $c->req->param('f'))
 158        || die "No file or sha1 provided.";
 159   my $hb = $c->req->param('hb')
 160        || $project->head_hash
 161        || die "Couldn't discern the corresponding head.";
 162   my $filename = $c->req->param('f') || '';
 163
 164   my $blame = $project->get_object($hb)->blame($filename);
 165   $c->stash(
 166     blame    => $blame,
 167     head     => $project->get_object($hb),
 168     filename => $filename,
 169
 170     # XXX Hack hack hack, see View::SyntaxHighlight
 171     language => ($filename =~ /\.p[lm]$/i ? 'Perl' : ''),
 172     blob     => join("\n", map $_->{line}, @$blame),
 173   );
 174
 175   $c->forward('View::SyntaxHighlight')
 176     unless $c->stash->{no_wrapper};
 177 }
 178
 179 sub _blob_objs {
 180   my ( $self, $c ) = @_;
 181   my $project = $c->stash->{Project};
 182   my $h  = $c->req->param('h')
 183        || $project->hash_by_path($c->req->param('hb'), $c->req->param('f'))
 184        || die "No file or sha1 provided.";
 185   my $hb = $c->req->param('hb')
 186        || $project->head_hash
 187        || die "Couldn't discern the corresponding head.";
 188
 189   my $filename = $c->req->param('f') || '';
 190
 191   my $blob = $project->get_object($h);
 192   $blob = $project->get_object(
 193     $project->hash_by_path($h || $hb, $filename)
 194   ) if $blob->type ne 'blob';
 195
 196   return $blob, $project->get_object($hb), $filename;
 197 }
 198
 199 =head2 blob
 200
 201 The blob action i.e the contents of a file.
 202
 203 =cut
 204
 205 sub blob : Local {
 206   my ( $self, $c ) = @_;
 207
 208   my($blob, $head, $filename) = $self->_blob_objs($c);
 209   $c->stash(
 210     blob     => $blob->content,
 211     head     => $head,
 212     filename => $filename,
 213     # XXX Hack hack hack, see View::SyntaxHighlight
 214     language => ($filename =~ /\.p[lm]$/i ? 'Perl' : ''),
 215     action   => 'blob',
 216   );
 217
 218   $c->forward('View::SyntaxHighlight')
 219     unless $c->stash->{no_wrapper};
 220 }
 221
 222 =head2 blob_plain
 223
 224 The plain text version of blob, where file is rendered as is.
 225
 226 =cut
 227
 228 sub blob_plain : Local {
 229   my($self, $c) = @_;
 230
 231   my($blob) = $self->_blob_objs($c);
 232   $c->response->content_type('text/plain; charset=utf-8');
 233   $c->response->body($blob->content);
 234   $c->response->status(200);
 235 }
 236
 237 =head2 blobdiff_plain
 238
 239 The plain text version of blobdiff.
 240
 241 =cut
 242
 243 sub blobdiff_plain : Local {
 244   my($self, $c) = @_;
 245
 246   $c->stash(no_wrapper => 1);
 247   $c->response->content_type('text/plain; charset=utf-8');
 248
 249   $c->forward('blobdiff');
 250 }
 251
 252 =head2 blobdiff
 253
 254 Exposes a given diff of a blob.
 255
 256 =cut
 257
 258 sub blobdiff : Local {
 259   my ( $self, $c ) = @_;
 260   my $commit = $self->_get_object($c, $c->req->param('hb'));
 261   my $filename = $c->req->param('f')
 262               || croak("No file specified!");
 263   my($tree, $patch) = $c->stash->{Project}->diff(
 264     commit => $commit,
 265     patch  => 1,
 266     parent => $c->req->param('hpb') || undef,
 267     file   => $filename,
 268   );
 269   $c->stash(
 270     commit    => $commit,
 271     diff      => $patch,
 272     filename  => $filename,
 273     # XXX Hack hack hack, see View::SyntaxHighlight
 274     blobs     => [$patch->[0]->{diff}],
 275     language  => 'Diff',
 276     action    => 'blobdiff',
 277   );
 278
 279   $c->forward('View::SyntaxHighlight')
 280     unless $c->stash->{no_wrapper};
 281 }
 282
 283 =head2 commit
 284
 285 Exposes a given commit.
 286
 287 =cut
 288
 289 sub commit : Local {
 290   my ( $self, $c ) = @_;
 291   my $project = $c->stash->{Project};
 292   my $commit = $self->_get_object($c);
 293   $c->stash(
 294       commit      => $commit,
 295       diff_tree   => ($project->diff(commit => $commit))[0],
 296       refs      => $project->references,
 297       action      => 'commit',
 298   );
 299 }
 300
 301 =head2 commitdiff
 302
 303 Exposes a given diff of a commit.
 304
 305 =cut
 306
 307 sub commitdiff : Local {
 308   my ( $self, $c ) = @_;
 309   my $commit = $self->_get_object($c);
 310   my($tree, $patch) = $c->stash->{Project}->diff(
 311       commit => $commit,
 312       parent => $c->req->param('hp') || undef,
 313       patch  => 1,
 314   );
 315   $c->stash(
 316     commit    => $commit,
 317     diff_tree => $tree,
 318     diff      => $patch,
 319     # XXX Hack hack hack, see View::SyntaxHighlight
 320     blobs     => [map $_->{diff}, @$patch],
 321     language  => 'Diff',
 322     action    => 'commitdiff',
 323   );
 324
 325   $c->forward('View::SyntaxHighlight')
 326     unless $c->stash->{no_wrapper};
 327 }
 328
 329 sub commitdiff_plain : Local {
 330   my($self, $c) = @_;
 331
 332   $c->stash(no_wrapper => 1);
 333   $c->response->content_type('text/plain; charset=utf-8');
 334
 335   $c->forward('commitdiff');
 336 }
 337
 338 =head2 shortlog
 339
 340 Expose an abbreviated log of a given sha1.
 341
 342 =cut
 343
 344 sub shortlog : Local {
 345   my ( $self, $c ) = @_;
 346
 347   my $project  = $c->stash->{Project};
 348   my $commit   = $self->_get_object($c, $c->req->param('hb'));
 349   my $filename = $c->req->param('f') || '';
 350
 351   my %logargs = (
 352       sha1   => $commit->sha1,
 353       count  => Gitalist->config->{paging}{log} || 25,
 354       ($filename ? (file => $filename) : ())
 355   );
 356
 357   my $page = $c->req->param('pg') || 0;
 358   $logargs{skip} = $c->req->param('pg') * $logargs{count}
 359     if $c->req->param('pg');
 360
 361   $c->stash(
 362       commit    => $commit,
 363       log_lines => [$project->list_revs(%logargs)],
 364       refs      => $project->references,
 365       page      => $page,
 366       filename  => $filename,
 367       action    => 'shortlog',
 368   );
 369 }
 370
 371 =head2 log
 372
 373 Calls shortlog internally. Perhaps that should be reversed ...
 374
 375 =cut
 376 sub log : Local {
 377     $_[0]->shortlog($_[1]);
 378     $_[1]->stash->{action} = 'log';
 379 }
 380
 381 # For legacy support.
 382 sub history : Local {
 383     my ( $self, $c ) = @_;
 384     $self->shortlog($c);
 385     my $project = $c->stash->{Project};
 386     my $file = $project->get_object(
 387         $project->hash_by_path(
 388             $project->head_hash,
 389             $c->stash->{filename}
 390         )
 391     );
 392      $c->stash( action => 'history',
 393                filetype => $file->type,
 394            );
 395 }
 396
 397 =head2 tree
 398
 399 The tree of a given commit.
 400
 401 =cut
 402
 403 sub tree : Local {
 404   my ( $self, $c ) = @_;
 405   my $project = $c->stash->{Project};
 406   my $commit  = $self->_get_object($c, $c->req->param('hb'));
 407   my $filename = $c->req->param('f') || '';
 408   my $tree    = $filename
 409     ? $project->get_object($project->hash_by_path($commit->sha1, $filename))
 410     : $project->get_object($commit->tree_sha1)
 411   ;
 412   $c->stash(
 413       commit    => $commit,
 414       tree      => $tree,
 415       tree_list => [$project->list_tree($tree->sha1)],
 416       path      => $c->req->param('f') || '',
 417       action    => 'tree',
 418   );
 419 }
 420
 421 =head2 reflog
 422
 423 Expose the local reflog. This may go away.
 424
 425 =cut
 426
 427 sub reflog : Local {
 428   my ( $self, $c ) = @_;
 429   my @log = $c->stash->{Project}->reflog(
 430       '--since=yesterday'
 431   );
 432
 433   $c->stash(
 434       log    => \@log,
 435       action => 'reflog',
 436   );
 437 }
 438
 439 =head2 search
 440
 441 The action for the search form.
 442
 443 =cut
 444
 445 sub search : Local {
 446   my($self, $c) = @_;
 447   $c->stash(current_action => 'GitRepos');
 448   my $project = $c->stash->{Project};
 449   my $commit  = $self->_get_object($c);
 450   # Lifted from /shortlog.
 451   my %logargs = (
 452     sha1   => $commit->sha1,
 453     count  => Gitalist->config->{paging}{log},
 454     ($c->req->param('f') ? (file => $c->req->param('f')) : ()),
 455     search => {
 456       type   => $c->req->param('type'),
 457       text   => $c->req->param('text'),
 458       regexp => $c->req->param('regexp') || 0,
 459     },
 460   );
 461
 462   $c->stash(
 463       commit  => $commit,
 464       results => [$project->list_revs(%logargs)],
 465       action  => 'search',
 466           # This could be added - page      => $page,
 467   );
 468 }
 469
 470 =head2 search_help
 471
 472 Provides some help for the search form.
 473
 474 =cut
 475
 476 sub search_help : Local {
 477     my ($self, $c) = @_;
 478     $c->stash(template => 'search_help.tt2');
 479 }
 480
 481 =head2 atom
 482
 483 Provides an atom feed for a given project.
 484
 485 =cut
 486
 487 sub atom : Local {
 488   my($self, $c) = @_;
 489
 490   my $feed = XML::Atom::Feed->new;
 491
 492   my $host = lc Sys::Hostname::hostname();
 493   $feed->title($host . ' - ' . Gitalist->config->{name});
 494   $feed->updated(~~DateTime->now);
 495
 496   my $project = $c->stash->{Project};
 497   my %logargs = (
 498       sha1   => $project->head_hash,
 499       count  => Gitalist->config->{paging}{log} || 25,
 500       ($c->req->param('f') ? (file => $c->req->param('f')) : ())
 501   );
 502
 503   my $mk_title = $c->stash->{short_cmt};
 504   for my $commit ($project->list_revs(%logargs)) {
 505     my $entry = XML::Atom::Entry->new;
 506     $entry->title( $mk_title->($commit->comment) );
 507     $entry->id($c->uri_for('commit', {h=>$commit->sha1}));
 508     # XXX Needs work ...
 509     $entry->content($commit->comment);
 510     $feed->add_entry($entry);
 511   }
 512
 513   $c->response->body($feed->as_xml);
 514   $c->response->content_type('application/atom+xml');
 515   $c->response->status(200);
 516 }
 517
 518 =head2 rss
 519
 520 Provides an RSS feed for a given project.
 521
 522 =cut
 523
 524 sub rss : Local {
 525   my ($self, $c) = @_;
 526
 527   my $project = $c->stash->{Project};
 528
 529   my $rss = XML::RSS->new(version => '2.0');
 530   $rss->channel(
 531     title          => lc(Sys::Hostname::hostname()) . ' - ' . Gitalist->config->{name},
 532     link           => $c->uri_for('summary', {p=>$project->name}),
 533     language       => 'en',
 534     description    => $project->description,
 535     pubDate        => DateTime->now,
 536     lastBuildDate  => DateTime->now,
 537   );
 538
 539   my %logargs = (
 540       sha1   => $project->head_hash,
 541       count  => Gitalist->config->{paging}{log} || 25,
 542       ($c->req->param('f') ? (file => $c->req->param('f')) : ())
 543   );
 544   my $mk_title = $c->stash->{short_cmt};
 545   for my $commit ($project->list_revs(%logargs)) {
 546     # XXX Needs work ....
 547     $rss->add_item(
 548         title       => $mk_title->($commit->comment),
 549         permaLink   => $c->uri_for(commit => {h=>$commit->sha1}),
 550         description => $commit->comment,
 551     );
 552   }
 553
 554   $c->response->body($rss->as_string);
 555   $c->response->content_type('application/rss+xml');
 556   $c->response->status(200);
 557 }
 558
 559 sub opml : Local {
 560   my($self, $c) = @_;
 561
 562   my $opml = XML::OPML::SimpleGen->new();
 563
 564   $opml->head(title => lc(Sys::Hostname::hostname()) . ' - ' . Gitalist->config->{name});
 565
 566   my @list = @{ $c->model()->projects };
 567   die 'No projects found in '. $c->model->repo_dir
 568     unless @list;
 569
 570   for my $proj ( @list ) {
 571     $opml->insert_outline(
 572       text   => $proj->name. ' - '. $proj->description,
 573       xmlUrl => $c->uri_for(rss => {p => $proj->name}),
 574     );
 575   }
 576
 577   $c->response->body($opml->as_string);
 578   $c->response->content_type('application/rss');
 579   $c->response->status(200);
 580 }
 581
 582 =head2 patch
 583
 584 A raw patch for a given commit.
 585
 586 =cut
 587
 588 sub patch : Local {
 589     my ($self, $c) = @_;
 590     $c->detach('patches', [1]);
 591 }
 592
 593 =head2 patches
 594
 595 The patcheset for a given commit ???
 596
 597 =cut
 598
 599 sub patches : Local {
 600     my ($self, $c, $count) = @_;
 601     $count ||= Gitalist->config->{patches}{max};
 602     my $commit = $self->_get_object($c);
 603     my $parent = $c->req->param('hp') || undef;
 604     my $patch = $commit->get_patch( $parent, $count );
 605     $c->response->body($patch);
 606     $c->response->content_type('text/plain');
 607     $c->response->status(200);
 608 }
 609
 610 =head2 snapshot
 611
 612 Provides a snapshot of a given commit.
 613
 614 =cut
 615
 616 sub snapshot : Local {
 617     my ($self, $c) = @_;
 618     my $format = $c->req->param('sf') || 'tgz';
 619     die unless $format;
 620     my $sha1 = $c->req->param('h') || $self->_get_object($c)->sha1;
 621     my @snap = $c->stash->{Project}->snapshot(
 622         sha1 => $sha1,
 623         format => $format
 624     );
 625     $c->response->status(200);
 626     $c->response->headers->header( 'Content-Disposition' =>
 627                                        "attachment; filename=$snap[0]");
 628     $c->response->body($snap[1]);
 629 }
 630
 631 =head2 auto
 632
 633 Populate the header and footer. Perhaps not the best location.
 634
 635 =cut
 636
 637 sub auto : Private {
 638   my($self, $c) = @_;
 639
 640   my $project = $c->req->param('p');
 641   if (defined $project) {
 642     eval {
 643       $c->stash(Project => $c->model('GitRepos')->project($project));
 644     };
 645     if ($@) {
 646       $c->detach('/error_404');
 647     }
 648   }
 649
 650   my $a_project = $c->stash->{Project} || $c->model()->projects->[0];
 651   $c->stash(
 652     git_version => $a_project->run_cmd('--version'),
 653     version     => $Gitalist::VERSION,
 654
 655     # XXX Move these to a plugin!
 656     time_since => sub {
 657       return 'never' unless $_[0];
 658       return age_string(time - $_[0]->epoch);
 659     },
 660     short_cmt => sub {
 661       my $cmt = shift;
 662       my($line) = split /\n/, $cmt;
 663       $line =~ s/^(.{70,80}\b).*/$1 \x{2026}/;
 664       return $line;
 665     },
 666     abridged_description => sub {
 667         join(' ', grep { defined } (split / /, shift)[0..10]);
 668     },
 669   );
 670 }
 671
 672 =head2 end
 673
 674 Attempt to render a view, if needed.
 675
 676 =cut
 677
 678 sub end : ActionClass('RenderView') {
 679     my ($self, $c) = @_;
 680     # Give project views the current HEAD.
 681     if ($c->stash->{Project}) {
 682         $c->stash->{HEAD} = $c->stash->{Project}->head_hash;
 683     }
 684 }
 685
 686 sub error_404 :Private {
 687     my ($self, $c) = @_;
 688     $c->response->status(404);
 689     $c->response->body('Page not found');
 690 }
 691
 692 sub age_string {
 693   my $age = shift;
 694   my $age_str;
 695
 696   if ( $age > 60 * 60 * 24 * 365 * 2 ) {
 697     $age_str  = ( int $age / 60 / 60 / 24 / 365 );
 698     $age_str .= " years ago";
 699   }
 700   elsif ( $age > 60 * 60 * 24 * ( 365 / 12 ) * 2 ) {
 701     $age_str  = int $age / 60 / 60 / 24 / ( 365 / 12 );
 702     $age_str .= " months ago";
 703   }
 704   elsif ( $age > 60 * 60 * 24 * 7 * 2 ) {
 705     $age_str  = int $age / 60 / 60 / 24 / 7;
 706     $age_str .= " weeks ago";
 707   }
 708   elsif ( $age > 60 * 60 * 24 * 2 ) {
 709     $age_str  = int $age / 60 / 60 / 24;
 710     $age_str .= " days ago";
 711   }
 712   elsif ( $age > 60 * 60 * 2 ) {
 713     $age_str  = int $age / 60 / 60;
 714     $age_str .= " hours ago";
 715   }
 716   elsif ( $age > 60 * 2 ) {
 717     $age_str  = int $age / 60;
 718     $age_str .= " min ago";
 719   }
 720   elsif ( $age > 2 ) {
 721     $age_str  = int $age;
 722     $age_str .= " sec ago";
 723   }
 724   else {
 725     $age_str .= " right now";
 726   }
 727   return $age_str;
 728 }
 729
 730 __PACKAGE__->meta->make_immutable;
 731
 732 __END__
 733
 734 =head1 NAME
 735
 736 Gitalist::Controller::Root - Root controller for the application
 737
 738 =head1 DESCRIPTION
 739
 740 This controller handles all of the root level paths for the application
 741
 742 =head1 METHODS
 743
 744 =head2 age_string
 745
 746 =head2 blame
 747
 748 =head2 commitdiff_plain
 749
 750 =head2 error_404
 751
 752 =head2 history
 753
 754 =head2 opml
 755
 756 =head2 project_index
 757
 758 =head1 AUTHORS
 759
 760 See L<Gitalist> for authors.
 761
 762 =head1 LICENSE
 763
 764 See L<Gitalist> for the license.
 765
 766 =cut