lib/Gitalist/Controller/LegacyURI.pm

   1 package Gitalist::Controller::LegacyURI;
   2 use Moose;
   3 use Moose::Autobox;
   4 use namespace::autoclean;
   5
   6 BEGIN { extends 'Gitalist::Controller' }
   7
   8 my %LEGACY_DISPATCH = (
   9     opml                     => sub { '/opml/opml' },
  10     project_index            => sub { '/legacyuri/project_index' },
  11     '(?:summary|heads|tags)' => sub {
  12         my($c, $action, $repos) = @_;
  13         return "/repository/$action", [$repos];
  14     },
  15     blob => sub {
  16         my($c, $action, $repos) = @_;
  17         my $ref = $c->req->param('hb') || $c->req->param('h');
  18         return '/ref/blob', [$repos, $ref], $c->req->param('f');
  19     },
  20     blob_plain               => sub {
  21         my($c, $action, $repos) =  @_;
  22         my $ref = $c->req->param('hb') || $c->req->param('h');
  23         return '/ref/raw', [$repos, $ref], $c->req->param('f');
  24     },
  25     blobdiff                 => sub {
  26         my($c, $action, $repos) =  @_;
  27         my $ref     = $c->req->param('hb')  || $c->req->param('h');
  28         my $compare = $c->req->param('hbp') || $c->req->param('hp');
  29         return '/ref/diff', [$repos, $ref], $compare, $c->req->param('f');
  30     },
  31 );
  32
  33 sub _legacy_uri {
  34     my($self, $c, $repos, $action) = @_;
  35
  36     return
  37         unless $action;
  38
  39     my @result  = grep { $action =~ /^$_$/ } keys %LEGACY_DISPATCH;
  40     die "Matched too many actions for '$a' - @result"
  41         if @result > 1;
  42
  43     return $LEGACY_DISPATCH{$result[0]}->($c, $action, $repos)
  44         if $result[0];
  45 }
  46
  47 sub handler : Chained('/base') PathPart('legacy') Args() {
  48     my ( $self, $c, $repos ) = @_;
  49
  50     my ($action, $captures, @args) = $self->_legacy_uri($c, $repos, $c->req->param('a'));
  51
  52     die("Not supported")
  53         unless $action;
  54
  55     $c->res->redirect($c->uri_for_action($action, $captures || [], @args));
  56     $c->res->status(301);
  57 }
  58
  59 sub project_index : Chained('/base') Args(0) {
  60       my ( $self, $c ) = @_;
  61
  62       $c->response->content_type('text/plain');
  63       $c->response->body(
  64           join "\n", map $_->name, $c->model()->repositories->flatten
  65       ) or die 'No repositories found in '. $c->model->repo_dir;
  66 }
  67
  68 __PACKAGE__->meta->make_immutable;