Add fixmes here

[catagits/CatalystX-HelpText.git] / lib / CatalystX / HelpText / Script / SearchUndocumentedHelpText.pm

package CatalystX::HelpText::Script::SearchUndocumentedHelpText;
use Moose;
use Moose::Autobox;
use MooseX::Types::Path::Class qw/ Dir /;
use MooseX::Types::Moose qw/Str Undef/;
use File::Find;
use Data::Dumper;
use Getopt::Long::Descriptive; # Force GLD as we override bits..
use namespace::autoclean;

has help_files_path => (
    is => 'ro',
    isa => Dir,
    coerce => 1,
    required => 1,
    handles => {
        _get_file => 'file',
    }
);

has template_search_dir => (
    is => 'ro',
    isa => Str,
    default => './',
);

has filename_pattern => (
    is => 'ro',
    isa => Str,
    default => '\.(html|tt)$',
);

has help_files_ext => (
    is => 'ro',
    isa => Str|Undef,
    default => 'html',
);

sub run {
    my ($self) = @_;
    my $filename_pattern = $self->filename_pattern;
    my %helpkeys = ();
    find(
        {
            wanted => sub {
                my $filename = $File::Find::name;
                return unless -f $filename;
                return unless $filename =~ /$filename_pattern/;

                #FIXME - Not a regex here, we should actually pass the templates through TT
                #        and pass in our own callback!
                # I guess the 'here is a file name, hand me the list of links in it'
                # stuff should be delegated to another class (which is settable by command line)
                # to allow people to have alternative methods of using this
                open(FILE, $filename) or warn "Can't open $filename\n" && return;
                while (<FILE>) {
                    if (my ($key) = m/help_text\('(.*)'\)/o) {
                        $helpkeys{$key} = 1;
                    }
                }
                close(FILE);
            },
            bydepth => 1
        }, $self->template_search_dir->flatten);

    my @notfound = ();
    foreach (keys %helpkeys) {
        my $file = $self->_get_file($_);
        $file .= "." . $self->help_files_ext if defined($self->help_files_ext);
        push (@notfound, $file) unless (-e $file);
    }
    # XXX FIXME - This method is way too big!
    # It'd be useless if you wanted to customise it by sub-classing (which we _will_)
    # later want to do as part of our build process!
    # We should have a method to find a list of all the potential files
    # then a for each file method, which calls to the delegate class and
    # then we should build a hash of all the filemame => [qw/ helptext1 helptext 2 /]
    # and then finally we should hand that to a method for pretty printing
    # (and that method needs to unique the finds, which we don't do at the moment)
    print "\nMissing Help Text files:\n" if (scalar @notfound);
    print " - $_\n" for (@notfound);
}

with qw/
    MooseX::Getopt
/;

__PACKAGE__->meta->make_immutable;
__PACKAGE__->new_with_options->run unless caller;

1;