lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use base qw/Catalyst::View/;
   5 use Data::Dump 'dump';
   6 use Template;
   7 use Template::Timer;
   8 use NEXT;
   9
  10 our $VERSION = '0.26';
  11
  12 __PACKAGE__->mk_accessors('template');
  13 __PACKAGE__->mk_accessors('include_path');
  14
  15 *paths = \&include_path;
  16
  17 =head1 NAME
  18
  19 Catalyst::View::TT - Template View Class
  20
  21 =head1 SYNOPSIS
  22
  23 # use the helper to create your View
  24     myapp_create.pl view TT TT
  25
  26 # configure in lib/MyApp.pm
  27
  28     MyApp->config(
  29         name     => 'MyApp',
  30         root     => MyApp->path_to('root'),
  31         'View::TT' => {
  32             # any TT configurations items go here
  33             INCLUDE_PATH => [
  34               MyApp->path_to( 'root', 'src' ),
  35               MyApp->path_to( 'root', 'lib' ),
  36             ],
  37             PRE_PROCESS        => 'config/main',
  38             WRAPPER            => 'site/wrapper',
  39             TEMPLATE_EXTENSION => '.tt',
  40
  41             # two optional config items
  42             CATALYST_VAR => 'Catalyst',
  43             TIMER        => 1,
  44         },
  45     );
  46
  47 # render view from lib/MyApp.pm or lib/MyApp::C::SomeController.pm
  48
  49     sub message : Global {
  50         my ( $self, $c ) = @_;
  51         $c->stash->{template} = 'message.tt2';
  52         $c->stash->{message}  = 'Hello World!';
  53         $c->forward('MyApp::V::TT');
  54     }
  55
  56 # access variables from template
  57
  58     The message is: [% message %].
  59
  60     # example when CATALYST_VAR is set to 'Catalyst'
  61     Context is [% Catalyst %]
  62     The base is [% Catalyst.req.base %]
  63     The name is [% Catalyst.config.name %]
  64
  65     # example when CATALYST_VAR isn't set
  66     Context is [% c %]
  67     The base is [% base %]
  68     The name is [% name %]
  69
  70 =cut
  71
  72 sub _coerce_paths {
  73     my ( $paths, $dlim ) = shift;
  74     return () if ( !$paths );
  75     return @{$paths} if ( ref $paths eq 'ARRAY' );
  76
  77     # tweak delim to ignore C:/
  78     unless ( defined $dlim ) {
  79         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  80     }
  81     return split( /$dlim/, $paths );
  82 }
  83
  84 sub new {
  85     my ( $class, $c, $arguments ) = @_;
  86     my $config = {
  87         EVAL_PERL          => 0,
  88         TEMPLATE_EXTENSION => '',
  89         %{ $class->config },
  90         %{$arguments},
  91     };
  92     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  93         my $delim = $config->{DELIMITER};
  94         my @include_path
  95             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  96         if ( !@include_path ) {
  97             my $root = $c->config->{root};
  98             my $base = Path::Class::dir( $root, 'base' );
  99             @include_path = ( "$root", "$base" );
 100         }
 101         $config->{INCLUDE_PATH} = \@include_path;
 102     }
 103
 104     # if we're debugging and/or the TIMER option is set, then we install
 105     # Template::Timer as a custom CONTEXT object, but only if we haven't
 106     # already got a custom CONTEXT defined
 107
 108     if ( $config->{TIMER} ) {
 109         if ( $config->{CONTEXT} ) {
 110             $c->log->error(
 111                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 112             );
 113         }
 114         else {
 115             $config->{CONTEXT} = Template::Timer->new(%$config);
 116         }
 117     }
 118
 119     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 120         $c->log->debug( "TT Config: ", dump($config) );
 121     }
 122     if ( $config->{PROVIDERS} ) {
 123         my @providers = ();
 124         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 125             foreach my $p (@{$config->{PROVIDERS}}) {
 126                 my $pname = $p->{name};
 127                 my $prov = 'Template::Provider';
 128                 if($pname eq '_file_')
 129                 {
 130                     $p->{args} = { %$config };
 131                 }
 132                 else
 133                 {
 134                     $prov .="::$pname" if($pname ne '_file_');
 135                 }
 136                 eval "require $prov";
 137                 if(!$@) {
 138                     push @providers, "$prov"->new($p->{args});
 139                 }
 140                 else
 141                 {
 142                     $c->log->warn("Can't load $prov, ($@)");
 143                 }
 144             }
 145         }
 146         delete $config->{PROVIDERS};
 147         if(@providers) {
 148             $config->{LOAD_TEMPLATES} = \@providers;
 149         }
 150     }
 151
 152     my $self = $class->NEXT::new(
 153         $c, { %$config },
 154     );
 155
 156     # Set base include paths. Local'd in render if needed
 157     $self->include_path($config->{INCLUDE_PATH});
 158
 159     $self->config($config);
 160
 161     # Creation of template outside of call to new so that we can pass [ $self ]
 162     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 163     # of include paths to search for templates.
 164
 165     # Use a weakend copy of self so we dont have loops preventing GC from working
 166     my $copy = $self;
 167     Scalar::Util::weaken($copy);
 168     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 169
 170     $self->{template} =
 171         Template->new($config) || do {
 172             my $error = Template->error();
 173             $c->log->error($error);
 174             $c->error($error);
 175             return undef;
 176         };
 177
 178
 179     return $self;
 180 }
 181
 182 sub process {
 183     my ( $self, $c ) = @_;
 184
 185     my $template = $c->stash->{template}
 186       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 187
 188     unless (defined $template) {
 189         $c->log->debug('No template specified for rendering') if $c->debug;
 190         return 0;
 191     }
 192
 193     my $output = $self->render($c, $template);
 194
 195     if (UNIVERSAL::isa($output, 'Template::Exception')) {
 196         my $error = qq/Couldn't render template "$output"/;
 197         $c->log->error($error);
 198         $c->error($error);
 199         return 0;
 200     }
 201
 202     unless ( $c->response->content_type ) {
 203         $c->response->content_type('text/html; charset=utf-8');
 204     }
 205
 206     $c->response->body($output);
 207
 208     return 1;
 209 }
 210
 211 sub render {
 212     my ($self, $c, $template, $args) = @_;
 213
 214     $c->log->debug(qq/Rendering template "$template"/) if $c->debug;
 215
 216     my $output;
 217     my $vars = {
 218         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 219         $self->template_vars($c)
 220     };
 221
 222     local $self->{include_path} =
 223         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 224         if ref $vars->{additional_template_paths};
 225
 226     unless ($self->template->process( $template, $vars, \$output ) ) {
 227         return $self->template->error;
 228     } else {
 229         return $output;
 230     }
 231 }
 232
 233 sub template_vars {
 234     my ( $self, $c ) = @_;
 235
 236     my $cvar = $self->config->{CATALYST_VAR};
 237
 238     defined $cvar
 239       ? ( $cvar => $c )
 240       : (
 241         c    => $c,
 242         base => $c->req->base,
 243         name => $c->config->{name}
 244       )
 245 }
 246
 247
 248 1;
 249
 250 __END__
 251
 252 =head1 DESCRIPTION
 253
 254 This is the Catalyst view class for the L<Template Toolkit|Template>.
 255 Your application should defined a view class which is a subclass of
 256 this module.  The easiest way to achieve this is using the
 257 F<myapp_create.pl> script (where F<myapp> should be replaced with
 258 whatever your application is called).  This script is created as part
 259 of the Catalyst setup.
 260
 261     $ script/myapp_create.pl view TT TT
 262
 263 This creates a MyApp::V::TT.pm module in the F<lib> directory (again,
 264 replacing C<MyApp> with the name of your application) which looks
 265 something like this:
 266
 267     package FooBar::V::TT;
 268
 269     use strict;
 270      use base 'Catalyst::View::TT';
 271
 272     __PACKAGE__->config->{DEBUG} = 'all';
 273
 274 Now you can modify your action handlers in the main application and/or
 275 controllers to forward to your view class.  You might choose to do this
 276 in the end() method, for example, to automatically forward all actions
 277 to the TT view class.
 278
 279     # In MyApp or MyApp::Controller::SomeController
 280
 281     sub end : Private {
 282         my( $self, $c ) = @_;
 283         $c->forward('MyApp::V::TT');
 284     }
 285
 286 =head2 CONFIGURATION
 287
 288 There are a three different ways to configure your view class.  The
 289 first way is to call the C<config()> method in the view subclass.  This
 290 happens when the module is first loaded.
 291
 292     package MyApp::V::TT;
 293
 294     use strict;
 295     use base 'Catalyst::View::TT';
 296
 297     MyApp::V::TT->config({
 298         INCLUDE_PATH => [
 299             MyApp->path_to( 'root', 'templates', 'lib' ),
 300             MyApp->path_to( 'root', 'templates', 'src' ),
 301         ],
 302         PRE_PROCESS  => 'config/main',
 303         WRAPPER      => 'site/wrapper',
 304     });
 305
 306 The second way is to define a C<new()> method in your view subclass.
 307 This performs the configuration when the view object is created,
 308 shortly after being loaded.  Remember to delegate to the base class
 309 C<new()> method (via C<$self-E<gt>NEXT::new()> in the example below) after
 310 performing any configuration.
 311
 312     sub new {
 313         my $self = shift;
 314         $self->config({
 315             INCLUDE_PATH => [
 316                 MyApp->path_to( 'root', 'templates', 'lib' ),
 317                 MyApp->path_to( 'root', 'templates', 'src' ),
 318             ],
 319             PRE_PROCESS  => 'config/main',
 320             WRAPPER      => 'site/wrapper',
 321         });
 322         return $self->NEXT::new(@_);
 323     }
 324
 325 The final, and perhaps most direct way, is to define a class
 326 item in your main application configuration, again by calling the
 327 uniquitous C<config()> method.  The items in the class hash are
 328 added to those already defined by the above two methods.  This happens
 329 in the base class new() method (which is one reason why you must
 330 remember to call it via C<NEXT> if you redefine the C<new()> method in a
 331 subclass).
 332
 333     package MyApp;
 334
 335     use strict;
 336     use Catalyst;
 337
 338     MyApp->config({
 339         name     => 'MyApp',
 340         root     => MyApp->path_to('root'),
 341         'V::TT' => {
 342             INCLUDE_PATH => [
 343                 MyApp->path_to( 'root', 'templates', 'lib' ),
 344                 MyApp->path_to( 'root', 'templates', 'src' ),
 345             ],
 346             PRE_PROCESS  => 'config/main',
 347             WRAPPER      => 'site/wrapper',
 348         },
 349     });
 350
 351 Note that any configuration items defined by one of the earlier
 352 methods will be overwritten by items of the same name provided by the
 353 latter methods.
 354
 355 =head2 DYNAMIC INCLUDE_PATH
 356
 357 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 358
 359 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 360 follows:
 361
 362     $c->stash->{additional_template_paths} =
 363         [$c->config->{root} . '/test_include_path'];
 364
 365 If you need to add paths to the end of INCLUDE_PATH, there is also an
 366 include_path() accessor available:
 367
 368     push( @{ $c->view('TT')->include_path }, qw/path/ );
 369
 370 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 371 MUST check for duplicate paths. Without such checking, the above code will add
 372 "path" to INCLUDE_PATH at every request, causing a memory leak.
 373
 374 A safer approach is to use include_path() to overwrite the array of paths
 375 rather than adding to it. This eliminates both the need to perform duplicate
 376 checking and the chance of a memory leak:
 377
 378     @{ $c->view('TT')->include_path } = qw/path another_path/;
 379
 380 If you are calling C<render> directly then you can specify dynamic paths by
 381 having a C<additional_template_paths> key with a value of additonal directories
 382 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 383
 384 =head2 RENDERING VIEWS
 385
 386 The view plugin renders the template specified in the C<template>
 387 item in the stash.
 388
 389     sub message : Global {
 390         my ( $self, $c ) = @_;
 391         $c->stash->{template} = 'message.tt2';
 392         $c->forward('MyApp::V::TT');
 393     }
 394
 395 If a stash item isn't defined, then it instead uses the
 396 stringification of the action dispatched to (as defined by $c->action)
 397 in the above example, this would be C<message>, but because the default
 398 is to append '.tt', it would load C<root/message.tt>.
 399
 400 The items defined in the stash are passed to the Template Toolkit for
 401 use as template variables.
 402
 403     sub default : Private {
 404         my ( $self, $c ) = @_;
 405         $c->stash->{template} = 'message.tt2';
 406         $c->stash->{message}  = 'Hello World!';
 407         $c->forward('MyApp::V::TT');
 408     }
 409
 410 A number of other template variables are also added:
 411
 412     c      A reference to the context object, $c
 413     base   The URL base, from $c->req->base()
 414     name   The application name, from $c->config->{ name }
 415
 416 These can be accessed from the template in the usual way:
 417
 418 <message.tt2>:
 419
 420     The message is: [% message %]
 421     The base is [% base %]
 422     The name is [% name %]
 423
 424
 425 The output generated by the template is stored in C<< $c->response->body >>.
 426
 427 =head2 CAPTURING TEMPLATE OUTPUT
 428
 429 If you wish to use the output of a template for some other purpose than
 430 displaying in the response, e.g. for sending an email, this is possible using
 431 L<Catalyst::Plugin::Email> and the L<render> method:
 432
 433   sub send_email : Local {
 434     my ($self, $c) = @_;
 435
 436     $c->email(
 437       header => [
 438         To      => 'me@localhost',
 439         Subject => 'A TT Email',
 440       ],
 441       body => $c->view('TT')->render($c, 'email.tt', {
 442         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 443         email_tmpl_param1 => 'foo'
 444         }
 445       ),
 446     );
 447   # Redirect or display a message
 448   }
 449
 450 =head2 TEMPLATE PROFILING
 451
 452 See L<C<TIMER>> property of the L<config> method.
 453
 454 =head2 METHODS
 455
 456 =head2 new
 457
 458 The constructor for the TT view. Sets up the template provider,
 459 and reads the application config.
 460
 461 =head2 process
 462
 463 Renders the template specified in C<< $c->stash->{template} >> or
 464 C<< $c->action >> (the private name of the matched action.  Calls L<render> to
 465 perform actual rendering. Output is stored in C<< $c->response->body >>.
 466
 467 =head2 render($c, $template, \%args)
 468
 469 Renders the given template and returns output, or a L<Template::Exception>
 470 object upon error.
 471
 472 The template variables are set to C<%$args> if $args is a hashref, or
 473 $C<< $c->stash >> otherwise. In either case the variables are augmented with
 474 C<base> set to C< << $c->req->base >>, C<c> to C<$c> and C<name> to
 475 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 476 can be defined to specify the name of a template variable through which the
 477 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base> and
 478 C<name> variables are omitted.
 479
 480 C<$template> can be anything that Template::process understands how to
 481 process, including the name of a template file or a reference to a test string.
 482 See L<Template::process|Template/process> for a full list of supported formats.
 483
 484 =head2 template_vars
 485
 486 Returns a list of keys/values to be used as the catalyst variables in the
 487 template.
 488
 489 =head2 config
 490
 491 This method allows your view subclass to pass additional settings to
 492 the TT configuration hash, or to set the options as below:
 493
 494 =head2 paths
 495
 496 The list of paths TT will look for templates in.
 497
 498 =head2 C<CATALYST_VAR>
 499
 500 Allows you to change the name of the Catalyst context object. If set, it will also
 501 remove the base and name aliases, so you will have access them through <context>.
 502
 503 For example:
 504
 505     MyApp->config({
 506         name     => 'MyApp',
 507         root     => MyApp->path_to('root'),
 508         'V::TT' => {
 509             CATALYST_VAR => 'Catalyst',
 510         },
 511     });
 512
 513 F<message.tt2>:
 514
 515     The base is [% Catalyst.req.base %]
 516     The name is [% Catalyst.config.name %]
 517
 518 =head2 C<TIMER>
 519
 520 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 521 C<Catalyst::View::TT> will enable profiling of template processing
 522 (using L<Template::Timer>). This will embed HTML comments in the
 523 output from your templates, such as:
 524
 525     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 526     <!-- TIMER START: include mainmenu/cssindex.tt -->
 527     <!-- TIMER START: process mainmenu/cssindex.tt -->
 528     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 529     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 530
 531     ....
 532
 533     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 534
 535
 536 =head2 C<TEMPLATE_EXTENSION>
 537
 538 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 539
 540 For example:
 541
 542   package MyApp::C::Test;
 543   sub test : Local { .. }
 544
 545 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 546 <root>/test/test.tt.
 547
 548 =head2 HELPERS
 549
 550 The L<Catalyst::Helper::View::TT> and
 551 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 552 your view module.  There are invoked by the F<myapp_create.pl> script:
 553
 554     $ script/myapp_create.pl view TT TT
 555
 556     $ script/myapp_create.pl view TT TTSite
 557
 558 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 559 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 560 further.  It also creates a default set of templates to get you
 561 started.  It also configures the view module to locate the templates
 562 automatically.
 563
 564 =head1 SEE ALSO
 565
 566 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 567 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 568
 569 =head1 AUTHORS
 570
 571 Sebastian Riedel, C<sri@cpan.org>
 572
 573 Marcus Ramberg, C<mramberg@cpan.org>
 574
 575 Jesse Sheidlower, C<jester@panix.com>
 576
 577 Andy Wardley, C<abw@cpan.org>
 578
 579 =head1 COPYRIGHT
 580
 581 This program is free software, you can redistribute it and/or modify it
 582 under the same terms as Perl itself.
 583
 584 =cut