lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11
  12 our $VERSION = '0.30';
  13
  14 __PACKAGE__->mk_accessors('template');
  15 __PACKAGE__->mk_accessors('include_path');
  16
  17 *paths = \&include_path;
  18
  19 =head1 NAME
  20
  21 Catalyst::View::TT - Template View Class
  22
  23 =head1 SYNOPSIS
  24
  25 # use the helper to create your View
  26
  27     myapp_create.pl view TT TT
  28
  29 # configure in lib/MyApp.pm (Could be set from configfile instead)
  30
  31     MyApp->config(
  32         name     => 'MyApp',
  33         root     => MyApp->path_to('root'),
  34         'View::TT' => {
  35             # any TT configurations items go here
  36             INCLUDE_PATH => [
  37               MyApp->path_to( 'root', 'src' ),
  38               MyApp->path_to( 'root', 'lib' ),
  39             ],
  40             TEMPLATE_EXTENSION => '.tt',
  41             CATALYST_VAR => 'c',
  42             TIMER        => 0,
  43             # Not set by default
  44             PRE_PROCESS        => 'config/main',
  45             WRAPPER            => 'site/wrapper',
  46         },
  47     );
  48
  49 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  50
  51     sub message : Global {
  52         my ( $self, $c ) = @_;
  53         $c->stash->{template} = 'message.tt2';
  54         $c->stash->{message}  = 'Hello World!';
  55         $c->forward( $c->view('TT') );
  56     }
  57
  58 # access variables from template
  59
  60     The message is: [% message %].
  61
  62     # example when CATALYST_VAR is set to 'Catalyst'
  63     Context is [% Catalyst %]
  64     The base is [% Catalyst.req.base %]
  65     The name is [% Catalyst.config.name %]
  66
  67     # example when CATALYST_VAR isn't set
  68     Context is [% c %]
  69     The base is [% base %]
  70     The name is [% name %]
  71
  72 =cut
  73
  74 sub _coerce_paths {
  75     my ( $paths, $dlim ) = shift;
  76     return () if ( !$paths );
  77     return @{$paths} if ( ref $paths eq 'ARRAY' );
  78
  79     # tweak delim to ignore C:/
  80     unless ( defined $dlim ) {
  81         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  82     }
  83     return split( /$dlim/, $paths );
  84 }
  85
  86 sub new {
  87     my ( $class, $c, $arguments ) = @_;
  88     my $config = {
  89         EVAL_PERL          => 0,
  90         TEMPLATE_EXTENSION => '',
  91         %{ $class->config },
  92         %{$arguments},
  93     };
  94     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  95         my $delim = $config->{DELIMITER};
  96         my @include_path
  97             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  98         if ( !@include_path ) {
  99             my $root = $c->config->{root};
 100             my $base = Path::Class::dir( $root, 'base' );
 101             @include_path = ( "$root", "$base" );
 102         }
 103         $config->{INCLUDE_PATH} = \@include_path;
 104     }
 105
 106     # if we're debugging and/or the TIMER option is set, then we install
 107     # Template::Timer as a custom CONTEXT object, but only if we haven't
 108     # already got a custom CONTEXT defined
 109
 110     if ( $config->{TIMER} ) {
 111         if ( $config->{CONTEXT} ) {
 112             $c->log->error(
 113                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 114             );
 115         }
 116         else {
 117             $config->{CONTEXT} = Template::Timer->new(%$config);
 118         }
 119     }
 120
 121     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 122         $c->log->debug( "TT Config: ", dump($config) );
 123     }
 124
 125     my $self = $class->next::method(
 126         $c, { %$config },
 127     );
 128
 129     # Set base include paths. Local'd in render if needed
 130     $self->include_path($config->{INCLUDE_PATH});
 131
 132     $self->config($config);
 133
 134     # Creation of template outside of call to new so that we can pass [ $self ]
 135     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 136     # of include paths to search for templates.
 137
 138     # Use a weakend copy of self so we dont have loops preventing GC from working
 139     my $copy = $self;
 140     Scalar::Util::weaken($copy);
 141     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 142
 143     if ( $config->{PROVIDERS} ) {
 144         my @providers = ();
 145         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 146             foreach my $p (@{$config->{PROVIDERS}}) {
 147                 my $pname = $p->{name};
 148                 my $prov = 'Template::Provider';
 149                 if($pname eq '_file_')
 150                 {
 151                     $p->{args} = { %$config };
 152                 }
 153                 else
 154                 {
 155                     if($pname =~ s/^\+//) {
 156                         $prov = $pname;
 157                     }
 158                     else
 159                     {
 160                         $prov .= "::$pname";
 161                     }
 162                     # We copy the args people want from the config
 163                     # to the args
 164                     $p->{args} ||= {};
 165                     if ($p->{copy_config}) {
 166                         map  { $p->{args}->{$_} = $config->{$_}  }
 167                                    grep { exists $config->{$_} }
 168                                    @{ $p->{copy_config} };
 169                     }
 170                 }
 171                 eval "require $prov";
 172                 if(!$@) {
 173                     push @providers, "$prov"->new($p->{args});
 174                 }
 175                 else
 176                 {
 177                     $c->log->warn("Can't load $prov, ($@)");
 178                 }
 179             }
 180         }
 181         delete $config->{PROVIDERS};
 182         if(@providers) {
 183             $config->{LOAD_TEMPLATES} = \@providers;
 184         }
 185     }
 186
 187     $self->{template} =
 188         Template->new($config) || do {
 189             my $error = Template->error();
 190             $c->log->error($error);
 191             $c->error($error);
 192             return undef;
 193         };
 194
 195
 196     return $self;
 197 }
 198
 199 sub process {
 200     my ( $self, $c ) = @_;
 201
 202     my $template = $c->stash->{template}
 203       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 204
 205     unless (defined $template) {
 206         $c->log->debug('No template specified for rendering') if $c->debug;
 207         return 0;
 208     }
 209
 210     my $output = $self->render($c, $template);
 211
 212     if (UNIVERSAL::isa($output, 'Template::Exception')) {
 213         my $error = qq/Couldn't render template "$output"/;
 214         $c->log->error($error);
 215         $c->error($error);
 216         return 0;
 217     }
 218
 219     unless ( $c->response->content_type ) {
 220         $c->response->content_type('text/html; charset=utf-8');
 221     }
 222
 223     $c->response->body($output);
 224
 225     return 1;
 226 }
 227
 228 sub render {
 229     my ($self, $c, $template, $args) = @_;
 230
 231     $c->log->debug(qq/Rendering template "$template"/) if $c->debug;
 232
 233     my $output;
 234     my $vars = {
 235         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 236         $self->template_vars($c)
 237     };
 238
 239     local $self->{include_path} =
 240         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 241         if ref $vars->{additional_template_paths};
 242
 243     unless ($self->template->process( $template, $vars, \$output ) ) {
 244         return $self->template->error;
 245     } else {
 246         return $output;
 247     }
 248 }
 249
 250 sub template_vars {
 251     my ( $self, $c ) = @_;
 252
 253     my $cvar = $self->config->{CATALYST_VAR};
 254
 255     defined $cvar
 256       ? ( $cvar => $c )
 257       : (
 258         c    => $c,
 259         base => $c->req->base,
 260         name => $c->config->{name}
 261       )
 262 }
 263
 264
 265 1;
 266
 267 __END__
 268
 269 =head1 DESCRIPTION
 270
 271 This is the Catalyst view class for the L<Template Toolkit|Template>.
 272 Your application should defined a view class which is a subclass of
 273 this module.  The easiest way to achieve this is using the
 274 F<myapp_create.pl> script (where F<myapp> should be replaced with
 275 whatever your application is called).  This script is created as part
 276 of the Catalyst setup.
 277
 278     $ script/myapp_create.pl view TT TT
 279
 280 This creates a MyApp::View::TT.pm module in the F<lib> directory (again,
 281 replacing C<MyApp> with the name of your application) which looks
 282 something like this:
 283
 284     package FooBar::View::TT;
 285
 286     use strict;
 287     use warnings;
 288
 289     use base 'Catalyst::View::TT';
 290
 291     __PACKAGE__->config->{DEBUG} = 'all';
 292
 293 Now you can modify your action handlers in the main application and/or
 294 controllers to forward to your view class.  You might choose to do this
 295 in the end() method, for example, to automatically forward all actions
 296 to the TT view class.
 297
 298     # In MyApp or MyApp::Controller::SomeController
 299
 300     sub end : Private {
 301         my( $self, $c ) = @_;
 302         $c->forward( $c->view('TT') );
 303     }
 304
 305 =head2 CONFIGURATION
 306
 307 There are a three different ways to configure your view class.  The
 308 first way is to call the C<config()> method in the view subclass.  This
 309 happens when the module is first loaded.
 310
 311     package MyApp::View::TT;
 312
 313     use strict;
 314     use base 'Catalyst::View::TT';
 315
 316     MyApp::View::TT->config({
 317         INCLUDE_PATH => [
 318             MyApp->path_to( 'root', 'templates', 'lib' ),
 319             MyApp->path_to( 'root', 'templates', 'src' ),
 320         ],
 321         PRE_PROCESS  => 'config/main',
 322         WRAPPER      => 'site/wrapper',
 323     });
 324
 325 The second way is to define a C<new()> method in your view subclass.
 326 This performs the configuration when the view object is created,
 327 shortly after being loaded.  Remember to delegate to the base class
 328 C<new()> method (via C<$self-E<gt>next::method()> in the example below) after
 329 performing any configuration.
 330
 331     sub new {
 332         my $self = shift;
 333         $self->config({
 334             INCLUDE_PATH => [
 335                 MyApp->path_to( 'root', 'templates', 'lib' ),
 336                 MyApp->path_to( 'root', 'templates', 'src' ),
 337             ],
 338             PRE_PROCESS  => 'config/main',
 339             WRAPPER      => 'site/wrapper',
 340         });
 341         return $self->next::method(@_);
 342     }
 343
 344 The final, and perhaps most direct way, is to define a class
 345 item in your main application configuration, again by calling the
 346 ubiquitous C<config()> method.  The items in the class hash are
 347 added to those already defined by the above two methods.  This happens
 348 in the base class new() method (which is one reason why you must
 349 remember to call it via C<MRO::Compat> if you redefine the C<new()>
 350 method in a subclass).
 351
 352     package MyApp;
 353
 354     use strict;
 355     use Catalyst;
 356
 357     MyApp->config({
 358         name     => 'MyApp',
 359         root     => MyApp->path_to('root'),
 360         'View::TT' => {
 361             INCLUDE_PATH => [
 362                 MyApp->path_to( 'root', 'templates', 'lib' ),
 363                 MyApp->path_to( 'root', 'templates', 'src' ),
 364             ],
 365             PRE_PROCESS  => 'config/main',
 366             WRAPPER      => 'site/wrapper',
 367         },
 368     });
 369
 370 Note that any configuration items defined by one of the earlier
 371 methods will be overwritten by items of the same name provided by the
 372 latter methods.
 373
 374 =head2 DYNAMIC INCLUDE_PATH
 375
 376 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 377
 378 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 379 follows:
 380
 381     $c->stash->{additional_template_paths} =
 382         [$c->config->{root} . '/test_include_path'];
 383
 384 If you need to add paths to the end of INCLUDE_PATH, there is also an
 385 include_path() accessor available:
 386
 387     push( @{ $c->view('TT')->include_path }, qw/path/ );
 388
 389 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 390 MUST check for duplicate paths. Without such checking, the above code will add
 391 "path" to INCLUDE_PATH at every request, causing a memory leak.
 392
 393 A safer approach is to use include_path() to overwrite the array of paths
 394 rather than adding to it. This eliminates both the need to perform duplicate
 395 checking and the chance of a memory leak:
 396
 397     @{ $c->view('TT')->include_path } = qw/path another_path/;
 398
 399 If you are calling C<render> directly then you can specify dynamic paths by
 400 having a C<additional_template_paths> key with a value of additonal directories
 401 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 402
 403 =head2 RENDERING VIEWS
 404
 405 The view plugin renders the template specified in the C<template>
 406 item in the stash.
 407
 408     sub message : Global {
 409         my ( $self, $c ) = @_;
 410         $c->stash->{template} = 'message.tt2';
 411         $c->forward( $c->view('TT') );
 412     }
 413
 414 If a stash item isn't defined, then it instead uses the
 415 stringification of the action dispatched to (as defined by $c->action)
 416 in the above example, this would be C<message>, but because the default
 417 is to append '.tt', it would load C<root/message.tt>.
 418
 419 The items defined in the stash are passed to the Template Toolkit for
 420 use as template variables.
 421
 422     sub default : Private {
 423         my ( $self, $c ) = @_;
 424         $c->stash->{template} = 'message.tt2';
 425         $c->stash->{message}  = 'Hello World!';
 426         $c->forward( $c->view('TT') );
 427     }
 428
 429 A number of other template variables are also added:
 430
 431     c      A reference to the context object, $c
 432     base   The URL base, from $c->req->base()
 433     name   The application name, from $c->config->{ name }
 434
 435 These can be accessed from the template in the usual way:
 436
 437 <message.tt2>:
 438
 439     The message is: [% message %]
 440     The base is [% base %]
 441     The name is [% name %]
 442
 443
 444 The output generated by the template is stored in C<< $c->response->body >>.
 445
 446 =head2 CAPTURING TEMPLATE OUTPUT
 447
 448 If you wish to use the output of a template for some other purpose than
 449 displaying in the response, e.g. for sending an email, this is possible using
 450 L<Catalyst::Plugin::Email> and the L<render> method:
 451
 452   sub send_email : Local {
 453     my ($self, $c) = @_;
 454
 455     $c->email(
 456       header => [
 457         To      => 'me@localhost',
 458         Subject => 'A TT Email',
 459       ],
 460       body => $c->view('TT')->render($c, 'email.tt', {
 461         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 462         email_tmpl_param1 => 'foo'
 463         }
 464       ),
 465     );
 466   # Redirect or display a message
 467   }
 468
 469 =head2 TEMPLATE PROFILING
 470
 471 See L<C<TIMER>> property of the L<config> method.
 472
 473 =head2 METHODS
 474
 475 =head2 new
 476
 477 The constructor for the TT view. Sets up the template provider,
 478 and reads the application config.
 479
 480 =head2 process
 481
 482 Renders the template specified in C<< $c->stash->{template} >> or
 483 C<< $c->action >> (the private name of the matched action).  Calls L<render> to
 484 perform actual rendering. Output is stored in C<< $c->response->body >>.
 485
 486 =head2 render($c, $template, \%args)
 487
 488 Renders the given template and returns output, or a L<Template::Exception>
 489 object upon error.
 490
 491 The template variables are set to C<%$args> if $args is a hashref, or
 492 $C<< $c->stash >> otherwise. In either case the variables are augmented with
 493 C<base> set to C< << $c->req->base >>, C<c> to C<$c> and C<name> to
 494 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 495 can be defined to specify the name of a template variable through which the
 496 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base> and
 497 C<name> variables are omitted.
 498
 499 C<$template> can be anything that Template::process understands how to
 500 process, including the name of a template file or a reference to a test string.
 501 See L<Template::process|Template/process> for a full list of supported formats.
 502
 503 =head2 template_vars
 504
 505 Returns a list of keys/values to be used as the catalyst variables in the
 506 template.
 507
 508 =head2 config
 509
 510 This method allows your view subclass to pass additional settings to
 511 the TT configuration hash, or to set the options as below:
 512
 513 =head2 paths
 514
 515 The list of paths TT will look for templates in.
 516
 517 =head2 C<CATALYST_VAR>
 518
 519 Allows you to change the name of the Catalyst context object. If set, it will also
 520 remove the base and name aliases, so you will have access them through <context>.
 521
 522 For example:
 523
 524     MyApp->config({
 525         name     => 'MyApp',
 526         root     => MyApp->path_to('root'),
 527         'View::TT' => {
 528             CATALYST_VAR => 'Catalyst',
 529         },
 530     });
 531
 532 F<message.tt2>:
 533
 534     The base is [% Catalyst.req.base %]
 535     The name is [% Catalyst.config.name %]
 536
 537 =head2 C<TIMER>
 538
 539 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 540 C<Catalyst::View::TT> will enable profiling of template processing
 541 (using L<Template::Timer>). This will embed HTML comments in the
 542 output from your templates, such as:
 543
 544     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 545     <!-- TIMER START: include mainmenu/cssindex.tt -->
 546     <!-- TIMER START: process mainmenu/cssindex.tt -->
 547     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 548     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 549
 550     ....
 551
 552     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 553
 554
 555 =head2 C<TEMPLATE_EXTENSION>
 556
 557 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 558
 559 For example:
 560
 561   package MyApp::Controller::Test;
 562   sub test : Local { .. }
 563
 564 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 565 <root>/test/test.tt.
 566
 567 =head2 C<PROVIDERS>
 568
 569 Allows you to specify the template providers that TT will use.
 570
 571     MyApp->config({
 572         name     => 'MyApp',
 573         root     => MyApp->path_to('root'),
 574         'View::TT' => {
 575             PROVIDERS => [
 576                 {
 577                     name    => 'DBI',
 578                     args    => {
 579                         DBI_DSN => 'dbi:DB2:books',
 580                         DBI_USER=> 'foo'
 581                     }
 582                 }, {
 583                     name    => '_file_',
 584                     args    => {}
 585                 }
 586             ]
 587         },
 588     });
 589
 590 The 'name' key should correspond to the class name of the provider you
 591 want to use.  The _file_ name is a special case that represents the default
 592 TT file-based provider.  By default the name is will be prefixed with
 593 'Template::Provider::'.  You can fully qualify the name by using a unary
 594 plus:
 595
 596     name => '+MyApp::Provider::Foo'
 597
 598 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 599 from the general config, into the config for the provider:
 600
 601     DEFAULT_ENCODING    => 'utf-8',
 602     PROVIDERS => [
 603         {
 604             name    => 'Encoding',
 605             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 606         }
 607     ]
 608
 609 This can prove useful when you want to use the additional_template_paths hack
 610 in your own provider, or if you need to use Template::Provider::Encoding
 611
 612 =head2 HELPERS
 613
 614 The L<Catalyst::Helper::View::TT> and
 615 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 616 your view module.  There are invoked by the F<myapp_create.pl> script:
 617
 618     $ script/myapp_create.pl view TT TT
 619
 620     $ script/myapp_create.pl view TT TTSite
 621
 622 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 623 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 624 further.  It also creates a default set of templates to get you
 625 started.  It also configures the view module to locate the templates
 626 automatically.
 627
 628 =head1 SEE ALSO
 629
 630 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 631 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 632
 633 =head1 AUTHORS
 634
 635 Sebastian Riedel, C<sri@cpan.org>
 636
 637 Marcus Ramberg, C<mramberg@cpan.org>
 638
 639 Jesse Sheidlower, C<jester@panix.com>
 640
 641 Andy Wardley, C<abw@cpan.org>
 642
 643 =head1 COPYRIGHT
 644
 645 This program is free software. You can redistribute it and/or modify it
 646 under the same terms as Perl itself.
 647
 648 =cut