lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11 use Scalar::Util qw/blessed weaken/;
  12
  13 our $VERSION = '0.35';
  14
  15 __PACKAGE__->mk_accessors('template');
  16 __PACKAGE__->mk_accessors('expose_methods');
  17 __PACKAGE__->mk_accessors('include_path');
  18
  19 *paths = \&include_path;
  20
  21 =head1 NAME
  22
  23 Catalyst::View::TT - Template View Class
  24
  25 =head1 SYNOPSIS
  26
  27 # use the helper to create your View
  28
  29     myapp_create.pl view Web TT
  30
  31 # add custom configration in View/Web.pm
  32
  33     __PACKAGE__->config(
  34         # any TT configuration items go here
  35         INCLUDE_PATH => [
  36           MyApp->path_to( 'root', 'src' ),
  37           MyApp->path_to( 'root', 'lib' ),
  38         ],
  39         TEMPLATE_EXTENSION => '.tt',
  40         CATALYST_VAR => 'c',
  41         TIMER        => 0,
  42         # Not set by default
  43         PRE_PROCESS        => 'config/main',
  44         WRAPPER            => 'site/wrapper',
  45         render_die => 1, # Default for new apps, see render method docs
  46         expose_methods => [qw/method_in_view_class/],
  47     );
  48
  49 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  50
  51     sub message : Global {
  52         my ( $self, $c ) = @_;
  53         $c->stash->{template} = 'message.tt2';
  54         $c->stash->{message}  = 'Hello World!';
  55         $c->forward( $c->view('Web') );
  56     }
  57
  58 # access variables from template
  59
  60     The message is: [% message %].
  61
  62     # example when CATALYST_VAR is set to 'Catalyst'
  63     Context is [% Catalyst %]
  64     The base is [% Catalyst.req.base %]
  65     The name is [% Catalyst.config.name %]
  66
  67     # example when CATALYST_VAR isn't set
  68     Context is [% c %]
  69     The base is [% base %]
  70     The name is [% name %]
  71
  72 =cut
  73
  74 sub _coerce_paths {
  75     my ( $paths, $dlim ) = shift;
  76     return () if ( !$paths );
  77     return @{$paths} if ( ref $paths eq 'ARRAY' );
  78
  79     # tweak delim to ignore C:/
  80     unless ( defined $dlim ) {
  81         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  82     }
  83     return split( /$dlim/, $paths );
  84 }
  85
  86 sub new {
  87     my ( $class, $c, $arguments ) = @_;
  88     my $config = {
  89         EVAL_PERL          => 0,
  90         TEMPLATE_EXTENSION => '',
  91         %{ $class->config },
  92         %{$arguments},
  93     };
  94     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  95         my $delim = $config->{DELIMITER};
  96         my @include_path
  97             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  98         if ( !@include_path ) {
  99             my $root = $c->config->{root};
 100             my $base = Path::Class::dir( $root, 'base' );
 101             @include_path = ( "$root", "$base" );
 102         }
 103         $config->{INCLUDE_PATH} = \@include_path;
 104     }
 105
 106     # if we're debugging and/or the TIMER option is set, then we install
 107     # Template::Timer as a custom CONTEXT object, but only if we haven't
 108     # already got a custom CONTEXT defined
 109
 110     if ( $config->{TIMER} ) {
 111         if ( $config->{CONTEXT} ) {
 112             $c->log->error(
 113                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 114             );
 115         }
 116         else {
 117             $config->{CONTEXT} = Template::Timer->new(%$config);
 118         }
 119     }
 120
 121     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 122         $c->log->debug( "TT Config: ", dump($config) );
 123     }
 124
 125     my $self = $class->next::method(
 126         $c, { %$config },
 127     );
 128
 129     # Set base include paths. Local'd in render if needed
 130     $self->include_path($config->{INCLUDE_PATH});
 131
 132     $self->expose_methods($config->{expose_methods});
 133     $self->config($config);
 134
 135     # Creation of template outside of call to new so that we can pass [ $self ]
 136     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 137     # of include paths to search for templates.
 138
 139     # Use a weakend copy of self so we dont have loops preventing GC from working
 140     my $copy = $self;
 141     Scalar::Util::weaken($copy);
 142     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 143
 144     if ( $config->{PROVIDERS} ) {
 145         my @providers = ();
 146         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 147             foreach my $p (@{$config->{PROVIDERS}}) {
 148                 my $pname = $p->{name};
 149                 my $prov = 'Template::Provider';
 150                 if($pname eq '_file_')
 151                 {
 152                     $p->{args} = { %$config };
 153                 }
 154                 else
 155                 {
 156                     if($pname =~ s/^\+//) {
 157                         $prov = $pname;
 158                     }
 159                     else
 160                     {
 161                         $prov .= "::$pname";
 162                     }
 163                     # We copy the args people want from the config
 164                     # to the args
 165                     $p->{args} ||= {};
 166                     if ($p->{copy_config}) {
 167                         map  { $p->{args}->{$_} = $config->{$_}  }
 168                                    grep { exists $config->{$_} }
 169                                    @{ $p->{copy_config} };
 170                     }
 171                 }
 172                 local $@;
 173                 eval "require $prov";
 174                 if(!$@) {
 175                     push @providers, "$prov"->new($p->{args});
 176                 }
 177                 else
 178                 {
 179                     $c->log->warn("Can't load $prov, ($@)");
 180                 }
 181             }
 182         }
 183         delete $config->{PROVIDERS};
 184         if(@providers) {
 185             $config->{LOAD_TEMPLATES} = \@providers;
 186         }
 187     }
 188
 189     $self->{template} =
 190         Template->new($config) || do {
 191             my $error = Template->error();
 192             $c->log->error($error);
 193             $c->error($error);
 194             return undef;
 195         };
 196
 197
 198     return $self;
 199 }
 200
 201 sub process {
 202     my ( $self, $c ) = @_;
 203
 204     my $template = $c->stash->{template}
 205       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 206
 207     unless (defined $template) {
 208         $c->log->debug('No template specified for rendering') if $c->debug;
 209         return 0;
 210     }
 211
 212     local $@;
 213     my $output = eval { $self->render($c, $template) };
 214     if (my $err = $@) {
 215         return $self->_rendering_error($c, $template . ': ' . $err);
 216     }
 217     if (blessed($output) && $output->isa('Template::Exception')) {
 218         $self->_rendering_error($c, $output);
 219     }
 220
 221     unless ( $c->response->content_type ) {
 222         $c->response->content_type('text/html; charset=utf-8');
 223     }
 224
 225     $c->response->body($output);
 226
 227     return 1;
 228 }
 229
 230 sub _rendering_error {
 231     my ($self, $c, $err) = @_;
 232     my $error = qq/Couldn't render template "$err"/;
 233     $c->log->error($error);
 234     $c->error($error);
 235     return 0;
 236 }
 237
 238 sub render {
 239     my ($self, $c, $template, $args) = @_;
 240
 241     $c->log->debug(qq/Rendering template "$template"/) if $c && $c->debug;
 242
 243     my $output;
 244     my $vars = {
 245         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 246         $self->template_vars($c)
 247     };
 248
 249     local $self->{include_path} =
 250         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 251         if ref $vars->{additional_template_paths};
 252
 253     unless ( $self->template->process( $template, $vars, \$output ) ) {
 254         if (exists $self->{render_die}) {
 255             die $self->template->error if $self->{render_die};
 256             return $self->template->error;
 257         }
 258         $c->log->debug('The Catalyst::View::TT render() method will start dying on error in a future release. Unless you are calling the render() method manually, you probably want the new behaviour, so set render_die => 1 in config for ' . blessed($self) . '. If you wish to continue to return the exception rather than throwing it, add render_die => 0 to your config.') if $c->debug;
 259         return $self->template->error;
 260     }
 261     return $output;
 262 }
 263
 264 sub template_vars {
 265     my ( $self, $c ) = @_;
 266
 267     return  () unless $c;
 268     my $cvar = $self->config->{CATALYST_VAR};
 269
 270     my %vars = defined $cvar
 271       ? ( $cvar => $c )
 272       : (
 273         c    => $c,
 274         base => $c->req->base,
 275         name => $c->config->{name}
 276       );
 277
 278     if ($self->expose_methods) {
 279         my $meta = $self->meta;
 280         foreach my $method_name (@{$self->expose_methods}) {
 281             my $method = $meta->get_method( $method_name );
 282             unless ($method) {
 283                 Catalyst::Exception->throw( "$method_name not found in TT view" );
 284             }
 285             my $method_body = $method->body;
 286             my $weak_ctx = $c;
 287             weaken $weak_ctx;
 288             my $sub = sub {
 289                 $self->$method_body($weak_ctx, @_);
 290             };
 291             $vars{$method_name} = $sub;
 292         }
 293     }
 294     return %vars;
 295 }
 296
 297 1;
 298
 299 __END__
 300
 301 =head1 DESCRIPTION
 302
 303 This is the Catalyst view class for the L<Template Toolkit|Template>.
 304 Your application should defined a view class which is a subclass of
 305 this module. Throughout this manual it will be assumed that your application
 306 is named F<MyApp> and you are creating a TT view named F<Web>; these names
 307 are placeholders and should always be replaced with whatever name you've
 308 chosen for your application and your view. The easiest way to create a TT
 309 view class is through the F<myapp_create.pl> script that is created along
 310 with the application:
 311
 312     $ script/myapp_create.pl view Web TT
 313
 314 This creates a F<MyApp::View::Web.pm> module in the F<lib> directory (again,
 315 replacing C<MyApp> with the name of your application) which looks
 316 something like this:
 317
 318     package FooBar::View::Web;
 319
 320     use strict;
 321     use warnings;
 322
 323     use base 'Catalyst::View::TT';
 324
 325     __PACKAGE__->config(DEBUG => 'all');
 326
 327 Now you can modify your action handlers in the main application and/or
 328 controllers to forward to your view class.  You might choose to do this
 329 in the end() method, for example, to automatically forward all actions
 330 to the TT view class.
 331
 332     # In MyApp or MyApp::Controller::SomeController
 333
 334     sub end : Private {
 335         my( $self, $c ) = @_;
 336         $c->forward( $c->view('Web') );
 337     }
 338
 339 But if you are using the standard auto-generated end action, you don't even need
 340 to do this!
 341
 342     # in MyApp::Controller::Root
 343     sub end : ActionClass('RenderView') {} # no need to change this line
 344
 345     # in MyApp.pm
 346     __PACKAGE__->config(
 347         ...
 348         default_view => 'Web',
 349     );
 350
 351 This will Just Work.  And it has the advantages that:
 352
 353 =over 4
 354
 355 =item *
 356
 357 If you want to use a different view for a given request, just set
 358 << $c->stash->{current_view} >>.  (See L<Catalyst>'s C<< $c->view >> method
 359 for details.
 360
 361 =item *
 362
 363 << $c->res->redirect >> is handled by default.  If you just forward to
 364 C<View::Web> in your C<end> routine, you could break this by sending additional
 365 content.
 366
 367 =back
 368
 369 See L<Catalyst::Action::RenderView> for more details.
 370
 371 =head2 CONFIGURATION
 372
 373 There are a three different ways to configure your view class.  The
 374 first way is to call the C<config()> method in the view subclass.  This
 375 happens when the module is first loaded.
 376
 377     package MyApp::View::Web;
 378
 379     use strict;
 380     use base 'Catalyst::View::TT';
 381
 382     __PACKAGE__->config({
 383         INCLUDE_PATH => [
 384             MyApp->path_to( 'root', 'templates', 'lib' ),
 385             MyApp->path_to( 'root', 'templates', 'src' ),
 386         ],
 387         PRE_PROCESS  => 'config/main',
 388         WRAPPER      => 'site/wrapper',
 389     });
 390
 391 You may also override the configuration provided in the view class by adding
 392 a 'View::Web' section to your application config (either in the application
 393 main class, or in your configuration file). This should be reserved for
 394 deployment-specific concerns. For example:
 395
 396     # MyApp_local.conf (Config::General format)
 397
 398     <View Web>
 399       WRAPPER "custom_wrapper"
 400       INCLUDE_PATH __path_to('root/templates/custom_site')__
 401       INCLUDE_PATH __path_to('root/templates')__
 402     </View>
 403
 404 might be used as part of a simple way to deploy different instances of the
 405 same application with different themes.
 406
 407 =head2 DYNAMIC INCLUDE_PATH
 408
 409 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 410
 411 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 412 follows:
 413
 414     $c->stash->{additional_template_paths} =
 415         [$c->config->{root} . '/test_include_path'];
 416
 417 If you need to add paths to the end of INCLUDE_PATH, there is also an
 418 include_path() accessor available:
 419
 420     push( @{ $c->view('Web')->include_path }, qw/path/ );
 421
 422 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 423 MUST check for duplicate paths. Without such checking, the above code will add
 424 "path" to INCLUDE_PATH at every request, causing a memory leak.
 425
 426 A safer approach is to use include_path() to overwrite the array of paths
 427 rather than adding to it. This eliminates both the need to perform duplicate
 428 checking and the chance of a memory leak:
 429
 430     @{ $c->view('Web')->include_path } = qw/path another_path/;
 431
 432 If you are calling C<render> directly then you can specify dynamic paths by
 433 having a C<additional_template_paths> key with a value of additonal directories
 434 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 435
 436 =head2 RENDERING VIEWS
 437
 438 The view plugin renders the template specified in the C<template>
 439 item in the stash.
 440
 441     sub message : Global {
 442         my ( $self, $c ) = @_;
 443         $c->stash->{template} = 'message.tt2';
 444         $c->forward( $c->view('Web') );
 445     }
 446
 447 If a stash item isn't defined, then it instead uses the
 448 stringification of the action dispatched to (as defined by $c->action)
 449 in the above example, this would be C<message>, but because the default
 450 is to append '.tt', it would load C<root/message.tt>.
 451
 452 The items defined in the stash are passed to the Template Toolkit for
 453 use as template variables.
 454
 455     sub default : Private {
 456         my ( $self, $c ) = @_;
 457         $c->stash->{template} = 'message.tt2';
 458         $c->stash->{message}  = 'Hello World!';
 459         $c->forward( $c->view('Web') );
 460     }
 461
 462 A number of other template variables are also added:
 463
 464     c      A reference to the context object, $c
 465     base   The URL base, from $c->req->base()
 466     name   The application name, from $c->config->{ name }
 467
 468 These can be accessed from the template in the usual way:
 469
 470 <message.tt2>:
 471
 472     The message is: [% message %]
 473     The base is [% base %]
 474     The name is [% name %]
 475
 476
 477 The output generated by the template is stored in C<< $c->response->body >>.
 478
 479 =head2 CAPTURING TEMPLATE OUTPUT
 480
 481 If you wish to use the output of a template for some other purpose than
 482 displaying in the response, e.g. for sending an email, this is possible using
 483 L<Catalyst::Plugin::Email> and the L<render> method:
 484
 485   sub send_email : Local {
 486     my ($self, $c) = @_;
 487
 488     $c->email(
 489       header => [
 490         To      => 'me@localhost',
 491         Subject => 'A TT Email',
 492       ],
 493       body => $c->view('Web')->render($c, 'email.tt', {
 494         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 495         email_tmpl_param1 => 'foo'
 496         }
 497       ),
 498     );
 499   # Redirect or display a message
 500   }
 501
 502 =head2 TEMPLATE PROFILING
 503
 504 See L<C<TIMER>> property of the L<config> method.
 505
 506 =head2 METHODS
 507
 508 =head2 new
 509
 510 The constructor for the TT view. Sets up the template provider,
 511 and reads the application config.
 512
 513 =head2 process($c)
 514
 515 Renders the template specified in C<< $c->stash->{template} >> or
 516 C<< $c->action >> (the private name of the matched action).  Calls L<render> to
 517 perform actual rendering. Output is stored in C<< $c->response->body >>.
 518
 519 It is possible to forward to the process method of a TT view from inside
 520 Catalyst like this:
 521
 522     $c->forward('View::Web');
 523
 524 N.B. This is usually done automatically by L<Catalyst::Action::RenderView>.
 525
 526 =head2 render($c, $template, \%args)
 527
 528 Renders the given template and returns output. Throws a L<Template::Exception>
 529 object upon error.
 530
 531 The template variables are set to C<%$args> if C<$args> is a hashref, or
 532 C<< $c->stash >> otherwise. In either case the variables are augmented with
 533 C<base> set to C<< $c->req->base >>, C<c> to C<$c>, and C<name> to
 534 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 535 can be defined to specify the name of a template variable through which the
 536 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base>, and
 537 C<name> variables are omitted.
 538
 539 C<$template> can be anything that Template::process understands how to
 540 process, including the name of a template file or a reference to a test string.
 541 See L<Template::process|Template/process> for a full list of supported formats.
 542
 543 To use the render method outside of your Catalyst app, just pass a undef context.
 544 This can be useful for tests, for instance.
 545
 546 It is possible to forward to the render method of a TT view from inside Catalyst
 547 to render page fragments like this:
 548
 549     my $fragment = $c->forward("View::Web", "render", $template_name, $c->stash->{fragment_data});
 550
 551 =head3 Backwards compatibility note
 552
 553 The render method used to just return the Template::Exception object, rather
 554 than just throwing it. This is now deprecated and instead the render method
 555 will throw an exception for new applications.
 556
 557 This behaviour can be activated (and is activated in the default skeleton
 558 configuration) by using C<< render_die => 1 >>. If you rely on the legacy
 559 behaviour then a warning will be issued.
 560
 561 To silence this warning, set C<< render_die => 0 >>, but it is recommended
 562 you adjust your code so that it works with C<< render_die => 1 >>.
 563
 564 In a future release, C<< render_die => 1 >> will become the default if
 565 unspecified.
 566
 567 =head2 template_vars
 568
 569 Returns a list of keys/values to be used as the catalyst variables in the
 570 template.
 571
 572 =head2 config
 573
 574 This method allows your view subclass to pass additional settings to
 575 the TT configuration hash, or to set the options as below:
 576
 577 =head2 paths
 578
 579 The list of paths TT will look for templates in.
 580
 581 =head2 expose_methods
 582
 583 The list of methods in your View class which should be made available to the templates.
 584
 585 For example:
 586
 587   expose_methods => [qw/uri_for_static/],
 588
 589   ...
 590
 591   sub uri_for_css {
 592     my ($self, $c, $filename) = @_;
 593
 594     # additional complexity like checking file exists here
 595
 596     return $c->uri_for('/static/css/' . $filename);
 597   }
 598
 599 Then in the template:
 600
 601   [% uri_for_css('home.css') %]
 602
 603 =head2 C<CATALYST_VAR>
 604
 605 Allows you to change the name of the Catalyst context object. If set, it will also
 606 remove the base and name aliases, so you will have access them through <context>.
 607
 608 For example, if CATALYST_VAR has been set to "Catalyst", a template might
 609 contain:
 610
 611     The base is [% Catalyst.req.base %]
 612     The name is [% Catalyst.config.name %]
 613
 614 =head2 C<TIMER>
 615
 616 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 617 C<Catalyst::View::TT> will enable profiling of template processing
 618 (using L<Template::Timer>). This will embed HTML comments in the
 619 output from your templates, such as:
 620
 621     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 622     <!-- TIMER START: include mainmenu/cssindex.tt -->
 623     <!-- TIMER START: process mainmenu/cssindex.tt -->
 624     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 625     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 626
 627     ....
 628
 629     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 630
 631
 632 =head2 C<TEMPLATE_EXTENSION>
 633
 634 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 635
 636 For example:
 637
 638   package MyApp::Controller::Test;
 639   sub test : Local { .. }
 640
 641 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 642 <root>/test/test.tt.
 643
 644 =head2 C<PROVIDERS>
 645
 646 Allows you to specify the template providers that TT will use.
 647
 648     MyApp->config({
 649         name     => 'MyApp',
 650         root     => MyApp->path_to('root'),
 651         'View::Web' => {
 652             PROVIDERS => [
 653                 {
 654                     name    => 'DBI',
 655                     args    => {
 656                         DBI_DSN => 'dbi:DB2:books',
 657                         DBI_USER=> 'foo'
 658                     }
 659                 }, {
 660                     name    => '_file_',
 661                     args    => {}
 662                 }
 663             ]
 664         },
 665     });
 666
 667 The 'name' key should correspond to the class name of the provider you
 668 want to use.  The _file_ name is a special case that represents the default
 669 TT file-based provider.  By default the name is will be prefixed with
 670 'Template::Provider::'.  You can fully qualify the name by using a unary
 671 plus:
 672
 673     name => '+MyApp::Provider::Foo'
 674
 675 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 676 from the general config, into the config for the provider:
 677
 678     DEFAULT_ENCODING    => 'utf-8',
 679     PROVIDERS => [
 680         {
 681             name    => 'Encoding',
 682             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 683         }
 684     ]
 685
 686 This can prove useful when you want to use the additional_template_paths hack
 687 in your own provider, or if you need to use Template::Provider::Encoding
 688
 689 =head2 HELPERS
 690
 691 The L<Catalyst::Helper::View::TT> and
 692 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 693 your view module.  There are invoked by the F<myapp_create.pl> script:
 694
 695     $ script/myapp_create.pl view Web TT
 696
 697     $ script/myapp_create.pl view Web TTSite
 698
 699 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 700 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 701 further.  It also creates a default set of templates to get you
 702 started.  It also configures the view module to locate the templates
 703 automatically.
 704
 705 =head1 NOTES
 706
 707 If you are using the L<CGI> module inside your templates, you will
 708 experience that the Catalyst server appears to hang while rendering
 709 the web page. This is due to the debug mode of L<CGI> (which is
 710 waiting for input in the terminal window). Turning off the
 711 debug mode using the "-no_debug" option solves the
 712 problem, eg.:
 713
 714     [% USE CGI('-no_debug') %]
 715
 716 =head1 SEE ALSO
 717
 718 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 719 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 720
 721 =head1 AUTHORS
 722
 723 Sebastian Riedel, C<sri@cpan.org>
 724
 725 Marcus Ramberg, C<mramberg@cpan.org>
 726
 727 Jesse Sheidlower, C<jester@panix.com>
 728
 729 Andy Wardley, C<abw@cpan.org>
 730
 731 Luke Saunders, C<luke.saunders@gmail.com>
 732
 733 =head1 COPYRIGHT
 734
 735 This program is free software. You can redistribute it and/or modify it
 736 under the same terms as Perl itself.
 737
 738 =cut