lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11
  12 our $VERSION = '0.31';
  13
  14 __PACKAGE__->mk_accessors('template');
  15 __PACKAGE__->mk_accessors('include_path');
  16
  17 *paths = \&include_path;
  18
  19 =head1 NAME
  20
  21 Catalyst::View::TT - Template View Class
  22
  23 =head1 SYNOPSIS
  24
  25 # use the helper to create your View
  26
  27     myapp_create.pl view TT TT
  28
  29 # configure in lib/MyApp.pm (Could be set from configfile instead)
  30
  31     MyApp->config(
  32         name     => 'MyApp',
  33         root     => MyApp->path_to('root'),
  34         'View::TT' => {
  35             # any TT configurations items go here
  36             INCLUDE_PATH => [
  37               MyApp->path_to( 'root', 'src' ),
  38               MyApp->path_to( 'root', 'lib' ),
  39             ],
  40             TEMPLATE_EXTENSION => '.tt',
  41             CATALYST_VAR => 'c',
  42             TIMER        => 0,
  43             # Not set by default
  44             PRE_PROCESS        => 'config/main',
  45             WRAPPER            => 'site/wrapper',
  46         },
  47     );
  48
  49 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  50
  51     sub message : Global {
  52         my ( $self, $c ) = @_;
  53         $c->stash->{template} = 'message.tt2';
  54         $c->stash->{message}  = 'Hello World!';
  55         $c->forward( $c->view('TT') );
  56     }
  57
  58 # access variables from template
  59
  60     The message is: [% message %].
  61
  62     # example when CATALYST_VAR is set to 'Catalyst'
  63     Context is [% Catalyst %]
  64     The base is [% Catalyst.req.base %]
  65     The name is [% Catalyst.config.name %]
  66
  67     # example when CATALYST_VAR isn't set
  68     Context is [% c %]
  69     The base is [% base %]
  70     The name is [% name %]
  71
  72 =cut
  73
  74 sub _coerce_paths {
  75     my ( $paths, $dlim ) = shift;
  76     return () if ( !$paths );
  77     return @{$paths} if ( ref $paths eq 'ARRAY' );
  78
  79     # tweak delim to ignore C:/
  80     unless ( defined $dlim ) {
  81         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  82     }
  83     return split( /$dlim/, $paths );
  84 }
  85
  86 sub new {
  87     my ( $class, $c, $arguments ) = @_;
  88     my $config = {
  89         EVAL_PERL          => 0,
  90         TEMPLATE_EXTENSION => '',
  91         %{ $class->config },
  92         %{$arguments},
  93     };
  94     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  95         my $delim = $config->{DELIMITER};
  96         my @include_path
  97             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  98         if ( !@include_path ) {
  99             my $root = $c->config->{root};
 100             my $base = Path::Class::dir( $root, 'base' );
 101             @include_path = ( "$root", "$base" );
 102         }
 103         $config->{INCLUDE_PATH} = \@include_path;
 104     }
 105
 106     # if we're debugging and/or the TIMER option is set, then we install
 107     # Template::Timer as a custom CONTEXT object, but only if we haven't
 108     # already got a custom CONTEXT defined
 109
 110     if ( $config->{TIMER} ) {
 111         if ( $config->{CONTEXT} ) {
 112             $c->log->error(
 113                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 114             );
 115         }
 116         else {
 117             $config->{CONTEXT} = Template::Timer->new(%$config);
 118         }
 119     }
 120
 121     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 122         $c->log->debug( "TT Config: ", dump($config) );
 123     }
 124
 125     my $self = $class->next::method(
 126         $c, { %$config },
 127     );
 128
 129     # Set base include paths. Local'd in render if needed
 130     $self->include_path($config->{INCLUDE_PATH});
 131
 132     $self->config($config);
 133
 134     # Creation of template outside of call to new so that we can pass [ $self ]
 135     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 136     # of include paths to search for templates.
 137
 138     # Use a weakend copy of self so we dont have loops preventing GC from working
 139     my $copy = $self;
 140     Scalar::Util::weaken($copy);
 141     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 142
 143     if ( $config->{PROVIDERS} ) {
 144         my @providers = ();
 145         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 146             foreach my $p (@{$config->{PROVIDERS}}) {
 147                 my $pname = $p->{name};
 148                 my $prov = 'Template::Provider';
 149                 if($pname eq '_file_')
 150                 {
 151                     $p->{args} = { %$config };
 152                 }
 153                 else
 154                 {
 155                     if($pname =~ s/^\+//) {
 156                         $prov = $pname;
 157                     }
 158                     else
 159                     {
 160                         $prov .= "::$pname";
 161                     }
 162                     # We copy the args people want from the config
 163                     # to the args
 164                     $p->{args} ||= {};
 165                     if ($p->{copy_config}) {
 166                         map  { $p->{args}->{$_} = $config->{$_}  }
 167                                    grep { exists $config->{$_} }
 168                                    @{ $p->{copy_config} };
 169                     }
 170                 }
 171                 eval "require $prov";
 172                 if(!$@) {
 173                     push @providers, "$prov"->new($p->{args});
 174                 }
 175                 else
 176                 {
 177                     $c->log->warn("Can't load $prov, ($@)");
 178                 }
 179             }
 180         }
 181         delete $config->{PROVIDERS};
 182         if(@providers) {
 183             $config->{LOAD_TEMPLATES} = \@providers;
 184         }
 185     }
 186
 187     $self->{template} =
 188         Template->new($config) || do {
 189             my $error = Template->error();
 190             $c->log->error($error);
 191             $c->error($error);
 192             return undef;
 193         };
 194
 195
 196     return $self;
 197 }
 198
 199 sub process {
 200     my ( $self, $c ) = @_;
 201
 202     my $template = $c->stash->{template}
 203       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 204
 205     unless (defined $template) {
 206         $c->log->debug('No template specified for rendering') if $c->debug;
 207         return 0;
 208     }
 209
 210     my $output = $self->render($c, $template);
 211
 212     if (UNIVERSAL::isa($output, 'Template::Exception')) {
 213         my $error = qq/Couldn't render template "$output"/;
 214         $c->log->error($error);
 215         $c->error($error);
 216         return 0;
 217     }
 218
 219     unless ( $c->response->content_type ) {
 220         $c->response->content_type('text/html; charset=utf-8');
 221     }
 222
 223     $c->response->body($output);
 224
 225     return 1;
 226 }
 227
 228 sub render {
 229     my ($self, $c, $template, $args) = @_;
 230
 231     $c->log->debug(qq/Rendering template "$template"/) if $c && $c->debug;
 232
 233     my $output;
 234     my $vars = {
 235         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 236         $self->template_vars($c)
 237     };
 238
 239     local $self->{include_path} =
 240         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 241         if ref $vars->{additional_template_paths};
 242
 243     unless ($self->template->process( $template, $vars, \$output ) ) {
 244         return $self->template->error;
 245     } else {
 246         return $output;
 247     }
 248 }
 249
 250 sub template_vars {
 251     my ( $self, $c ) = @_;
 252
 253     return  () unless $c;
 254     my $cvar = $self->config->{CATALYST_VAR};
 255
 256     defined $cvar
 257       ? ( $cvar => $c )
 258       : (
 259         c    => $c,
 260         base => $c->req->base,
 261         name => $c->config->{name}
 262       )
 263 }
 264
 265
 266 1;
 267
 268 __END__
 269
 270 =head1 DESCRIPTION
 271
 272 This is the Catalyst view class for the L<Template Toolkit|Template>.
 273 Your application should defined a view class which is a subclass of
 274 this module.  The easiest way to achieve this is using the
 275 F<myapp_create.pl> script (where F<myapp> should be replaced with
 276 whatever your application is called).  This script is created as part
 277 of the Catalyst setup.
 278
 279     $ script/myapp_create.pl view TT TT
 280
 281 This creates a MyApp::View::TT.pm module in the F<lib> directory (again,
 282 replacing C<MyApp> with the name of your application) which looks
 283 something like this:
 284
 285     package FooBar::View::TT;
 286
 287     use strict;
 288     use warnings;
 289
 290     use base 'Catalyst::View::TT';
 291
 292     __PACKAGE__->config(DEBUG => 'all');
 293
 294 Now you can modify your action handlers in the main application and/or
 295 controllers to forward to your view class.  You might choose to do this
 296 in the end() method, for example, to automatically forward all actions
 297 to the TT view class.
 298
 299     # In MyApp or MyApp::Controller::SomeController
 300
 301     sub end : Private {
 302         my( $self, $c ) = @_;
 303         $c->forward( $c->view('TT') );
 304     }
 305
 306 But if you are using the standard auto-generated end action, you don't even need
 307 to do this!
 308
 309     # in MyApp::Controller::Root
 310     sub end : ActionClass('RenderView') {} # no need to change this line
 311
 312     # in MyApp.pm
 313     __PACKAGE__->config(
 314         ...
 315         default_view => 'TT',
 316     );
 317
 318 This will Just Work.  And it has the advantages that:
 319
 320 =over 4
 321
 322 =item *
 323
 324 If you want to use a different view for a given request, just set
 325 << $c->stash->{current_view} >>.  (See L<Catalyst>'s C<< $c->view >> method
 326 for details.
 327
 328 =item *
 329
 330 << $c->res->redirect >> is handled by default.  If you just forward to
 331 C<View::TT> in your C<end> routine, you could break this by sending additional
 332 content.
 333
 334 =back
 335
 336 See L<Catalyst::Action::RenderView> for more details.
 337
 338 =head2 CONFIGURATION
 339
 340 There are a three different ways to configure your view class.  The
 341 first way is to call the C<config()> method in the view subclass.  This
 342 happens when the module is first loaded.
 343
 344     package MyApp::View::TT;
 345
 346     use strict;
 347     use base 'Catalyst::View::TT';
 348
 349     MyApp::View::TT->config({
 350         INCLUDE_PATH => [
 351             MyApp->path_to( 'root', 'templates', 'lib' ),
 352             MyApp->path_to( 'root', 'templates', 'src' ),
 353         ],
 354         PRE_PROCESS  => 'config/main',
 355         WRAPPER      => 'site/wrapper',
 356     });
 357
 358 The second way is to define a C<new()> method in your view subclass.
 359 This performs the configuration when the view object is created,
 360 shortly after being loaded.  Remember to delegate to the base class
 361 C<new()> method (via C<$self-E<gt>next::method()> in the example below) after
 362 performing any configuration.
 363
 364     sub new {
 365         my $self = shift;
 366         $self->config({
 367             INCLUDE_PATH => [
 368                 MyApp->path_to( 'root', 'templates', 'lib' ),
 369                 MyApp->path_to( 'root', 'templates', 'src' ),
 370             ],
 371             PRE_PROCESS  => 'config/main',
 372             WRAPPER      => 'site/wrapper',
 373         });
 374         return $self->next::method(@_);
 375     }
 376
 377 The final, and perhaps most direct way, is to define a class
 378 item in your main application configuration, again by calling the
 379 ubiquitous C<config()> method.  The items in the class hash are
 380 added to those already defined by the above two methods.  This happens
 381 in the base class new() method (which is one reason why you must
 382 remember to call it via C<MRO::Compat> if you redefine the C<new()>
 383 method in a subclass).
 384
 385     package MyApp;
 386
 387     use strict;
 388     use Catalyst;
 389
 390     MyApp->config({
 391         name     => 'MyApp',
 392         root     => MyApp->path_to('root'),
 393         'View::TT' => {
 394             INCLUDE_PATH => [
 395                 MyApp->path_to( 'root', 'templates', 'lib' ),
 396                 MyApp->path_to( 'root', 'templates', 'src' ),
 397             ],
 398             PRE_PROCESS  => 'config/main',
 399             WRAPPER      => 'site/wrapper',
 400         },
 401     });
 402
 403 Note that any configuration items defined by one of the earlier
 404 methods will be overwritten by items of the same name provided by the
 405 latter methods.
 406
 407 =head2 DYNAMIC INCLUDE_PATH
 408
 409 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 410
 411 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 412 follows:
 413
 414     $c->stash->{additional_template_paths} =
 415         [$c->config->{root} . '/test_include_path'];
 416
 417 If you need to add paths to the end of INCLUDE_PATH, there is also an
 418 include_path() accessor available:
 419
 420     push( @{ $c->view('TT')->include_path }, qw/path/ );
 421
 422 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 423 MUST check for duplicate paths. Without such checking, the above code will add
 424 "path" to INCLUDE_PATH at every request, causing a memory leak.
 425
 426 A safer approach is to use include_path() to overwrite the array of paths
 427 rather than adding to it. This eliminates both the need to perform duplicate
 428 checking and the chance of a memory leak:
 429
 430     @{ $c->view('TT')->include_path } = qw/path another_path/;
 431
 432 If you are calling C<render> directly then you can specify dynamic paths by
 433 having a C<additional_template_paths> key with a value of additonal directories
 434 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 435
 436 =head2 RENDERING VIEWS
 437
 438 The view plugin renders the template specified in the C<template>
 439 item in the stash.
 440
 441     sub message : Global {
 442         my ( $self, $c ) = @_;
 443         $c->stash->{template} = 'message.tt2';
 444         $c->forward( $c->view('TT') );
 445     }
 446
 447 If a stash item isn't defined, then it instead uses the
 448 stringification of the action dispatched to (as defined by $c->action)
 449 in the above example, this would be C<message>, but because the default
 450 is to append '.tt', it would load C<root/message.tt>.
 451
 452 The items defined in the stash are passed to the Template Toolkit for
 453 use as template variables.
 454
 455     sub default : Private {
 456         my ( $self, $c ) = @_;
 457         $c->stash->{template} = 'message.tt2';
 458         $c->stash->{message}  = 'Hello World!';
 459         $c->forward( $c->view('TT') );
 460     }
 461
 462 A number of other template variables are also added:
 463
 464     c      A reference to the context object, $c
 465     base   The URL base, from $c->req->base()
 466     name   The application name, from $c->config->{ name }
 467
 468 These can be accessed from the template in the usual way:
 469
 470 <message.tt2>:
 471
 472     The message is: [% message %]
 473     The base is [% base %]
 474     The name is [% name %]
 475
 476
 477 The output generated by the template is stored in C<< $c->response->body >>.
 478
 479 =head2 CAPTURING TEMPLATE OUTPUT
 480
 481 If you wish to use the output of a template for some other purpose than
 482 displaying in the response, e.g. for sending an email, this is possible using
 483 L<Catalyst::Plugin::Email> and the L<render> method:
 484
 485   sub send_email : Local {
 486     my ($self, $c) = @_;
 487
 488     $c->email(
 489       header => [
 490         To      => 'me@localhost',
 491         Subject => 'A TT Email',
 492       ],
 493       body => $c->view('TT')->render($c, 'email.tt', {
 494         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 495         email_tmpl_param1 => 'foo'
 496         }
 497       ),
 498     );
 499   # Redirect or display a message
 500   }
 501
 502 =head2 TEMPLATE PROFILING
 503
 504 See L<C<TIMER>> property of the L<config> method.
 505
 506 =head2 METHODS
 507
 508 =head2 new
 509
 510 The constructor for the TT view. Sets up the template provider,
 511 and reads the application config.
 512
 513 =head2 process($c)
 514
 515 Renders the template specified in C<< $c->stash->{template} >> or
 516 C<< $c->action >> (the private name of the matched action).  Calls L<render> to
 517 perform actual rendering. Output is stored in C<< $c->response->body >>.
 518
 519 It is possible to forward to the process method of a TT view from inside
 520 Catalyst like this:
 521
 522     $c->forward('View::TT');
 523
 524 N.B. This is usually done automatically by L<Catalyst::Action::RenderView>.
 525
 526 =head2 render($c, $template, \%args)
 527
 528 Renders the given template and returns output, or a L<Template::Exception>
 529 object upon error.
 530
 531 The template variables are set to C<%$args> if $args is a hashref, or
 532 $C<< $c->stash >> otherwise. In either case the variables are augmented with
 533 C<base> set to C< << $c->req->base >>, C<c> to C<$c> and C<name> to
 534 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 535 can be defined to specify the name of a template variable through which the
 536 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base> and
 537 C<name> variables are omitted.
 538
 539 C<$template> can be anything that Template::process understands how to
 540 process, including the name of a template file or a reference to a test string.
 541 See L<Template::process|Template/process> for a full list of supported formats.
 542
 543 To use the render method outside of your Catalyst app, just pass a undef context.
 544 This can be useful for tests, for instance.
 545
 546 It is possible to forward to the render method of a TT view from inside Catalyst
 547 to render page fragments like this:
 548
 549     my $fragment = $c->forward("View::TT", "render", $template_name, $c->stash->{fragment_data});
 550
 551 =head2 template_vars
 552
 553 Returns a list of keys/values to be used as the catalyst variables in the
 554 template.
 555
 556 =head2 config
 557
 558 This method allows your view subclass to pass additional settings to
 559 the TT configuration hash, or to set the options as below:
 560
 561 =head2 paths
 562
 563 The list of paths TT will look for templates in.
 564
 565 =head2 C<CATALYST_VAR>
 566
 567 Allows you to change the name of the Catalyst context object. If set, it will also
 568 remove the base and name aliases, so you will have access them through <context>.
 569
 570 For example:
 571
 572     MyApp->config({
 573         name     => 'MyApp',
 574         root     => MyApp->path_to('root'),
 575         'View::TT' => {
 576             CATALYST_VAR => 'Catalyst',
 577         },
 578     });
 579
 580 F<message.tt2>:
 581
 582     The base is [% Catalyst.req.base %]
 583     The name is [% Catalyst.config.name %]
 584
 585 =head2 C<TIMER>
 586
 587 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 588 C<Catalyst::View::TT> will enable profiling of template processing
 589 (using L<Template::Timer>). This will embed HTML comments in the
 590 output from your templates, such as:
 591
 592     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 593     <!-- TIMER START: include mainmenu/cssindex.tt -->
 594     <!-- TIMER START: process mainmenu/cssindex.tt -->
 595     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 596     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 597
 598     ....
 599
 600     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 601
 602
 603 =head2 C<TEMPLATE_EXTENSION>
 604
 605 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 606
 607 For example:
 608
 609   package MyApp::Controller::Test;
 610   sub test : Local { .. }
 611
 612 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 613 <root>/test/test.tt.
 614
 615 =head2 C<PROVIDERS>
 616
 617 Allows you to specify the template providers that TT will use.
 618
 619     MyApp->config({
 620         name     => 'MyApp',
 621         root     => MyApp->path_to('root'),
 622         'View::TT' => {
 623             PROVIDERS => [
 624                 {
 625                     name    => 'DBI',
 626                     args    => {
 627                         DBI_DSN => 'dbi:DB2:books',
 628                         DBI_USER=> 'foo'
 629                     }
 630                 }, {
 631                     name    => '_file_',
 632                     args    => {}
 633                 }
 634             ]
 635         },
 636     });
 637
 638 The 'name' key should correspond to the class name of the provider you
 639 want to use.  The _file_ name is a special case that represents the default
 640 TT file-based provider.  By default the name is will be prefixed with
 641 'Template::Provider::'.  You can fully qualify the name by using a unary
 642 plus:
 643
 644     name => '+MyApp::Provider::Foo'
 645
 646 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 647 from the general config, into the config for the provider:
 648
 649     DEFAULT_ENCODING    => 'utf-8',
 650     PROVIDERS => [
 651         {
 652             name    => 'Encoding',
 653             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 654         }
 655     ]
 656
 657 This can prove useful when you want to use the additional_template_paths hack
 658 in your own provider, or if you need to use Template::Provider::Encoding
 659
 660 =head2 HELPERS
 661
 662 The L<Catalyst::Helper::View::TT> and
 663 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 664 your view module.  There are invoked by the F<myapp_create.pl> script:
 665
 666     $ script/myapp_create.pl view TT TT
 667
 668     $ script/myapp_create.pl view TT TTSite
 669
 670 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 671 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 672 further.  It also creates a default set of templates to get you
 673 started.  It also configures the view module to locate the templates
 674 automatically.
 675
 676 =head1 NOTES
 677
 678 If you are using the L<CGI> module inside your templates, you will
 679 experience that the Catalyst server appears to hang while rendering
 680 the web page. This is due to the debug mode of L<CGI> (which is
 681 waiting for input in the terminal window). Turning off the
 682 debug mode using the "-no_debug" option solves the
 683 problem, eg.:
 684
 685     [% USE CGI('-no_debug') %]
 686
 687 =head1 SEE ALSO
 688
 689 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 690 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 691
 692 =head1 AUTHORS
 693
 694 Sebastian Riedel, C<sri@cpan.org>
 695
 696 Marcus Ramberg, C<mramberg@cpan.org>
 697
 698 Jesse Sheidlower, C<jester@panix.com>
 699
 700 Andy Wardley, C<abw@cpan.org>
 701
 702 =head1 COPYRIGHT
 703
 704 This program is free software. You can redistribute it and/or modify it
 705 under the same terms as Perl itself.
 706
 707 =cut