lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use base qw/Catalyst::Base/;
   5 use Template;
   6 use Template::Timer;
   7 use NEXT;
   8
   9 our $VERSION = '0.08';
  10
  11 __PACKAGE__->mk_accessors('template');
  12
  13 =head1 NAME
  14
  15 Catalyst::View::TT - Template View Class
  16
  17 =head1 SYNOPSIS
  18
  19     # use the helper
  20     create.pl view TT TT
  21
  22     # lib/MyApp/View/TT.pm
  23     package MyApp::View::TT;
  24
  25     use base 'Catalyst::View::TT';
  26
  27     __PACKAGE__->config->{DEBUG} = 'all';
  28
  29     1;
  30
  31     # Meanwhile, maybe in an '!end' action
  32     $c->forward('MyApp::View::TT');
  33
  34
  35 =head1 DESCRIPTION
  36
  37 This is the C<Template> view class. Your subclass should inherit from this
  38 class.  The plugin renders the template specified in C<< $c->stash->{template} >>
  39 or C<< $c->request->match >>.  The template variables are set up from the
  40 contents of C<< $c->stash >>, augmented with C<base> set to C<< $c->req->base >>,
  41 C<c> to C<$c> and C<name> to C<< $c->config->{name} >>.  The output is
  42 stored in C<< $c->response->output >>.
  43
  44
  45 If you want to override TT config settings, you can do it there by setting
  46 C<< __PACKAGE__->config->{OPTION} >> as shown in the synopsis. Of interest might be
  47 C<EVAL_PERL>, which is disabled by default, and C<LOAD_TEMPLATES>, which is set to
  48 use the provider.
  49
  50 If you want to use EVAL perl, add something like this:
  51
  52     __PACKAGE__->config->{EVAL_PERL} = 1;
  53     __PACKAGE__->config->{LOAD_TEMPLATES} = undef;
  54
  55 If you have configured Catalyst for debug output C<Catalyst::View::TT> will
  56 enable profiling of template processing (using C<Template::Timer>.  This will cause
  57 HTML comments will get embedded in the output from your templates, such as:
  58
  59     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
  60     <!-- TIMER START: include mainmenu/cssindex.tt -->
  61     <!-- TIMER START: process mainmenu/cssindex.tt -->
  62     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
  63     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
  64
  65     ....
  66
  67     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
  68
  69 You can supress template profiling when debug is enabled by setting:
  70
  71     __PACKAGE__->config->{CONTEXT} = undef;
  72
  73
  74 =head2 METHODS
  75
  76 =cut
  77
  78 sub new {
  79     my $self = shift;
  80     my $c    = shift;
  81     $self = $self->NEXT::new(@_);
  82     my $root   = $c->config->{root};
  83     my %config = (
  84         EVAL_PERL    => 0,
  85         INCLUDE_PATH => [ $root, "$root/base" ],
  86         %{ $self->config() }
  87     );
  88
  89     if ( $c->debug && not exists $config{CONTEXT} ) {
  90        $config{CONTEXT} = Template::Timer->new(%config);
  91     }
  92
  93     $self->template( Template->new( \%config ) );
  94     return $self;
  95 }
  96
  97 =head3 process
  98
  99 Renders the template specified in C<< $c->stash->{template} >> or C<< $c->request->match >>.
 100 Template variables are set up from the contents of C<< $c->stash >>, augmented with C<base>
 101 set to C<< $c->req->base >>, C<c> to C<$c> and C<name> to C<< $c->config->{name} >>.  Output is
 102 stored in C<< $c->response->output >>.
 103
 104 =cut
 105
 106 sub process {
 107     my ( $self, $c ) = @_;
 108     $c->res->headers->content_type('text/html; charset=utf-8')
 109     unless $c->res->headers->content_type();
 110     my $output;
 111     my $name = $c->stash->{template} || $c->req->match;
 112     unless ($name) {
 113         $c->log->debug('No template specified for rendering') if $c->debug;
 114         return 0;
 115     }
 116     $c->log->debug(qq/Rendering template "$name"/) if $c->debug;
 117     unless (
 118         $self->template->process(
 119             $name,
 120             {
 121                 base => $c->req->base,
 122                 c    => $c,
 123                 name => $c->config->{name},
 124                 %{ $c->stash }
 125             },
 126             \$output
 127         )
 128       )
 129     {
 130         my $error = $self->template->error;
 131         $error = qq/Couldn't render template "$error"/;
 132         $c->log->error($error);
 133         $c->errors($error);
 134     }
 135     $c->res->output($output);
 136     return 1;
 137 }
 138
 139 =head3 config
 140
 141 This allows your view subclass to pass additional settings to the
 142 TT config hash.
 143
 144 =cut
 145
 146 =head1 SEE ALSO
 147
 148 L<Catalyst>.
 149
 150 =head1 AUTHOR
 151
 152 Sebastian Riedel, C<sri@cpan.org>
 153 Marcus Ramberg, C<mramberg@cpan.org>
 154
 155 =head1 COPYRIGHT
 156
 157 This program is free software, you can redistribute it and/or modify it under
 158 the same terms as Perl itself.
 159
 160 =cut
 161
 162 1;