lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11
  12 our $VERSION = '0.32';
  13
  14 __PACKAGE__->mk_accessors('template');
  15 __PACKAGE__->mk_accessors('include_path');
  16
  17 *paths = \&include_path;
  18
  19 =head1 NAME
  20
  21 Catalyst::View::TT - Template View Class
  22
  23 =head1 SYNOPSIS
  24
  25 # use the helper to create your View
  26
  27     myapp_create.pl view TT TT
  28
  29 # configure in lib/MyApp.pm (Could be set from configfile instead)
  30
  31     MyApp->config(
  32         name     => 'MyApp',
  33         root     => MyApp->path_to('root'),
  34         'View::TT' => {
  35             # any TT configurations items go here
  36             INCLUDE_PATH => [
  37               MyApp->path_to( 'root', 'src' ),
  38               MyApp->path_to( 'root', 'lib' ),
  39             ],
  40             TEMPLATE_EXTENSION => '.tt',
  41             CATALYST_VAR => 'c',
  42             TIMER        => 0,
  43             # Not set by default
  44             PRE_PROCESS        => 'config/main',
  45             WRAPPER            => 'site/wrapper',
  46         },
  47     );
  48
  49 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  50
  51     sub message : Global {
  52         my ( $self, $c ) = @_;
  53         $c->stash->{template} = 'message.tt2';
  54         $c->stash->{message}  = 'Hello World!';
  55         $c->forward( $c->view('TT') );
  56     }
  57
  58 # access variables from template
  59
  60     The message is: [% message %].
  61
  62     # example when CATALYST_VAR is set to 'Catalyst'
  63     Context is [% Catalyst %]
  64     The base is [% Catalyst.req.base %]
  65     The name is [% Catalyst.config.name %]
  66
  67     # example when CATALYST_VAR isn't set
  68     Context is [% c %]
  69     The base is [% base %]
  70     The name is [% name %]
  71
  72 =cut
  73
  74 sub _coerce_paths {
  75     my ( $paths, $dlim ) = shift;
  76     return () if ( !$paths );
  77     return @{$paths} if ( ref $paths eq 'ARRAY' );
  78
  79     # tweak delim to ignore C:/
  80     unless ( defined $dlim ) {
  81         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  82     }
  83     return split( /$dlim/, $paths );
  84 }
  85
  86 sub new {
  87     my ( $class, $c, $arguments ) = @_;
  88     my $config = {
  89         EVAL_PERL          => 0,
  90         TEMPLATE_EXTENSION => '',
  91         %{ $class->config },
  92         %{$arguments},
  93     };
  94     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  95         my $delim = $config->{DELIMITER};
  96         my @include_path
  97             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  98         if ( !@include_path ) {
  99             my $root = $c->config->{root};
 100             my $base = Path::Class::dir( $root, 'base' );
 101             @include_path = ( "$root", "$base" );
 102         }
 103         $config->{INCLUDE_PATH} = \@include_path;
 104     }
 105
 106     # if we're debugging and/or the TIMER option is set, then we install
 107     # Template::Timer as a custom CONTEXT object, but only if we haven't
 108     # already got a custom CONTEXT defined
 109
 110     if ( $config->{TIMER} ) {
 111         if ( $config->{CONTEXT} ) {
 112             $c->log->error(
 113                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 114             );
 115         }
 116         else {
 117             $config->{CONTEXT} = Template::Timer->new(%$config);
 118         }
 119     }
 120
 121     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 122         $c->log->debug( "TT Config: ", dump($config) );
 123     }
 124
 125     my $self = $class->next::method(
 126         $c, { %$config },
 127     );
 128
 129     # Set base include paths. Local'd in render if needed
 130     $self->include_path($config->{INCLUDE_PATH});
 131
 132     $self->config($config);
 133
 134     # Creation of template outside of call to new so that we can pass [ $self ]
 135     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 136     # of include paths to search for templates.
 137
 138     # Use a weakend copy of self so we dont have loops preventing GC from working
 139     my $copy = $self;
 140     Scalar::Util::weaken($copy);
 141     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 142
 143     if ( $config->{PROVIDERS} ) {
 144         my @providers = ();
 145         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 146             foreach my $p (@{$config->{PROVIDERS}}) {
 147                 my $pname = $p->{name};
 148                 my $prov = 'Template::Provider';
 149                 if($pname eq '_file_')
 150                 {
 151                     $p->{args} = { %$config };
 152                 }
 153                 else
 154                 {
 155                     if($pname =~ s/^\+//) {
 156                         $prov = $pname;
 157                     }
 158                     else
 159                     {
 160                         $prov .= "::$pname";
 161                     }
 162                     # We copy the args people want from the config
 163                     # to the args
 164                     $p->{args} ||= {};
 165                     if ($p->{copy_config}) {
 166                         map  { $p->{args}->{$_} = $config->{$_}  }
 167                                    grep { exists $config->{$_} }
 168                                    @{ $p->{copy_config} };
 169                     }
 170                 }
 171                 local $@;
 172                 eval "require $prov";
 173                 if(!$@) {
 174                     push @providers, "$prov"->new($p->{args});
 175                 }
 176                 else
 177                 {
 178                     $c->log->warn("Can't load $prov, ($@)");
 179                 }
 180             }
 181         }
 182         delete $config->{PROVIDERS};
 183         if(@providers) {
 184             $config->{LOAD_TEMPLATES} = \@providers;
 185         }
 186     }
 187
 188     $self->{template} =
 189         Template->new($config) || do {
 190             my $error = Template->error();
 191             $c->log->error($error);
 192             $c->error($error);
 193             return undef;
 194         };
 195
 196
 197     return $self;
 198 }
 199
 200 sub process {
 201     my ( $self, $c ) = @_;
 202
 203     my $template = $c->stash->{template}
 204       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 205
 206     unless (defined $template) {
 207         $c->log->debug('No template specified for rendering') if $c->debug;
 208         return 0;
 209     }
 210
 211     local $@;
 212     my $output = eval { $self->render($c, $template) };
 213     if (my $err = $@) {
 214         my $error = qq/Couldn't render template "$template"/;
 215         $c->log->error($error);
 216         $c->error($error);
 217         return 0;
 218     }
 219
 220     unless ( $c->response->content_type ) {
 221         $c->response->content_type('text/html; charset=utf-8');
 222     }
 223
 224     $c->response->body($output);
 225
 226     return 1;
 227 }
 228
 229 sub render {
 230     my ($self, $c, $template, $args) = @_;
 231
 232     $c->log->debug(qq/Rendering template "$template"/) if $c && $c->debug;
 233
 234     my $output;
 235     my $vars = {
 236         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 237         $self->template_vars($c)
 238     };
 239
 240     local $self->{include_path} =
 241         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 242         if ref $vars->{additional_template_paths};
 243
 244     unless ( $self->template->process( $template, $vars, \$output ) ) {
 245         if (exists $self->{render_die}) {
 246             die $self->template->error if $self->{render_die};
 247             return $self->template->error;
 248         }
 249         require Carp;
 250         Carp::carp('The Catalyst::View::TT render() method of will die on error in a future release. If you want it to continue to return the exception instead, pass render_die => 0 to the constructor');
 251         return $self->template->error;
 252     }
 253     return $output;
 254 }
 255
 256 sub template_vars {
 257     my ( $self, $c ) = @_;
 258
 259     return  () unless $c;
 260     my $cvar = $self->config->{CATALYST_VAR};
 261
 262     defined $cvar
 263       ? ( $cvar => $c )
 264       : (
 265         c    => $c,
 266         base => $c->req->base,
 267         name => $c->config->{name}
 268       )
 269 }
 270
 271
 272 1;
 273
 274 __END__
 275
 276 =head1 DESCRIPTION
 277
 278 This is the Catalyst view class for the L<Template Toolkit|Template>.
 279 Your application should defined a view class which is a subclass of
 280 this module.  The easiest way to achieve this is using the
 281 F<myapp_create.pl> script (where F<myapp> should be replaced with
 282 whatever your application is called).  This script is created as part
 283 of the Catalyst setup.
 284
 285     $ script/myapp_create.pl view TT TT
 286
 287 This creates a MyApp::View::TT.pm module in the F<lib> directory (again,
 288 replacing C<MyApp> with the name of your application) which looks
 289 something like this:
 290
 291     package FooBar::View::TT;
 292
 293     use strict;
 294     use warnings;
 295
 296     use base 'Catalyst::View::TT';
 297
 298     __PACKAGE__->config(DEBUG => 'all');
 299
 300 Now you can modify your action handlers in the main application and/or
 301 controllers to forward to your view class.  You might choose to do this
 302 in the end() method, for example, to automatically forward all actions
 303 to the TT view class.
 304
 305     # In MyApp or MyApp::Controller::SomeController
 306
 307     sub end : Private {
 308         my( $self, $c ) = @_;
 309         $c->forward( $c->view('TT') );
 310     }
 311
 312 But if you are using the standard auto-generated end action, you don't even need
 313 to do this!
 314
 315     # in MyApp::Controller::Root
 316     sub end : ActionClass('RenderView') {} # no need to change this line
 317
 318     # in MyApp.pm
 319     __PACKAGE__->config(
 320         ...
 321         default_view => 'TT',
 322     );
 323
 324 This will Just Work.  And it has the advantages that:
 325
 326 =over 4
 327
 328 =item *
 329
 330 If you want to use a different view for a given request, just set
 331 << $c->stash->{current_view} >>.  (See L<Catalyst>'s C<< $c->view >> method
 332 for details.
 333
 334 =item *
 335
 336 << $c->res->redirect >> is handled by default.  If you just forward to
 337 C<View::TT> in your C<end> routine, you could break this by sending additional
 338 content.
 339
 340 =back
 341
 342 See L<Catalyst::Action::RenderView> for more details.
 343
 344 =head2 CONFIGURATION
 345
 346 There are a three different ways to configure your view class.  The
 347 first way is to call the C<config()> method in the view subclass.  This
 348 happens when the module is first loaded.
 349
 350     package MyApp::View::TT;
 351
 352     use strict;
 353     use base 'Catalyst::View::TT';
 354
 355     MyApp::View::TT->config({
 356         INCLUDE_PATH => [
 357             MyApp->path_to( 'root', 'templates', 'lib' ),
 358             MyApp->path_to( 'root', 'templates', 'src' ),
 359         ],
 360         PRE_PROCESS  => 'config/main',
 361         WRAPPER      => 'site/wrapper',
 362     });
 363
 364 The second way is to define a C<new()> method in your view subclass.
 365 This performs the configuration when the view object is created,
 366 shortly after being loaded.  Remember to delegate to the base class
 367 C<new()> method (via C<$self-E<gt>next::method()> in the example below) after
 368 performing any configuration.
 369
 370     sub new {
 371         my $self = shift;
 372         $self->config({
 373             INCLUDE_PATH => [
 374                 MyApp->path_to( 'root', 'templates', 'lib' ),
 375                 MyApp->path_to( 'root', 'templates', 'src' ),
 376             ],
 377             PRE_PROCESS  => 'config/main',
 378             WRAPPER      => 'site/wrapper',
 379         });
 380         return $self->next::method(@_);
 381     }
 382
 383 The final, and perhaps most direct way, is to define a class
 384 item in your main application configuration, again by calling the
 385 ubiquitous C<config()> method.  The items in the class hash are
 386 added to those already defined by the above two methods.  This happens
 387 in the base class new() method (which is one reason why you must
 388 remember to call it via C<MRO::Compat> if you redefine the C<new()>
 389 method in a subclass).
 390
 391     package MyApp;
 392
 393     use strict;
 394     use Catalyst;
 395
 396     MyApp->config({
 397         name     => 'MyApp',
 398         root     => MyApp->path_to('root'),
 399         'View::TT' => {
 400             INCLUDE_PATH => [
 401                 MyApp->path_to( 'root', 'templates', 'lib' ),
 402                 MyApp->path_to( 'root', 'templates', 'src' ),
 403             ],
 404             PRE_PROCESS  => 'config/main',
 405             WRAPPER      => 'site/wrapper',
 406         },
 407     });
 408
 409 Note that any configuration items defined by one of the earlier
 410 methods will be overwritten by items of the same name provided by the
 411 latter methods.
 412
 413 =head2 DYNAMIC INCLUDE_PATH
 414
 415 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 416
 417 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 418 follows:
 419
 420     $c->stash->{additional_template_paths} =
 421         [$c->config->{root} . '/test_include_path'];
 422
 423 If you need to add paths to the end of INCLUDE_PATH, there is also an
 424 include_path() accessor available:
 425
 426     push( @{ $c->view('TT')->include_path }, qw/path/ );
 427
 428 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 429 MUST check for duplicate paths. Without such checking, the above code will add
 430 "path" to INCLUDE_PATH at every request, causing a memory leak.
 431
 432 A safer approach is to use include_path() to overwrite the array of paths
 433 rather than adding to it. This eliminates both the need to perform duplicate
 434 checking and the chance of a memory leak:
 435
 436     @{ $c->view('TT')->include_path } = qw/path another_path/;
 437
 438 If you are calling C<render> directly then you can specify dynamic paths by
 439 having a C<additional_template_paths> key with a value of additonal directories
 440 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 441
 442 =head2 RENDERING VIEWS
 443
 444 The view plugin renders the template specified in the C<template>
 445 item in the stash.
 446
 447     sub message : Global {
 448         my ( $self, $c ) = @_;
 449         $c->stash->{template} = 'message.tt2';
 450         $c->forward( $c->view('TT') );
 451     }
 452
 453 If a stash item isn't defined, then it instead uses the
 454 stringification of the action dispatched to (as defined by $c->action)
 455 in the above example, this would be C<message>, but because the default
 456 is to append '.tt', it would load C<root/message.tt>.
 457
 458 The items defined in the stash are passed to the Template Toolkit for
 459 use as template variables.
 460
 461     sub default : Private {
 462         my ( $self, $c ) = @_;
 463         $c->stash->{template} = 'message.tt2';
 464         $c->stash->{message}  = 'Hello World!';
 465         $c->forward( $c->view('TT') );
 466     }
 467
 468 A number of other template variables are also added:
 469
 470     c      A reference to the context object, $c
 471     base   The URL base, from $c->req->base()
 472     name   The application name, from $c->config->{ name }
 473
 474 These can be accessed from the template in the usual way:
 475
 476 <message.tt2>:
 477
 478     The message is: [% message %]
 479     The base is [% base %]
 480     The name is [% name %]
 481
 482
 483 The output generated by the template is stored in C<< $c->response->body >>.
 484
 485 =head2 CAPTURING TEMPLATE OUTPUT
 486
 487 If you wish to use the output of a template for some other purpose than
 488 displaying in the response, e.g. for sending an email, this is possible using
 489 L<Catalyst::Plugin::Email> and the L<render> method:
 490
 491   sub send_email : Local {
 492     my ($self, $c) = @_;
 493
 494     $c->email(
 495       header => [
 496         To      => 'me@localhost',
 497         Subject => 'A TT Email',
 498       ],
 499       body => $c->view('TT')->render($c, 'email.tt', {
 500         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 501         email_tmpl_param1 => 'foo'
 502         }
 503       ),
 504     );
 505   # Redirect or display a message
 506   }
 507
 508 =head2 TEMPLATE PROFILING
 509
 510 See L<C<TIMER>> property of the L<config> method.
 511
 512 =head2 METHODS
 513
 514 =head2 new
 515
 516 The constructor for the TT view. Sets up the template provider,
 517 and reads the application config.
 518
 519 =head2 process($c)
 520
 521 Renders the template specified in C<< $c->stash->{template} >> or
 522 C<< $c->action >> (the private name of the matched action).  Calls L<render> to
 523 perform actual rendering. Output is stored in C<< $c->response->body >>.
 524
 525 It is possible to forward to the process method of a TT view from inside
 526 Catalyst like this:
 527
 528     $c->forward('View::TT');
 529
 530 N.B. This is usually done automatically by L<Catalyst::Action::RenderView>.
 531
 532 =head2 render($c, $template, \%args)
 533
 534 Renders the given template and returns output. Throws a L<Template::Exception>
 535 object upon error.
 536
 537 The template variables are set to C<%$args> if $args is a hashref, or
 538 $C<< $c->stash >> otherwise. In either case the variables are augmented with
 539 C<base> set to C< << $c->req->base >>, C<c> to C<$c> and C<name> to
 540 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 541 can be defined to specify the name of a template variable through which the
 542 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base> and
 543 C<name> variables are omitted.
 544
 545 C<$template> can be anything that Template::process understands how to
 546 process, including the name of a template file or a reference to a test string.
 547 See L<Template::process|Template/process> for a full list of supported formats.
 548
 549 To use the render method outside of your Catalyst app, just pass a undef context.
 550 This can be useful for tests, for instance.
 551
 552 It is possible to forward to the render method of a TT view from inside Catalyst
 553 to render page fragments like this:
 554
 555     my $fragment = $c->forward("View::TT", "render", $template_name, $c->stash->{fragment_data});
 556
 557 =head2 template_vars
 558
 559 Returns a list of keys/values to be used as the catalyst variables in the
 560 template.
 561
 562 =head2 config
 563
 564 This method allows your view subclass to pass additional settings to
 565 the TT configuration hash, or to set the options as below:
 566
 567 =head2 paths
 568
 569 The list of paths TT will look for templates in.
 570
 571 =head2 C<CATALYST_VAR>
 572
 573 Allows you to change the name of the Catalyst context object. If set, it will also
 574 remove the base and name aliases, so you will have access them through <context>.
 575
 576 For example:
 577
 578     MyApp->config({
 579         name     => 'MyApp',
 580         root     => MyApp->path_to('root'),
 581         'View::TT' => {
 582             CATALYST_VAR => 'Catalyst',
 583         },
 584     });
 585
 586 F<message.tt2>:
 587
 588     The base is [% Catalyst.req.base %]
 589     The name is [% Catalyst.config.name %]
 590
 591 =head2 C<TIMER>
 592
 593 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 594 C<Catalyst::View::TT> will enable profiling of template processing
 595 (using L<Template::Timer>). This will embed HTML comments in the
 596 output from your templates, such as:
 597
 598     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 599     <!-- TIMER START: include mainmenu/cssindex.tt -->
 600     <!-- TIMER START: process mainmenu/cssindex.tt -->
 601     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 602     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 603
 604     ....
 605
 606     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 607
 608
 609 =head2 C<TEMPLATE_EXTENSION>
 610
 611 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 612
 613 For example:
 614
 615   package MyApp::Controller::Test;
 616   sub test : Local { .. }
 617
 618 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 619 <root>/test/test.tt.
 620
 621 =head2 C<PROVIDERS>
 622
 623 Allows you to specify the template providers that TT will use.
 624
 625     MyApp->config({
 626         name     => 'MyApp',
 627         root     => MyApp->path_to('root'),
 628         'View::TT' => {
 629             PROVIDERS => [
 630                 {
 631                     name    => 'DBI',
 632                     args    => {
 633                         DBI_DSN => 'dbi:DB2:books',
 634                         DBI_USER=> 'foo'
 635                     }
 636                 }, {
 637                     name    => '_file_',
 638                     args    => {}
 639                 }
 640             ]
 641         },
 642     });
 643
 644 The 'name' key should correspond to the class name of the provider you
 645 want to use.  The _file_ name is a special case that represents the default
 646 TT file-based provider.  By default the name is will be prefixed with
 647 'Template::Provider::'.  You can fully qualify the name by using a unary
 648 plus:
 649
 650     name => '+MyApp::Provider::Foo'
 651
 652 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 653 from the general config, into the config for the provider:
 654
 655     DEFAULT_ENCODING    => 'utf-8',
 656     PROVIDERS => [
 657         {
 658             name    => 'Encoding',
 659             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 660         }
 661     ]
 662
 663 This can prove useful when you want to use the additional_template_paths hack
 664 in your own provider, or if you need to use Template::Provider::Encoding
 665
 666 =head2 HELPERS
 667
 668 The L<Catalyst::Helper::View::TT> and
 669 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 670 your view module.  There are invoked by the F<myapp_create.pl> script:
 671
 672     $ script/myapp_create.pl view TT TT
 673
 674     $ script/myapp_create.pl view TT TTSite
 675
 676 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 677 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 678 further.  It also creates a default set of templates to get you
 679 started.  It also configures the view module to locate the templates
 680 automatically.
 681
 682 =head1 NOTES
 683
 684 If you are using the L<CGI> module inside your templates, you will
 685 experience that the Catalyst server appears to hang while rendering
 686 the web page. This is due to the debug mode of L<CGI> (which is
 687 waiting for input in the terminal window). Turning off the
 688 debug mode using the "-no_debug" option solves the
 689 problem, eg.:
 690
 691     [% USE CGI('-no_debug') %]
 692
 693 =head1 SEE ALSO
 694
 695 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 696 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 697
 698 =head1 AUTHORS
 699
 700 Sebastian Riedel, C<sri@cpan.org>
 701
 702 Marcus Ramberg, C<mramberg@cpan.org>
 703
 704 Jesse Sheidlower, C<jester@panix.com>
 705
 706 Andy Wardley, C<abw@cpan.org>
 707
 708 =head1 COPYRIGHT
 709
 710 This program is free software. You can redistribute it and/or modify it
 711 under the same terms as Perl itself.
 712
 713 =cut