lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11
  12 our $VERSION = '0.33';
  13
  14 __PACKAGE__->mk_accessors('template');
  15 __PACKAGE__->mk_accessors('include_path');
  16
  17 *paths = \&include_path;
  18
  19 =head1 NAME
  20
  21 Catalyst::View::TT - Template View Class
  22
  23 =head1 SYNOPSIS
  24
  25 # use the helper to create your View
  26
  27     myapp_create.pl view TT TT
  28
  29 # configure in lib/MyApp.pm (Could be set from configfile instead)
  30
  31     __PACKAGE__->config(
  32         name         => 'MyApp',
  33         root         => MyApp->path_to('root'),
  34         default_view => 'TT',
  35         'View::TT' => {
  36             # any TT configurations items go here
  37             INCLUDE_PATH => [
  38               MyApp->path_to( 'root', 'src' ),
  39               MyApp->path_to( 'root', 'lib' ),
  40             ],
  41             TEMPLATE_EXTENSION => '.tt',
  42             CATALYST_VAR => 'c',
  43             TIMER        => 0,
  44             # Not set by default
  45             PRE_PROCESS        => 'config/main',
  46             WRAPPER            => 'site/wrapper',
  47             render_die => 1, # Default for new apps, see render method docs
  48         },
  49     );
  50
  51 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  52
  53     sub message : Global {
  54         my ( $self, $c ) = @_;
  55         $c->stash->{template} = 'message.tt2';
  56         $c->stash->{message}  = 'Hello World!';
  57         $c->forward( $c->view('TT') );
  58     }
  59
  60 # access variables from template
  61
  62     The message is: [% message %].
  63
  64     # example when CATALYST_VAR is set to 'Catalyst'
  65     Context is [% Catalyst %]
  66     The base is [% Catalyst.req.base %]
  67     The name is [% Catalyst.config.name %]
  68
  69     # example when CATALYST_VAR isn't set
  70     Context is [% c %]
  71     The base is [% base %]
  72     The name is [% name %]
  73
  74 =cut
  75
  76 sub _coerce_paths {
  77     my ( $paths, $dlim ) = shift;
  78     return () if ( !$paths );
  79     return @{$paths} if ( ref $paths eq 'ARRAY' );
  80
  81     # tweak delim to ignore C:/
  82     unless ( defined $dlim ) {
  83         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  84     }
  85     return split( /$dlim/, $paths );
  86 }
  87
  88 sub new {
  89     my ( $class, $c, $arguments ) = @_;
  90     my $config = {
  91         EVAL_PERL          => 0,
  92         TEMPLATE_EXTENSION => '',
  93         %{ $class->config },
  94         %{$arguments},
  95     };
  96     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  97         my $delim = $config->{DELIMITER};
  98         my @include_path
  99             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
 100         if ( !@include_path ) {
 101             my $root = $c->config->{root};
 102             my $base = Path::Class::dir( $root, 'base' );
 103             @include_path = ( "$root", "$base" );
 104         }
 105         $config->{INCLUDE_PATH} = \@include_path;
 106     }
 107
 108     # if we're debugging and/or the TIMER option is set, then we install
 109     # Template::Timer as a custom CONTEXT object, but only if we haven't
 110     # already got a custom CONTEXT defined
 111
 112     if ( $config->{TIMER} ) {
 113         if ( $config->{CONTEXT} ) {
 114             $c->log->error(
 115                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 116             );
 117         }
 118         else {
 119             $config->{CONTEXT} = Template::Timer->new(%$config);
 120         }
 121     }
 122
 123     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 124         $c->log->debug( "TT Config: ", dump($config) );
 125     }
 126
 127     my $self = $class->next::method(
 128         $c, { %$config },
 129     );
 130
 131     # Set base include paths. Local'd in render if needed
 132     $self->include_path($config->{INCLUDE_PATH});
 133
 134     $self->config($config);
 135
 136     # Creation of template outside of call to new so that we can pass [ $self ]
 137     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 138     # of include paths to search for templates.
 139
 140     # Use a weakend copy of self so we dont have loops preventing GC from working
 141     my $copy = $self;
 142     Scalar::Util::weaken($copy);
 143     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 144
 145     if ( $config->{PROVIDERS} ) {
 146         my @providers = ();
 147         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 148             foreach my $p (@{$config->{PROVIDERS}}) {
 149                 my $pname = $p->{name};
 150                 my $prov = 'Template::Provider';
 151                 if($pname eq '_file_')
 152                 {
 153                     $p->{args} = { %$config };
 154                 }
 155                 else
 156                 {
 157                     if($pname =~ s/^\+//) {
 158                         $prov = $pname;
 159                     }
 160                     else
 161                     {
 162                         $prov .= "::$pname";
 163                     }
 164                     # We copy the args people want from the config
 165                     # to the args
 166                     $p->{args} ||= {};
 167                     if ($p->{copy_config}) {
 168                         map  { $p->{args}->{$_} = $config->{$_}  }
 169                                    grep { exists $config->{$_} }
 170                                    @{ $p->{copy_config} };
 171                     }
 172                 }
 173                 local $@;
 174                 eval "require $prov";
 175                 if(!$@) {
 176                     push @providers, "$prov"->new($p->{args});
 177                 }
 178                 else
 179                 {
 180                     $c->log->warn("Can't load $prov, ($@)");
 181                 }
 182             }
 183         }
 184         delete $config->{PROVIDERS};
 185         if(@providers) {
 186             $config->{LOAD_TEMPLATES} = \@providers;
 187         }
 188     }
 189
 190     $self->{template} =
 191         Template->new($config) || do {
 192             my $error = Template->error();
 193             $c->log->error($error);
 194             $c->error($error);
 195             return undef;
 196         };
 197
 198
 199     return $self;
 200 }
 201
 202 sub process {
 203     my ( $self, $c ) = @_;
 204
 205     my $template = $c->stash->{template}
 206       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 207
 208     unless (defined $template) {
 209         $c->log->debug('No template specified for rendering') if $c->debug;
 210         return 0;
 211     }
 212
 213     local $@;
 214     my $output = eval { $self->render($c, $template) };
 215     if (my $err = $@) {
 216         my $error = qq/Couldn't render template "$template"/;
 217         $c->log->error($error);
 218         $c->error($error);
 219         return 0;
 220     }
 221
 222     unless ( $c->response->content_type ) {
 223         $c->response->content_type('text/html; charset=utf-8');
 224     }
 225
 226     $c->response->body($output);
 227
 228     return 1;
 229 }
 230
 231 sub render {
 232     my ($self, $c, $template, $args) = @_;
 233
 234     $c->log->debug(qq/Rendering template "$template"/) if $c && $c->debug;
 235
 236     my $output;
 237     my $vars = {
 238         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 239         $self->template_vars($c)
 240     };
 241
 242     local $self->{include_path} =
 243         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 244         if ref $vars->{additional_template_paths};
 245
 246     unless ( $self->template->process( $template, $vars, \$output ) ) {
 247         if (exists $self->{render_die}) {
 248             die $self->template->error if $self->{render_die};
 249             return $self->template->error;
 250         }
 251         require Carp;
 252         Carp::carp('The Catalyst::View::TT render() method of will die on error in a future release. If you want it to continue to return the exception instead, pass render_die => 0 to the constructor');
 253         return $self->template->error;
 254     }
 255     return $output;
 256 }
 257
 258 sub template_vars {
 259     my ( $self, $c ) = @_;
 260
 261     return  () unless $c;
 262     my $cvar = $self->config->{CATALYST_VAR};
 263
 264     defined $cvar
 265       ? ( $cvar => $c )
 266       : (
 267         c    => $c,
 268         base => $c->req->base,
 269         name => $c->config->{name}
 270       )
 271 }
 272
 273
 274 1;
 275
 276 __END__
 277
 278 =head1 DESCRIPTION
 279
 280 This is the Catalyst view class for the L<Template Toolkit|Template>.
 281 Your application should defined a view class which is a subclass of
 282 this module.  The easiest way to achieve this is using the
 283 F<myapp_create.pl> script (where F<myapp> should be replaced with
 284 whatever your application is called).  This script is created as part
 285 of the Catalyst setup.
 286
 287     $ script/myapp_create.pl view TT TT
 288
 289 This creates a MyApp::View::TT.pm module in the F<lib> directory (again,
 290 replacing C<MyApp> with the name of your application) which looks
 291 something like this:
 292
 293     package FooBar::View::TT;
 294
 295     use strict;
 296     use warnings;
 297
 298     use base 'Catalyst::View::TT';
 299
 300     __PACKAGE__->config(DEBUG => 'all');
 301
 302 Now you can modify your action handlers in the main application and/or
 303 controllers to forward to your view class.  You might choose to do this
 304 in the end() method, for example, to automatically forward all actions
 305 to the TT view class.
 306
 307     # In MyApp or MyApp::Controller::SomeController
 308
 309     sub end : Private {
 310         my( $self, $c ) = @_;
 311         $c->forward( $c->view('TT') );
 312     }
 313
 314 But if you are using the standard auto-generated end action, you don't even need
 315 to do this!
 316
 317     # in MyApp::Controller::Root
 318     sub end : ActionClass('RenderView') {} # no need to change this line
 319
 320     # in MyApp.pm
 321     __PACKAGE__->config(
 322         ...
 323         default_view => 'TT',
 324     );
 325
 326 This will Just Work.  And it has the advantages that:
 327
 328 =over 4
 329
 330 =item *
 331
 332 If you want to use a different view for a given request, just set
 333 << $c->stash->{current_view} >>.  (See L<Catalyst>'s C<< $c->view >> method
 334 for details.
 335
 336 =item *
 337
 338 << $c->res->redirect >> is handled by default.  If you just forward to
 339 C<View::TT> in your C<end> routine, you could break this by sending additional
 340 content.
 341
 342 =back
 343
 344 See L<Catalyst::Action::RenderView> for more details.
 345
 346 =head2 CONFIGURATION
 347
 348 There are a three different ways to configure your view class.  The
 349 first way is to call the C<config()> method in the view subclass.  This
 350 happens when the module is first loaded.
 351
 352     package MyApp::View::TT;
 353
 354     use strict;
 355     use base 'Catalyst::View::TT';
 356
 357     MyApp::View::TT->config({
 358         INCLUDE_PATH => [
 359             MyApp->path_to( 'root', 'templates', 'lib' ),
 360             MyApp->path_to( 'root', 'templates', 'src' ),
 361         ],
 362         PRE_PROCESS  => 'config/main',
 363         WRAPPER      => 'site/wrapper',
 364     });
 365
 366 The second way is to define a C<new()> method in your view subclass.
 367 This performs the configuration when the view object is created,
 368 shortly after being loaded.  Remember to delegate to the base class
 369 C<new()> method (via C<$self-E<gt>next::method()> in the example below) after
 370 performing any configuration.
 371
 372     sub new {
 373         my $self = shift;
 374         $self->config({
 375             INCLUDE_PATH => [
 376                 MyApp->path_to( 'root', 'templates', 'lib' ),
 377                 MyApp->path_to( 'root', 'templates', 'src' ),
 378             ],
 379             PRE_PROCESS  => 'config/main',
 380             WRAPPER      => 'site/wrapper',
 381         });
 382         return $self->next::method(@_);
 383     }
 384
 385 The final, and perhaps most direct way, is to define a class
 386 item in your main application configuration, again by calling the
 387 ubiquitous C<config()> method.  The items in the class hash are
 388 added to those already defined by the above two methods.  This happens
 389 in the base class new() method (which is one reason why you must
 390 remember to call it via C<MRO::Compat> if you redefine the C<new()>
 391 method in a subclass).
 392
 393     package MyApp;
 394
 395     use strict;
 396     use Catalyst;
 397
 398     MyApp->config({
 399         name     => 'MyApp',
 400         root     => MyApp->path_to('root'),
 401         'View::TT' => {
 402             INCLUDE_PATH => [
 403                 MyApp->path_to( 'root', 'templates', 'lib' ),
 404                 MyApp->path_to( 'root', 'templates', 'src' ),
 405             ],
 406             PRE_PROCESS  => 'config/main',
 407             WRAPPER      => 'site/wrapper',
 408         },
 409     });
 410
 411 Note that any configuration items defined by one of the earlier
 412 methods will be overwritten by items of the same name provided by the
 413 latter methods.
 414
 415 =head2 DYNAMIC INCLUDE_PATH
 416
 417 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 418
 419 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 420 follows:
 421
 422     $c->stash->{additional_template_paths} =
 423         [$c->config->{root} . '/test_include_path'];
 424
 425 If you need to add paths to the end of INCLUDE_PATH, there is also an
 426 include_path() accessor available:
 427
 428     push( @{ $c->view('TT')->include_path }, qw/path/ );
 429
 430 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 431 MUST check for duplicate paths. Without such checking, the above code will add
 432 "path" to INCLUDE_PATH at every request, causing a memory leak.
 433
 434 A safer approach is to use include_path() to overwrite the array of paths
 435 rather than adding to it. This eliminates both the need to perform duplicate
 436 checking and the chance of a memory leak:
 437
 438     @{ $c->view('TT')->include_path } = qw/path another_path/;
 439
 440 If you are calling C<render> directly then you can specify dynamic paths by
 441 having a C<additional_template_paths> key with a value of additonal directories
 442 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 443
 444 =head2 RENDERING VIEWS
 445
 446 The view plugin renders the template specified in the C<template>
 447 item in the stash.
 448
 449     sub message : Global {
 450         my ( $self, $c ) = @_;
 451         $c->stash->{template} = 'message.tt2';
 452         $c->forward( $c->view('TT') );
 453     }
 454
 455 If a stash item isn't defined, then it instead uses the
 456 stringification of the action dispatched to (as defined by $c->action)
 457 in the above example, this would be C<message>, but because the default
 458 is to append '.tt', it would load C<root/message.tt>.
 459
 460 The items defined in the stash are passed to the Template Toolkit for
 461 use as template variables.
 462
 463     sub default : Private {
 464         my ( $self, $c ) = @_;
 465         $c->stash->{template} = 'message.tt2';
 466         $c->stash->{message}  = 'Hello World!';
 467         $c->forward( $c->view('TT') );
 468     }
 469
 470 A number of other template variables are also added:
 471
 472     c      A reference to the context object, $c
 473     base   The URL base, from $c->req->base()
 474     name   The application name, from $c->config->{ name }
 475
 476 These can be accessed from the template in the usual way:
 477
 478 <message.tt2>:
 479
 480     The message is: [% message %]
 481     The base is [% base %]
 482     The name is [% name %]
 483
 484
 485 The output generated by the template is stored in C<< $c->response->body >>.
 486
 487 =head2 CAPTURING TEMPLATE OUTPUT
 488
 489 If you wish to use the output of a template for some other purpose than
 490 displaying in the response, e.g. for sending an email, this is possible using
 491 L<Catalyst::Plugin::Email> and the L<render> method:
 492
 493   sub send_email : Local {
 494     my ($self, $c) = @_;
 495
 496     $c->email(
 497       header => [
 498         To      => 'me@localhost',
 499         Subject => 'A TT Email',
 500       ],
 501       body => $c->view('TT')->render($c, 'email.tt', {
 502         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 503         email_tmpl_param1 => 'foo'
 504         }
 505       ),
 506     );
 507   # Redirect or display a message
 508   }
 509
 510 =head2 TEMPLATE PROFILING
 511
 512 See L<C<TIMER>> property of the L<config> method.
 513
 514 =head2 METHODS
 515
 516 =head2 new
 517
 518 The constructor for the TT view. Sets up the template provider,
 519 and reads the application config.
 520
 521 =head2 process($c)
 522
 523 Renders the template specified in C<< $c->stash->{template} >> or
 524 C<< $c->action >> (the private name of the matched action).  Calls L<render> to
 525 perform actual rendering. Output is stored in C<< $c->response->body >>.
 526
 527 It is possible to forward to the process method of a TT view from inside
 528 Catalyst like this:
 529
 530     $c->forward('View::TT');
 531
 532 N.B. This is usually done automatically by L<Catalyst::Action::RenderView>.
 533
 534 =head2 render($c, $template, \%args)
 535
 536 Renders the given template and returns output. Throws a L<Template::Exception>
 537 object upon error.
 538
 539 The template variables are set to C<%$args> if $args is a hashref, or
 540 $C<< $c->stash >> otherwise. In either case the variables are augmented with
 541 C<base> set to C< << $c->req->base >>, C<c> to C<$c> and C<name> to
 542 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 543 can be defined to specify the name of a template variable through which the
 544 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base> and
 545 C<name> variables are omitted.
 546
 547 C<$template> can be anything that Template::process understands how to
 548 process, including the name of a template file or a reference to a test string.
 549 See L<Template::process|Template/process> for a full list of supported formats.
 550
 551 To use the render method outside of your Catalyst app, just pass a undef context.
 552 This can be useful for tests, for instance.
 553
 554 It is possible to forward to the render method of a TT view from inside Catalyst
 555 to render page fragments like this:
 556
 557     my $fragment = $c->forward("View::TT", "render", $template_name, $c->stash->{fragment_data});
 558
 559 =head3 Backwards compatibility note
 560
 561 The render method used to just return the Template::Exception object, rather
 562 than just throwing it. This is now deprecated and instead the render method
 563 will throw an exception for new applications.
 564
 565 This behaviour can be activated (and is activated in the default skeleton
 566 configuration) by using C<< render_die => 1 >>. If you rely on the legacy
 567 behaviour then a warning will be issued.
 568
 569 To silence this warning, set C<< render_die => 0 >>, but it is recommended
 570 you adjust your code so that it works with C<< render_die => 1 >>.
 571
 572 In a future release, C<< render_die => 1 >> will become the default if
 573 unspecified.
 574
 575 =head2 template_vars
 576
 577 Returns a list of keys/values to be used as the catalyst variables in the
 578 template.
 579
 580 =head2 config
 581
 582 This method allows your view subclass to pass additional settings to
 583 the TT configuration hash, or to set the options as below:
 584
 585 =head2 paths
 586
 587 The list of paths TT will look for templates in.
 588
 589 =head2 C<CATALYST_VAR>
 590
 591 Allows you to change the name of the Catalyst context object. If set, it will also
 592 remove the base and name aliases, so you will have access them through <context>.
 593
 594 For example:
 595
 596     MyApp->config({
 597         name     => 'MyApp',
 598         root     => MyApp->path_to('root'),
 599         'View::TT' => {
 600             CATALYST_VAR => 'Catalyst',
 601         },
 602     });
 603
 604 F<message.tt2>:
 605
 606     The base is [% Catalyst.req.base %]
 607     The name is [% Catalyst.config.name %]
 608
 609 =head2 C<TIMER>
 610
 611 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 612 C<Catalyst::View::TT> will enable profiling of template processing
 613 (using L<Template::Timer>). This will embed HTML comments in the
 614 output from your templates, such as:
 615
 616     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 617     <!-- TIMER START: include mainmenu/cssindex.tt -->
 618     <!-- TIMER START: process mainmenu/cssindex.tt -->
 619     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 620     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 621
 622     ....
 623
 624     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 625
 626
 627 =head2 C<TEMPLATE_EXTENSION>
 628
 629 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 630
 631 For example:
 632
 633   package MyApp::Controller::Test;
 634   sub test : Local { .. }
 635
 636 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 637 <root>/test/test.tt.
 638
 639 =head2 C<PROVIDERS>
 640
 641 Allows you to specify the template providers that TT will use.
 642
 643     MyApp->config({
 644         name     => 'MyApp',
 645         root     => MyApp->path_to('root'),
 646         'View::TT' => {
 647             PROVIDERS => [
 648                 {
 649                     name    => 'DBI',
 650                     args    => {
 651                         DBI_DSN => 'dbi:DB2:books',
 652                         DBI_USER=> 'foo'
 653                     }
 654                 }, {
 655                     name    => '_file_',
 656                     args    => {}
 657                 }
 658             ]
 659         },
 660     });
 661
 662 The 'name' key should correspond to the class name of the provider you
 663 want to use.  The _file_ name is a special case that represents the default
 664 TT file-based provider.  By default the name is will be prefixed with
 665 'Template::Provider::'.  You can fully qualify the name by using a unary
 666 plus:
 667
 668     name => '+MyApp::Provider::Foo'
 669
 670 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 671 from the general config, into the config for the provider:
 672
 673     DEFAULT_ENCODING    => 'utf-8',
 674     PROVIDERS => [
 675         {
 676             name    => 'Encoding',
 677             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 678         }
 679     ]
 680
 681 This can prove useful when you want to use the additional_template_paths hack
 682 in your own provider, or if you need to use Template::Provider::Encoding
 683
 684 =head2 HELPERS
 685
 686 The L<Catalyst::Helper::View::TT> and
 687 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 688 your view module.  There are invoked by the F<myapp_create.pl> script:
 689
 690     $ script/myapp_create.pl view TT TT
 691
 692     $ script/myapp_create.pl view TT TTSite
 693
 694 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 695 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 696 further.  It also creates a default set of templates to get you
 697 started.  It also configures the view module to locate the templates
 698 automatically.
 699
 700 =head1 NOTES
 701
 702 If you are using the L<CGI> module inside your templates, you will
 703 experience that the Catalyst server appears to hang while rendering
 704 the web page. This is due to the debug mode of L<CGI> (which is
 705 waiting for input in the terminal window). Turning off the
 706 debug mode using the "-no_debug" option solves the
 707 problem, eg.:
 708
 709     [% USE CGI('-no_debug') %]
 710
 711 =head1 SEE ALSO
 712
 713 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 714 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 715
 716 =head1 AUTHORS
 717
 718 Sebastian Riedel, C<sri@cpan.org>
 719
 720 Marcus Ramberg, C<mramberg@cpan.org>
 721
 722 Jesse Sheidlower, C<jester@panix.com>
 723
 724 Andy Wardley, C<abw@cpan.org>
 725
 726 =head1 COPYRIGHT
 727
 728 This program is free software. You can redistribute it and/or modify it
 729 under the same terms as Perl itself.
 730
 731 =cut