lib/Gitalist/Controller/Fragment/Ref.pm

   1 package Gitalist::Controller::Fragment::Ref;
   2 use Moose;
   3 use namespace::autoclean;
   4
   5 BEGIN { extends 'Gitalist::Controller' }
   6 with qw/
   7     Gitalist::URIStructure::Ref
   8     Gitalist::URIStructure::Fragment::WithLog
   9 /;
  10
  11 sub base : Chained('/fragment/repository/find') PathPart('') CaptureArgs(0) {}
  12
  13 sub _diff {
  14     my ($self, $c) = @_;
  15     my $commit = $c->stash->{Commit};
  16     my %filename = $c->stash->{filename} ? (filename => $c->stash->{filename}) : ();
  17     my($tree, $patch) = $c->stash->{Repository}->diff(
  18         commit => $commit,
  19         parent => $c->stash->{parent},
  20         patch  => 1,
  21         %filename,
  22     );
  23     $c->stash(
  24       diff_tree => $tree,
  25       diff      => $patch,
  26       # XXX Hack hack hack, see View::SyntaxHighlight
  27       blobs     => [map $_->{diff}, @$patch],
  28       language  => 'Diff',
  29       %filename,
  30     );
  31 }
  32
  33 after diff_fancy => sub {
  34     my ($self, $c) = @_;
  35     $self->_diff($c);
  36     $c->forward('View::SyntaxHighlight');
  37 };
  38
  39 after diff_plain => sub {
  40     my ($self, $c) = @_;
  41     $self->_diff($c);
  42 };
  43
  44 after tree => sub {
  45     my ( $self, $c ) = @_;
  46     my $repository = $c->stash->{Repository};
  47     my $commit  = $c->stash->{Commit};
  48     my $tree    = $c->stash->{filename}
  49       ? $repository->get_object($repository->hash_by_path($commit->sha1, $c->stash->{filename}))
  50       : $repository->get_object($commit->tree_sha1)
  51     ;
  52     $c->stash(
  53         tree      => $tree,
  54         tree_list => [$repository->list_tree($tree->sha1)],
  55     );
  56 };
  57
  58 after blame => sub {
  59     my($self, $c) = @_;
  60
  61     my $repository = $c->stash->{Repository};
  62                                                       # WTF?
  63     my $blame = $c->stash->{Commit}->blame($c->stash->{filename}, $c->stash->{Commit}->sha1);
  64     $c->stash(
  65         blame    => $blame,
  66         # XXX Hack hack hack, see View::SyntaxHighlight
  67         language => ($c->stash->{filename} =~ /\.p[lm]$/i ? 'Perl' : ''),
  68         blob     => join("\n", map $_->{line}, @$blame),
  69     );
  70
  71     $c->forward('View::SyntaxHighlight')
  72         unless $c->stash->{no_wrapper};
  73 };
  74
  75 =head2 blob
  76
  77 The blob action i.e the contents of a file.
  78
  79 =cut
  80
  81 after blob => sub {
  82     my ( $self, $c ) = @_;
  83     $c->stash(
  84         # XXX Hack hack hack, see View::SyntaxHighlight
  85         language => ($c->stash->{filename} =~ /\.p[lm]$/i ? 'Perl' : ''),
  86     );
  87
  88     $c->forward('View::SyntaxHighlight')
  89         unless $c->stash->{no_wrapper};
  90 };
  91
  92 after history => sub {
  93     my ($self, $c) = @_;
  94     my $repository  = $c->stash->{Repository};
  95     my $filename    = $c->stash->{filename};
  96
  97     my %logargs = (
  98        sha1   => $c->stash->{Commit}->sha1,
  99        count  => 25, #Gitalist->config->{paging}{log} || 25,
 100        ($filename ? (file => $filename) : ())
 101     );
 102
 103     my $file = $repository->get_object(
 104         $repository->hash_by_path(
 105             $repository->head_hash,
 106             $filename
 107         )
 108     );
 109
 110     my $page = $c->req->param('pg') || 0;
 111     $logargs{skip} = $c->req->param('pg') * $logargs{count}
 112         if $c->req->param('pg');
 113
 114     $c->stash(
 115        log_lines => [$repository->list_revs(%logargs)],
 116        refs      => $repository->references,
 117        filename  => $filename,
 118        filetype  => $file->type,
 119     );
 120 };
 121
 122 __PACKAGE__->meta->make_immutable;