lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use base qw/Catalyst::View/;
   5 use Template;
   6 use Template::Timer;
   7 use NEXT;
   8
   9 our $VERSION = '0.20';
  10
  11 __PACKAGE__->mk_accessors('template');
  12 __PACKAGE__->mk_accessors('include_path');
  13
  14 =head1 NAME
  15
  16 Catalyst::View::TT - Template View Class
  17
  18 =head1 SYNOPSIS
  19
  20 # use the helper to create View
  21     myapp_create.pl view TT TT
  22
  23 # configure in lib/MyApp.pm
  24
  25     MyApp->config({
  26         name     => 'MyApp',
  27         root     => MyApp->path_to('root');,
  28         'V::TT' => {
  29             # any TT configurations items go here
  30             INCLUDE_PATH => [
  31               MyApp->path_to( 'root', 'src' ),
  32               MyApp->path_to( 'root', 'lib' ),
  33             ],
  34             PRE_PROCESS        => 'config/main',
  35             WRAPPER            => 'site/wrapper',
  36             TEMPLATE_EXTENSION => '.tt',
  37
  38             # two optional config items
  39             CATALYST_VAR => 'Catalyst',
  40             TIMER        => 1,
  41         },
  42     });
  43
  44 # render view from lib/MyApp.pm or lib/MyApp::C::SomeController.pm
  45
  46     sub message : Global {
  47         my ( $self, $c ) = @_;
  48         $c->stash->{template} = 'message.tt2';
  49         $c->stash->{message}  = 'Hello World!';
  50         $c->forward('MyApp::V::TT');
  51     }
  52
  53 # access variables from template
  54
  55     The message is: [% message %].
  56
  57     # example when CATALYST_VAR is set to 'Catalyst'
  58     Context is [% Catalyst %]
  59     The base is [% Catalyst.req.base %]
  60     The name is [% Catalyst.config.name %]
  61
  62     # example when CATALYST_VAR isn't set
  63     Context is [% c %]
  64     The base is [% base %]
  65     The name is [% name %]
  66
  67 =head1 DESCRIPTION
  68
  69 This is the Catalyst view class for the L<Template Toolkit|Template>.
  70 Your application should defined a view class which is a subclass of
  71 this module.  The easiest way to achieve this is using the
  72 F<myapp_create.pl> script (where F<myapp> should be replaced with
  73 whatever your application is called).  This script is created as part
  74 of the Catalyst setup.
  75
  76     $ script/myapp_create.pl view TT TT
  77
  78 This creates a MyApp::V::TT.pm module in the F<lib> directory (again,
  79 replacing C<MyApp> with the name of your application) which looks
  80 something like this:
  81
  82     package FooBar::V::TT;
  83
  84     use strict;
  85      use base 'Catalyst::View::TT';
  86
  87     __PACKAGE__->config->{DEBUG} = 'all';
  88
  89 Now you can modify your action handlers in the main application and/or
  90 controllers to forward to your view class.  You might choose to do this
  91 in the end() method, for example, to automatically forward all actions
  92 to the TT view class.
  93
  94     # In MyApp or MyApp::Controller::SomeController
  95
  96     sub end : Private {
  97         my( $self, $c ) = @_;
  98         $c->forward('MyApp::V::TT');
  99     }
 100
 101 =head2 CONFIGURATION
 102
 103 There are a three different ways to configure your view class.  The
 104 first way is to call the C<config()> method in the view subclass.  This
 105 happens when the module is first loaded.
 106
 107     package MyApp::V::TT;
 108
 109     use strict;
 110     use base 'Catalyst::View::TT';
 111
 112     MyApp::V::TT->config({
 113         INCLUDE_PATH => [
 114             MyApp->path_to( 'root', 'templates', 'lib' ),
 115             MyApp->path_to( 'root', 'templates', 'src' ),
 116         ],
 117         PRE_PROCESS  => 'config/main',
 118         WRAPPER      => 'site/wrapper',
 119     });
 120
 121 The second way is to define a C<new()> method in your view subclass.
 122 This performs the configuration when the view object is created,
 123 shortly after being loaded.  Remember to delegate to the base class
 124 C<new()> method (via C<$self-E<gt>NEXT::new()> in the example below) after
 125 performing any configuration.
 126
 127     sub new {
 128         my $self = shift;
 129         $self->config({
 130             INCLUDE_PATH => [
 131                 MyApp->path_to( 'root', 'templates', 'lib' ),
 132                 MyApp->path_to( 'root', 'templates', 'src' ),
 133             ],
 134             PRE_PROCESS  => 'config/main',
 135             WRAPPER      => 'site/wrapper',
 136         });
 137         return $self->NEXT::new(@_);
 138     }
 139
 140 The final, and perhaps most direct way, is to define a class
 141 item in your main application configuration, again by calling the
 142 uniquitous C<config()> method.  The items in the class hash are
 143 added to those already defined by the above two methods.  This happens
 144 in the base class new() method (which is one reason why you must
 145 remember to call it via C<NEXT> if you redefine the C<new()> method in a
 146 subclass).
 147
 148     package MyApp;
 149
 150     use strict;
 151     use Catalyst;
 152
 153     MyApp->config({
 154         name     => 'MyApp',
 155         root     => MyApp->path_to('root'),
 156         'V::TT' => {
 157             INCLUDE_PATH => [
 158                 MyApp->path_to( 'root', 'templates', 'lib' ),
 159                 MyApp->path_to( 'root', 'templates', 'src' ),
 160             ],
 161             PRE_PROCESS  => 'config/main',
 162             WRAPPER      => 'site/wrapper',
 163         },
 164     });
 165
 166 Note that any configuration items defined by one of the earlier
 167 methods will be overwritten by items of the same name provided by the
 168 latter methods.
 169
 170 =head2 DYNAMIC INCLUDE_PATH
 171
 172 It is sometimes needed to dynamically add additional paths to the
 173 INCLUDE_PATH variable of the template object. This can be done by setting
 174 'additional_include_paths' on stash to a referrence to an array with
 175 additional paths:
 176
 177     $c->stash->{additional_template_paths} = [$c->config->{root} . '/test_include_path'];
 178
 179 =head2 RENDERING VIEWS
 180
 181 The view plugin renders the template specified in the C<template>
 182 item in the stash.
 183
 184     sub message : Global {
 185         my ( $self, $c ) = @_;
 186         $c->stash->{template} = 'message.tt2';
 187         $c->forward('MyApp::V::TT');
 188     }
 189
 190 If a class item isn't defined, then it instead uses the
 191 current match, as returned by C<$c-E<gt>match>.  In the above
 192 example, this would be C<message>.
 193
 194 The items defined in the stash are passed to the Template Toolkit for
 195 use as template variables.
 196
 197 sub message : Global {
 198     sub default : Private {
 199         my ( $self, $c ) = @_;
 200         $c->stash->{template} = 'message.tt2';
 201         $c->stash->{message}  = 'Hello World!';
 202         $c->forward('MyApp::V::TT');
 203     }
 204
 205 A number of other template variables are also added:
 206
 207     c      A reference to the context object, $c
 208     base   The URL base, from $c->req->base()
 209     name   The application name, from $c->config->{ name }
 210
 211 These can be accessed from the template in the usual way:
 212
 213 <message.tt2>:
 214
 215     The message is: [% message %]
 216     The base is [% base %]
 217     The name is [% name %]
 218
 219
 220 The output generated by the template is stored in
 221 C<$c-E<gt>response-E<gt>output>.
 222
 223 =head2 TEMPLATE PROFILING
 224
 225 =head2 METHODS
 226
 227 =over 4
 228
 229 =item new
 230
 231 The constructor for the TT view. Sets up the template provider,
 232 and reads the application config.
 233
 234 =cut
 235
 236 sub _coerce_paths {
 237     my ( $paths, $dlim ) = shift;
 238     return () if ( ! $paths );
 239     return @{$paths} if ( ref $paths eq 'ARRAY');
 240     if ( ! ref $paths ){
 241             # tweak delim to ignore C:/
 242             unless (defined $dlim) {
 243                 $dlim = ($^O eq 'MSWin32') ? ':(?!\\/)' : ':';
 244             }
 245             return split(/$dlim/, $paths);
 246     }
 247 }
 248
 249
 250 sub new {
 251     my ( $class, $c, $arguments ) = @_;
 252     my $delim = $class->config->{DELIMITER} || $arguments->{DELIMITER};
 253     my @include_path = _coerce_paths($arguments->{INCLUDE_PATH}, $delim);
 254     if(!@include_path){
 255         @include_path = _coerce_paths($class->config->{INCLUDE_PATH}, $delim);
 256     }
 257     if(!@include_path){
 258         my $root = $c->config->{root};
 259         my $base = Path::Class::dir($root, 'base');
 260         @include_path = ( "$root", "$base" );
 261     }
 262     my $config = {
 263         EVAL_PERL          => 0,
 264         TEMPLATE_EXTENSION => '',
 265         %{ $class->config },
 266         %{$arguments},
 267         INCLUDE_PATH => \@include_path,
 268     };
 269
 270     # if we're debugging and/or the TIMER option is set, then we install
 271     # Template::Timer as a custom CONTEXT object, but only if we haven't
 272     # already got a custom CONTEXT defined
 273
 274     if ( $config->{TIMER} ) {
 275         if ( $config->{CONTEXT} ) {
 276             $c->log->error(
 277                 'Cannot use Template::Timer - a TT CONFIG is already defined');
 278         }
 279         else {
 280             $config->{CONTEXT} = Template::Timer->new(%$config);
 281         }
 282     }
 283
 284     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 285         use Data::Dumper;
 286         $c->log->debug( "TT Config: ", Dumper($config) );
 287     }
 288
 289     my $self = $class->NEXT::new(
 290         $c,
 291         {
 292             template => Template->new($config) || do {
 293                 my $error = Template->error();
 294                 $c->log->error($error);
 295                 $c->error($error);
 296                 return undef;
 297               },
 298         %{$config},
 299         },
 300     );
 301     $self->include_path(\@include_path);
 302     $self->config($config);
 303
 304     return $self;
 305 }
 306
 307 =item process
 308
 309 Renders the template specified in C<$c-E<gt>stash-E<gt>{template}> or
 310 C<$c-E<gt>request-E<gt>match>. Template variables are set up from the
 311 contents of C<$c-E<gt>stash>, augmented with C<base> set to
 312 C<$c-E<gt>req-E<gt>base>, C<c> to C<$c> and C<name> to
 313 C<$c-E<gt>config-E<gt>{name}>. Alternately, the C<CATALYST_VAR>
 314 configuration item can be defined to specify the name of a template
 315 variable through which the context reference (C<$c>) can be accessed.
 316 In this case, the C<c>, C<base> and C<name> variables are omitted.
 317 Output is stored in C<$c-E<gt>response-E<gt>output>.
 318
 319 =cut
 320
 321 sub process {
 322     my ( $self, $c ) = @_;
 323
 324     my $template = $c->stash->{template}
 325       || ( $c->request->match || $c->request->action ) .
 326            $self->config->{TEMPLATE_EXTENSION};
 327
 328     unless ($template) {
 329         $c->log->debug('No template specified for rendering') if $c->debug;
 330         return 0;
 331     }
 332
 333     $c->log->debug(qq/Rendering template "$template"/) if $c->debug;
 334
 335     my $output;
 336     my $cvar = $self->config->{CATALYST_VAR};
 337     my $vars = {
 338         defined $cvar
 339         ? ( $cvar => $c )
 340         : (
 341             c    => $c,
 342             base => $c->req->base,
 343             name => $c->config->{name}
 344         ),
 345         %{ $c->stash() }
 346     };
 347
 348     my @tmp_path = @{$self->include_path};
 349     unshift @{$self->include_path}, @{$c->stash->{additional_template_paths}} if ref $c->stash->{additional_template_paths};
 350     unless ( $self->template->process( $template, $vars, \$output ) ) {
 351         my $error = $self->template->error;
 352         $error = qq/Couldn't render template "$error"/;
 353         $c->log->error($error);
 354         $c->error($error);
 355         return 0;
 356     }
 357     @{$self->include_path} = @tmp_path if ref $c->stash->{additional_template_paths};
 358
 359     unless ( $c->response->content_type ) {
 360         $c->response->content_type('text/html; charset=utf-8');
 361     }
 362
 363     $c->response->body($output);
 364
 365     return 1;
 366 }
 367
 368 =item config
 369
 370 This method allows your view subclass to pass additional settings to
 371 the TT configuration hash, or to set the options as below:
 372
 373 =over 2
 374
 375 =item C<CATALYST_VAR>
 376
 377 Allows you to change the name of the Catalyst context object. If set, it will also
 378 remove the base and name aliases, so you will have access them through <context>.
 379
 380 For example:
 381
 382     MyApp->config({
 383         name     => 'MyApp',
 384         root     => MyApp->path_to('root'),
 385         'V::TT' => {
 386             CATALYST_VAR => 'Catalyst',
 387         },
 388     });
 389
 390 F<message.tt2>:
 391
 392     The base is [% Catalyst.req.base %]
 393     The name is [% Catalyst.config.name %]
 394
 395 =item C<TIMER>
 396
 397 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 398 C<Catalyst::View::TT> will enable profiling of template processing
 399 (using L<Template::Timer>). This will embed HTML comments in the
 400 output from your templates, such as:
 401
 402     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 403     <!-- TIMER START: include mainmenu/cssindex.tt -->
 404     <!-- TIMER START: process mainmenu/cssindex.tt -->
 405     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 406     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 407
 408     ....
 409
 410     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 411
 412
 413 =item C<TEMPLATE_EXTENSION>
 414
 415 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 416
 417 For example:
 418
 419   package MyApp::C::Test;
 420   sub test : Local { .. }
 421
 422 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 423 <root>/test/test.tt.
 424
 425 =back
 426
 427 =back
 428
 429 =head2 HELPERS
 430
 431 The L<Catalyst::Helper::View::TT> and
 432 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 433 your view module.  There are invoked by the F<myapp_create.pl> script:
 434
 435     $ script/myapp_create.pl view TT TT
 436
 437     $ script/myapp_create.pl view TT TTSite
 438
 439 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 440 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 441 further.  It also creates a default set of templates to get you
 442 started.  It also configures the view module to locate the templates
 443 automatically.
 444
 445 =head1 SEE ALSO
 446
 447 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 448 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 449
 450 =head1 AUTHORS
 451
 452 Sebastian Riedel, C<sri@cpan.org>
 453
 454 Marcus Ramberg, C<mramberg@cpan.org>
 455
 456 Jesse Sheidlower, C<jester@panix.com>
 457
 458 Andy Wardley, C<abw@cpan.org>
 459
 460 =head1 COPYRIGHT
 461
 462 This program is free software, you can redistribute it and/or modify it
 463 under the same terms as Perl itself.
 464
 465 =cut
 466
 467 1;