lib/Gitalist/Controller/Root.pm

   1 package Gitalist::Controller::Root;
   2 use Moose;
   3 use namespace::autoclean;
   4
   5 BEGIN { extends 'Catalyst::Controller' }
   6
   7 #
   8 # Sets the actions in this controller to be registered with no prefix
   9 # so they function identically to actions created in MyApp.pm
  10 #
  11 __PACKAGE__->config->{namespace} = '';
  12
  13 use IO::Capture::Stdout;
  14 use XML::Atom::Feed;
  15 use XML::Atom::Entry;
  16 use Sys::Hostname ();
  17
  18 =head1 NAME
  19
  20 Gitalist::Controller::Root - Root Controller for Gitalist
  21
  22 =head1 DESCRIPTION
  23
  24 [enter your description here]
  25
  26 =head1 METHODS
  27
  28 =cut
  29
  30 =head2 index
  31
  32 =cut
  33
  34 =head2 run_gitweb
  35
  36 The C<gitweb> shim. It should now only be explicitly accessible by
  37 modifying the URL.
  38
  39 =cut
  40
  41 sub run_gitweb {
  42   my ( $self, $c ) = @_;
  43
  44   # XXX A slippery slope to be sure.
  45   if($c->req->param('a')) {
  46     my $capture = IO::Capture::Stdout->new();
  47     $capture->start();
  48     eval {
  49       my $action = gitweb::main($c);
  50       $action->();
  51     };
  52     $capture->stop();
  53
  54     use Data::Dumper;
  55     die Dumper($@)
  56       if $@;
  57
  58     my $output = join '', $capture->read;
  59     $c->stash->{gitweb_output} = $output;
  60     $c->stash->{template} = 'gitweb.tt2';
  61   }
  62 }
  63
  64 sub _get_object {
  65   my($self, $c, $haveh) = @_;
  66
  67   my $h = $haveh || $c->req->param('h') || '';
  68   my $f = $c->req->param('f');
  69
  70   my $m = $c->stash->{Project};
  71   my $pd = $m->path;
  72
  73   # Either use the provided h(ash) parameter, the f(ile) parameter or just use HEAD.
  74   my $hash = ($h =~ /[^a-f0-9]/ ? $m->head_hash($h) : $h)
  75           || ($f && $m->hash_by_path($f))
  76           || $m->head_hash
  77           # XXX This could definitely use more context.
  78           || Carp::croak("Couldn't find a hash for the commit object!");
  79
  80   my $commit = $m->get_object($hash)
  81     or Carp::croak("Couldn't find a commit object for '$hash' in '$pd'!");
  82
  83   return $commit;
  84 }
  85
  86 =head2 index
  87
  88 Provides the project listing.
  89
  90 =cut
  91
  92 sub index :Path :Args(0) {
  93   my ( $self, $c ) = @_;
  94
  95   $c->detach($c->req->param('a'))
  96     if $c->req->param('a');
  97
  98   my @list = @{ $c->model()->projects };
  99   die 'No projects found in '. $c->model->repo_dir
 100     unless @list;
 101
 102   my $search = $c->req->param('s') || '';
 103   if($search) {
 104     @list = grep {
 105          index($_->name, $search) > -1
 106       or ( $_->description !~ /^Unnamed repository/ and index($_->description, $search) > -1 )
 107     } @list
 108   }
 109
 110   $c->stash(
 111     search_text => $search,
 112     projects    => \@list,
 113     action      => 'index',
 114   );
 115 }
 116
 117 =head2 summary
 118
 119 A summary of what's happening in the repo.
 120
 121 =cut
 122
 123 sub summary : Local {
 124   my ( $self, $c ) = @_;
 125   my $project = $c->stash->{Project};
 126   $c->detach('error_404') unless $project;
 127   my $commit = $self->_get_object($c);
 128   my @heads  = @{$project->heads};
 129   my $maxitems = Gitalist->config->{paging}{summary} || 10;
 130   $c->stash(
 131     commit    => $commit,
 132     log_lines => [$project->list_revs(
 133         sha1 => $commit->sha1,
 134         count => $maxitems,
 135     )],
 136     refs      => $project->references,
 137     heads     => [ @heads[0 .. ($#heads < $maxitems ? $#heads : $maxitems)] ],
 138     action    => 'summary',
 139   );
 140 }
 141
 142 =head2 heads
 143
 144 The current list of heads (aka branches) in the repo.
 145
 146 =cut
 147
 148 sub heads : Local {
 149   my ( $self, $c ) = @_;
 150   my $project = $c->stash->{Project};
 151   $c->stash(
 152     commit => $self->_get_object($c),
 153     heads  => $project->heads,
 154     action => 'heads',
 155   );
 156 }
 157
 158 =head2 blob
 159
 160 The blob action i.e the contents of a file.
 161
 162 =cut
 163
 164 sub blob : Local {
 165   my ( $self, $c ) = @_;
 166   my $project = $c->stash->{Project};
 167   my $h  = $c->req->param('h')
 168        || $project->hash_by_path($c->req->param('hb'), $c->req->param('f'))
 169        || die "No file or sha1 provided.";
 170   my $hb = $c->req->param('hb')
 171        || $project->head_hash
 172        || die "Couldn't discern the corresponding head.";
 173
 174   my $filename = $c->req->param('f') || '';
 175
 176   $c->stash(
 177     blob     => $project->get_object($h)->content,
 178     head     => $project->get_object($hb),
 179     filename => $filename,
 180     # XXX Hack hack hack, see View::SyntaxHighlight
 181     language => ($filename =~ /\.p[lm]$/ ? 'Perl' : ''),
 182     action   => 'blob',
 183   );
 184
 185   $c->forward('View::SyntaxHighlight')
 186     unless $c->stash->{no_wrapper};
 187 }
 188
 189 sub blob_plain : Local {
 190   my($self, $c) = @_;
 191
 192   $c->stash(no_wrapper => 1);
 193   $c->response->content_type('text/plain; charset=utf-8');
 194
 195   $c->forward('blob');
 196 }
 197
 198 sub blobdiff_plain : Local {
 199   my($self, $c) = @_;
 200
 201   $c->stash(no_wrapper => 1);
 202   $c->response->content_type('text/plain; charset=utf-8');
 203
 204   $c->forward('blobdiff');
 205
 206 }
 207
 208 =head2 blobdiff
 209
 210 Exposes a given diff of a blob.
 211
 212 =cut
 213
 214 sub blobdiff : Local {
 215   my ( $self, $c ) = @_;
 216   my $commit = $self->_get_object($c, $c->req->param('hb'));
 217   my $filename = $c->req->param('f')
 218               || croak("No file specified!");
 219   my($tree, $patch) = $c->stash->{Project}->diff(
 220     commit => $commit,
 221     patch  => 1,
 222     parent => $c->req->param('hpb') || undef,
 223     file   => $filename,
 224   );
 225   $c->stash(
 226     commit    => $commit,
 227     diff      => $patch,
 228     # XXX Hack hack hack, see View::SyntaxHighlight
 229     blobs     => [$patch->[0]->{diff}],
 230     language  => 'Diff',
 231     action    => 'blobdiff',
 232   );
 233
 234   $c->forward('View::SyntaxHighlight')
 235     unless $c->stash->{no_wrapper};
 236 }
 237
 238 =head2 commit
 239
 240 Exposes a given commit.
 241
 242 =cut
 243
 244 sub commit : Local {
 245   my ( $self, $c ) = @_;
 246   my $project = $c->stash->{Project};
 247   my $commit = $self->_get_object($c);
 248   $c->stash(
 249       commit      => $commit,
 250       diff_tree   => ($project->diff(commit => $commit))[0],
 251       refs      => $project->references,
 252       action      => 'commit',
 253   );
 254 }
 255
 256 =head2 commitdiff
 257
 258 Exposes a given diff of a commit.
 259
 260 =cut
 261
 262 sub commitdiff : Local {
 263   my ( $self, $c ) = @_;
 264   my $commit = $self->_get_object($c);
 265   my($tree, $patch) = $c->stash->{Project}->diff(
 266       commit => $commit,
 267       parent => $c->req->param('hp') || undef,
 268       patch  => 1,
 269   );
 270   $c->stash(
 271     commit    => $commit,
 272     diff_tree => $tree,
 273     diff      => $patch,
 274     # XXX Hack hack hack, see View::SyntaxHighlight
 275     blobs     => [map $_->{diff}, @$patch],
 276     language  => 'Diff',
 277     action    => 'commitdiff',
 278   );
 279
 280   $c->forward('View::SyntaxHighlight')
 281     unless $c->stash->{no_wrapper};
 282 }
 283
 284 sub commitdiff_plain : Local {
 285   my($self, $c) = @_;
 286
 287   $c->stash(no_wrapper => 1);
 288   $c->response->content_type('text/plain; charset=utf-8');
 289
 290   $c->forward('commitdiff');
 291 }
 292
 293 =head2 shortlog
 294
 295 Expose an abbreviated log of a given sha1.
 296
 297 =cut
 298
 299 sub shortlog : Local {
 300   my ( $self, $c ) = @_;
 301   my $project = $c->stash->{Project};
 302   my $commit  = $self->_get_object($c);
 303   my %logargs = (
 304       sha1   => $commit->sha1,
 305       count  => Gitalist->config->{paging}{log} || 25,
 306       ($c->req->param('f') ? (file => $c->req->param('f')) : ())
 307   );
 308
 309   my $page = $c->req->param('pg') || 0;
 310   $logargs{skip} = $c->req->param('pg') * $logargs{count}
 311     if $c->req->param('pg');
 312
 313   $c->stash(
 314       commit    => $commit,
 315       log_lines => [$project->list_revs(%logargs)],
 316       refs      => $project->references,
 317       action    => 'shortlog',
 318       page      => $page,
 319   );
 320 }
 321
 322 =head2 log
 323
 324 Calls shortlog internally. Perhaps that should be reversed ...
 325
 326 =cut
 327 sub log : Local {
 328     $_[0]->shortlog($_[1]);
 329     $_[1]->stash->{action} = 'log';
 330 }
 331
 332 # For legacy support.
 333 sub history : Local {
 334   $_[0]->shortlog(@_[1 .. $#_]);
 335 }
 336
 337 =head2 tree
 338
 339 The tree of a given commit.
 340
 341 =cut
 342
 343 sub tree : Local {
 344   my ( $self, $c ) = @_;
 345   my $project = $c->stash->{Project};
 346   my $commit  = $self->_get_object($c, $c->req->param('hb'));
 347   my $tree    = $self->_get_object($c, $c->req->param('h') || $commit->tree_sha1);
 348   $c->stash(
 349       commit    => $commit,
 350       tree      => $tree,
 351       tree_list => [$project->list_tree($tree->sha1)],
 352       path      => $c->req->param('f') || '',
 353       action    => 'tree',
 354   );
 355 }
 356
 357 =head2 reflog
 358
 359 Expose the local reflog. This may go away.
 360
 361 =cut
 362
 363 sub reflog : Local {
 364   my ( $self, $c ) = @_;
 365   my @log = $c->stash->{Project}->reflog(
 366       '--since=yesterday'
 367   );
 368
 369   $c->stash(
 370       log    => \@log,
 371       action => 'reflog',
 372   );
 373 }
 374
 375 sub search : Local {
 376   my($self, $c) = @_;
 377   $c->stash(current_action => 'GitRepos');
 378   my $project = $c->stash->{Project};
 379   my $commit  = $self->_get_object($c);
 380   # Lifted from /shortlog.
 381   my %logargs = (
 382     sha1   => $commit->sha1,
 383     count  => Gitalist->config->{paging}{log},
 384     ($c->req->param('f') ? (file => $c->req->param('f')) : ()),
 385     search => {
 386       type   => $c->req->param('type'),
 387       text   => $c->req->param('text'),
 388       regexp => $c->req->param('regexp') || 0,
 389     },
 390   );
 391
 392   $c->stash(
 393       commit  => $commit,
 394       results => [$project->list_revs(%logargs)],
 395       action  => 'search',
 396           # This could be added - page      => $page,
 397   );
 398 }
 399
 400 sub atom : Local {
 401   my($self, $c) = @_;
 402
 403   my $feed = XML::Atom::Feed->new;
 404
 405   my $host = lc Sys::Hostname::hostname();
 406   $feed->title($host . ' - ' . Gitalist->config->{name});
 407   $feed->updated(~~DateTime->now);
 408
 409   my $project = $c->stash->{Project};
 410   my %logargs = (
 411       sha1   => $project->head_hash,
 412       count  => Gitalist->config->{paging}{log} || 25,
 413       ($c->req->param('f') ? (file => $c->req->param('f')) : ())
 414   );
 415
 416   my $mk_title = $c->stash->{short_cmt};
 417   for my $commit ($project->list_revs(%logargs)) {
 418     my $entry = XML::Atom::Entry->new;
 419     $entry->title( $mk_title->($commit->comment) );
 420     $entry->id($c->uri_for('commit', {h=>$commit->sha1}));
 421     # XXX Needs work ...
 422     $entry->content($commit->comment);
 423     $feed->add_entry($entry);
 424   }
 425
 426   $c->stash(
 427     feed       => $feed->as_xml,
 428     no_wrapper => 1,
 429   );
 430   $c->response->content_type('application/atom+xml')
 431 }
 432
 433 sub search_help : Local {
 434     # FIXME - implement search_help
 435     Carp::croak "Not implemented.";
 436 }
 437
 438 sub rss : Local {
 439     # FIXME - implement rss
 440     Carp::croak "Not implemented.";
 441 }
 442
 443 sub patch : Local {
 444     # FIXME - implement patches
 445     Carp::croak "Not implemented.";
 446 }
 447
 448 sub patches : Local {
 449     # FIXME - implement patches
 450     Carp::croak "Not implemented.";
 451 }
 452
 453 sub snapshot : Local {
 454     # FIXME - implement snapshot
 455     Carp::croak "Not implemented.";
 456 }
 457
 458 =head2 auto
 459
 460 Populate the header and footer. Perhaps not the best location.
 461
 462 =cut
 463
 464 sub auto : Private {
 465   my($self, $c) = @_;
 466
 467   # XXX Move these to a plugin!
 468   $c->stash(
 469     time_since => sub {
 470       return 'never' unless $_[0];
 471       return age_string(time - $_[0]->epoch);
 472     },
 473     short_cmt => sub {
 474       my $cmt = shift;
 475       my($line) = split /\n/, $cmt;
 476       $line =~ s/^(.{70,80}\b).*/$1 …/;
 477       return $line;
 478     },
 479     abridged_description => sub {
 480         join(' ', grep { defined } (split / /, shift)[0..10]);
 481     },
 482   );
 483
 484   # Yes, this is hideous.
 485   $self->header($c);
 486   $self->footer($c);
 487 }
 488
 489 # XXX This could probably be dropped altogether.
 490 use Gitalist::Util qw(to_utf8);
 491 # Formally git_header_html
 492 sub header {
 493   my($self, $c) = @_;
 494
 495   my $title = $c->config->{sitename};
 496
 497   my $project   = $c->req->param('project')  || $c->req->param('p');
 498   my $action    = $c->req->param('action')   || $c->req->param('a');
 499   my $file_name = $c->req->param('filename') || $c->req->param('f');
 500   if(defined $project) {
 501     $title .= " - " . to_utf8($project);
 502     if (defined $action) {
 503       $title .= "/$action";
 504       if (defined $file_name) {
 505         $title .= " - " . $file_name;
 506         if ($action eq "tree" && $file_name !~ m|/$|) {
 507           $title .= "/";
 508         }
 509       }
 510     }
 511   }
 512
 513   $c->stash->{version}     = $Gitalist::VERSION;
 514   # check git's version by running it on the first project in the list.
 515   $c->stash->{title}       = $title;
 516
 517   $c->stash->{stylesheet} = $c->config->{stylesheet} || 'gitweb.css';
 518
 519   $c->stash->{project} = $project;
 520   my @links;
 521   if($project) {
 522     my %href_params = $self->feed_info($c);
 523     $href_params{'-title'} ||= 'log';
 524
 525     foreach my $format qw(RSS Atom) {
 526       my $type = lc($format);
 527       push @links, {
 528         rel   => 'alternate',
 529         title => "$project - $href_params{'-title'} - $format feed",
 530
 531         # XXX A bit hacky and could do with using gitweb::href() features
 532         href  => "?a=$type;p=$project",
 533         type  => "application/$type+xml"
 534         }, {
 535         rel   => 'alternate',
 536
 537         # XXX This duplication also feels a bit awkward
 538         title => "$project - $href_params{'-title'} - $format feed (no merges)",
 539         href  => "?a=$type;p=$project;opt=--no-merges",
 540         type  => "application/$type+xml"
 541         };
 542     }
 543   } else {
 544     push @links, {
 545       rel => "alternate",
 546       title => $c->config->{sitename}." projects list",
 547       href => '?a=project_index',
 548       type => "text/plain; charset=utf-8"
 549       }, {
 550       rel => "alternate",
 551       title => $c->config->{sitename}." projects feeds",
 552       href => '?a=opml',
 553       type => "text/plain; charset=utf-8"
 554       };
 555   }
 556
 557   $c->stash->{favicon} = $c->config->{favicon};
 558
 559   # </head><body>
 560
 561   $c->stash(
 562     logo_url      => $c->config->{logo_url},
 563     logo_label    => $c->config->{logo_label},
 564     logo_img      => $c->config->{logo},
 565     home_link     => $c->config->{home_link},
 566     home_link_str => $c->config->{home_link_str},
 567     );
 568
 569   if (defined $project) {
 570       eval {
 571           $c->stash(Project => $c->model('GitRepos')->project($project));
 572       };
 573       if ($@) {
 574           $c->detach('error_404');
 575       }
 576       $c->stash(
 577           search_text => ( $c->req->param('s') ||
 578                                $c->req->param('searchtext') || ''),
 579           search_hash => ( $c->req->param('hb') || $c->req->param('hashbase')
 580                                || $c->req->param('h')  || $c->req->param('hash')
 581                                    || 'HEAD' ),
 582       );
 583   }
 584   my $a_project = $c->stash->{Project} || $c->model()->projects->[0];
 585   $c->stash->{git_version} = $a_project->run_cmd('--version');
 586 }
 587
 588 # Formally git_footer_html
 589 sub footer {
 590   my($self, $c) = @_;
 591
 592   my $feed_class = 'rss_logo';
 593
 594   my @feeds;
 595   my $project = $c->req->param('project')  || $c->req->param('p');
 596   if(defined $project) {
 597     (my $pstr = $project) =~ s[/?\.git$][];
 598     my $descr = $c->stash->{project_description}
 599             = $c->stash->{Project} ? $c->stash->{Project}->description : '';
 600
 601     my %href_params = $self->feed_info($c);
 602     if (!%href_params) {
 603       $feed_class .= ' generic';
 604     }
 605     $href_params{'-title'} ||= 'log';
 606
 607     @feeds = [
 608       map +{
 609         class => $feed_class,
 610         title => "$href_params{'-title'} $_ feed",
 611         href  => "/?p=$project;a=\L$_",
 612         name  => lc $_,
 613         }, qw(RSS Atom)
 614       ];
 615   } else {
 616     @feeds = [
 617       map {
 618         class => $feed_class,
 619           title => '',
 620           href  => "/?a=$_->[0]",
 621           name  => $_->[1],
 622         }, [opml=>'OPML'],[project_index=>'TXT'],
 623       ];
 624   }
 625 }
 626
 627 # XXX This feels wrong here, should probably be refactored.
 628 # returns hash to be passed to href to generate gitweb URL
 629 # in -title key it returns description of link
 630 sub feed_info {
 631   my($self, $c) = @_;
 632
 633   my $format = shift || 'Atom';
 634   my %res = (action => lc($format));
 635
 636   # feed links are possible only for project views
 637   return unless $c->req->param('project');
 638
 639   # some views should link to OPML, or to generic project feed,
 640   # or don't have specific feed yet (so they should use generic)
 641   return if $c->req->param('action') =~ /^(?:tags|heads|forks|tag|search)$/x;
 642
 643   my $branch;
 644   my $hash = $c->req->param('h')  || $c->req->param('hash');
 645   my $hash_base = $c->req->param('hb') || $c->req->param('hashbase');
 646
 647   # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
 648   # from tag links; this also makes possible to detect branch links
 649   if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
 650     (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
 651     $branch = $1;
 652   }
 653
 654   # find log type for feed description (title)
 655   my $type = 'log';
 656   my $file_name = $c->req->param('f') || $c->req->param('filename');
 657   if (defined $file_name) {
 658     $type  = "history of $file_name";
 659     $type .= "/" if $c->req->param('action') eq 'tree';
 660     $type .= " on '$branch'" if (defined $branch);
 661   } else {
 662     $type = "log of $branch" if (defined $branch);
 663   }
 664
 665   $res{-title} = $type;
 666   $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
 667   $res{'file_name'} = $file_name;
 668
 669   return %res;
 670 }
 671
 672 =head2 end
 673
 674 Attempt to render a view, if needed.
 675
 676 =cut
 677
 678 sub end : ActionClass('RenderView') {
 679     my ($self, $c) = @_;
 680     # Give project views the current HEAD.
 681     if ($c->stash->{Project}) {
 682         $c->stash->{HEAD} = $c->stash->{Project}->head_hash;
 683     }
 684 }
 685
 686 sub error_404 :Private {
 687     my ($self, $c) = @_;
 688     $c->response->status(404);
 689     $c->stash(
 690         title => 'Page not found',
 691         content => 'Page not found',
 692     );
 693 }
 694
 695 sub age_string {
 696         my $age = shift;
 697         my $age_str;
 698
 699         if ($age > 60*60*24*365*2) {
 700                 $age_str = (int $age/60/60/24/365);
 701                 $age_str .= " years ago";
 702         } elsif ($age > 60*60*24*(365/12)*2) {
 703                 $age_str = int $age/60/60/24/(365/12);
 704                 $age_str .= " months ago";
 705         } elsif ($age > 60*60*24*7*2) {
 706                 $age_str = int $age/60/60/24/7;
 707                 $age_str .= " weeks ago";
 708         } elsif ($age > 60*60*24*2) {
 709                 $age_str = int $age/60/60/24;
 710                 $age_str .= " days ago";
 711         } elsif ($age > 60*60*2) {
 712                 $age_str = int $age/60/60;
 713                 $age_str .= " hours ago";
 714         } elsif ($age > 60*2) {
 715                 $age_str = int $age/60;
 716                 $age_str .= " min ago";
 717         } elsif ($age > 2) {
 718                 $age_str = int $age;
 719                 $age_str .= " sec ago";
 720         } else {
 721                 $age_str .= " right now";
 722         }
 723         return $age_str;
 724 }
 725
 726 =head1 AUTHOR
 727
 728 Dan Brook
 729
 730 =head1 LICENSE
 731
 732 This library is free software. You can redistribute it and/or modify
 733 it under the same terms as Perl itself.
 734
 735 =cut
 736
 737 __PACKAGE__->meta->make_immutable;