lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use base qw/Catalyst::View/;
   5 use Data::Dump 'dump';
   6 use Template;
   7 use Template::Timer;
   8 use NEXT;
   9
  10 our $VERSION = '0.26';
  11
  12 __PACKAGE__->mk_accessors('template');
  13 __PACKAGE__->mk_accessors('include_path');
  14
  15 *paths = \&include_path;
  16
  17 =head1 NAME
  18
  19 Catalyst::View::TT - Template View Class
  20
  21 =head1 SYNOPSIS
  22
  23 # use the helper to create your View
  24     myapp_create.pl view TT TT
  25
  26 # configure in lib/MyApp.pm
  27
  28     MyApp->config(
  29         name     => 'MyApp',
  30         root     => MyApp->path_to('root'),
  31         'View::TT' => {
  32             # any TT configurations items go here
  33             INCLUDE_PATH => [
  34               MyApp->path_to( 'root', 'src' ),
  35               MyApp->path_to( 'root', 'lib' ),
  36             ],
  37             PRE_PROCESS        => 'config/main',
  38             WRAPPER            => 'site/wrapper',
  39             TEMPLATE_EXTENSION => '.tt',
  40
  41             # two optional config items
  42             CATALYST_VAR => 'Catalyst',
  43             TIMER        => 1,
  44         },
  45     );
  46
  47 # render view from lib/MyApp.pm or lib/MyApp::C::SomeController.pm
  48
  49     sub message : Global {
  50         my ( $self, $c ) = @_;
  51         $c->stash->{template} = 'message.tt2';
  52         $c->stash->{message}  = 'Hello World!';
  53         $c->forward('MyApp::V::TT');
  54     }
  55
  56 # access variables from template
  57
  58     The message is: [% message %].
  59
  60     # example when CATALYST_VAR is set to 'Catalyst'
  61     Context is [% Catalyst %]
  62     The base is [% Catalyst.req.base %]
  63     The name is [% Catalyst.config.name %]
  64
  65     # example when CATALYST_VAR isn't set
  66     Context is [% c %]
  67     The base is [% base %]
  68     The name is [% name %]
  69
  70 =cut
  71
  72 sub _coerce_paths {
  73     my ( $paths, $dlim ) = shift;
  74     return () if ( !$paths );
  75     return @{$paths} if ( ref $paths eq 'ARRAY' );
  76
  77     # tweak delim to ignore C:/
  78     unless ( defined $dlim ) {
  79         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  80     }
  81     return split( /$dlim/, $paths );
  82 }
  83
  84 sub new {
  85     my ( $class, $c, $arguments ) = @_;
  86     my $config = {
  87         EVAL_PERL          => 0,
  88         TEMPLATE_EXTENSION => '',
  89         %{ $class->config },
  90         %{$arguments},
  91     };
  92     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  93         my $delim = $config->{DELIMITER};
  94         my @include_path
  95             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  96         if ( !@include_path ) {
  97             my $root = $c->config->{root};
  98             my $base = Path::Class::dir( $root, 'base' );
  99             @include_path = ( "$root", "$base" );
 100         }
 101         $config->{INCLUDE_PATH} = \@include_path;
 102     }
 103
 104     # if we're debugging and/or the TIMER option is set, then we install
 105     # Template::Timer as a custom CONTEXT object, but only if we haven't
 106     # already got a custom CONTEXT defined
 107
 108     if ( $config->{TIMER} ) {
 109         if ( $config->{CONTEXT} ) {
 110             $c->log->error(
 111                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 112             );
 113         }
 114         else {
 115             $config->{CONTEXT} = Template::Timer->new(%$config);
 116         }
 117     }
 118
 119     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 120         $c->log->debug( "TT Config: ", dump($config) );
 121     }
 122     if ( $config->{PROVIDERS} ) {
 123         my @providers = ();
 124         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 125             foreach my $p (@{$config->{PROVIDERS}}) {
 126                 my $pname = $p->{name};
 127                 my $prov = 'Template::Provider';
 128                 if($pname eq '_file_')
 129                 {
 130                     $p->{args} = { %$config };
 131                 }
 132                 else
 133                 {
 134                     if($pname =~ s/^\+//) {
 135                         $prov = $pname;
 136                     }
 137                     else
 138                     {
 139                         $prov .= "::$pname";
 140                     }
 141                 }
 142                 eval "require $prov";
 143                 if(!$@) {
 144                     push @providers, "$prov"->new($p->{args});
 145                 }
 146                 else
 147                 {
 148                     $c->log->warn("Can't load $prov, ($@)");
 149                 }
 150             }
 151         }
 152         delete $config->{PROVIDERS};
 153         if(@providers) {
 154             $config->{LOAD_TEMPLATES} = \@providers;
 155         }
 156     }
 157
 158     my $self = $class->NEXT::new(
 159         $c, { %$config },
 160     );
 161
 162     # Set base include paths. Local'd in render if needed
 163     $self->include_path($config->{INCLUDE_PATH});
 164
 165     $self->config($config);
 166
 167     # Creation of template outside of call to new so that we can pass [ $self ]
 168     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 169     # of include paths to search for templates.
 170
 171     # Use a weakend copy of self so we dont have loops preventing GC from working
 172     my $copy = $self;
 173     Scalar::Util::weaken($copy);
 174     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 175
 176     $self->{template} =
 177         Template->new($config) || do {
 178             my $error = Template->error();
 179             $c->log->error($error);
 180             $c->error($error);
 181             return undef;
 182         };
 183
 184
 185     return $self;
 186 }
 187
 188 sub process {
 189     my ( $self, $c ) = @_;
 190
 191     my $template = $c->stash->{template}
 192       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 193
 194     unless (defined $template) {
 195         $c->log->debug('No template specified for rendering') if $c->debug;
 196         return 0;
 197     }
 198
 199     my $output = $self->render($c, $template);
 200
 201     if (UNIVERSAL::isa($output, 'Template::Exception')) {
 202         my $error = qq/Couldn't render template "$output"/;
 203         $c->log->error($error);
 204         $c->error($error);
 205         return 0;
 206     }
 207
 208     unless ( $c->response->content_type ) {
 209         $c->response->content_type('text/html; charset=utf-8');
 210     }
 211
 212     $c->response->body($output);
 213
 214     return 1;
 215 }
 216
 217 sub render {
 218     my ($self, $c, $template, $args) = @_;
 219
 220     $c->log->debug(qq/Rendering template "$template"/) if $c->debug;
 221
 222     my $output;
 223     my $vars = {
 224         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 225         $self->template_vars($c)
 226     };
 227
 228     local $self->{include_path} =
 229         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 230         if ref $vars->{additional_template_paths};
 231
 232     unless ($self->template->process( $template, $vars, \$output ) ) {
 233         return $self->template->error;
 234     } else {
 235         return $output;
 236     }
 237 }
 238
 239 sub template_vars {
 240     my ( $self, $c ) = @_;
 241
 242     my $cvar = $self->config->{CATALYST_VAR};
 243
 244     defined $cvar
 245       ? ( $cvar => $c )
 246       : (
 247         c    => $c,
 248         base => $c->req->base,
 249         name => $c->config->{name}
 250       )
 251 }
 252
 253
 254 1;
 255
 256 __END__
 257
 258 =head1 DESCRIPTION
 259
 260 This is the Catalyst view class for the L<Template Toolkit|Template>.
 261 Your application should defined a view class which is a subclass of
 262 this module.  The easiest way to achieve this is using the
 263 F<myapp_create.pl> script (where F<myapp> should be replaced with
 264 whatever your application is called).  This script is created as part
 265 of the Catalyst setup.
 266
 267     $ script/myapp_create.pl view TT TT
 268
 269 This creates a MyApp::V::TT.pm module in the F<lib> directory (again,
 270 replacing C<MyApp> with the name of your application) which looks
 271 something like this:
 272
 273     package FooBar::V::TT;
 274
 275     use strict;
 276      use base 'Catalyst::View::TT';
 277
 278     __PACKAGE__->config->{DEBUG} = 'all';
 279
 280 Now you can modify your action handlers in the main application and/or
 281 controllers to forward to your view class.  You might choose to do this
 282 in the end() method, for example, to automatically forward all actions
 283 to the TT view class.
 284
 285     # In MyApp or MyApp::Controller::SomeController
 286
 287     sub end : Private {
 288         my( $self, $c ) = @_;
 289         $c->forward('MyApp::V::TT');
 290     }
 291
 292 =head2 CONFIGURATION
 293
 294 There are a three different ways to configure your view class.  The
 295 first way is to call the C<config()> method in the view subclass.  This
 296 happens when the module is first loaded.
 297
 298     package MyApp::V::TT;
 299
 300     use strict;
 301     use base 'Catalyst::View::TT';
 302
 303     MyApp::V::TT->config({
 304         INCLUDE_PATH => [
 305             MyApp->path_to( 'root', 'templates', 'lib' ),
 306             MyApp->path_to( 'root', 'templates', 'src' ),
 307         ],
 308         PRE_PROCESS  => 'config/main',
 309         WRAPPER      => 'site/wrapper',
 310     });
 311
 312 The second way is to define a C<new()> method in your view subclass.
 313 This performs the configuration when the view object is created,
 314 shortly after being loaded.  Remember to delegate to the base class
 315 C<new()> method (via C<$self-E<gt>NEXT::new()> in the example below) after
 316 performing any configuration.
 317
 318     sub new {
 319         my $self = shift;
 320         $self->config({
 321             INCLUDE_PATH => [
 322                 MyApp->path_to( 'root', 'templates', 'lib' ),
 323                 MyApp->path_to( 'root', 'templates', 'src' ),
 324             ],
 325             PRE_PROCESS  => 'config/main',
 326             WRAPPER      => 'site/wrapper',
 327         });
 328         return $self->NEXT::new(@_);
 329     }
 330
 331 The final, and perhaps most direct way, is to define a class
 332 item in your main application configuration, again by calling the
 333 uniquitous C<config()> method.  The items in the class hash are
 334 added to those already defined by the above two methods.  This happens
 335 in the base class new() method (which is one reason why you must
 336 remember to call it via C<NEXT> if you redefine the C<new()> method in a
 337 subclass).
 338
 339     package MyApp;
 340
 341     use strict;
 342     use Catalyst;
 343
 344     MyApp->config({
 345         name     => 'MyApp',
 346         root     => MyApp->path_to('root'),
 347         'V::TT' => {
 348             INCLUDE_PATH => [
 349                 MyApp->path_to( 'root', 'templates', 'lib' ),
 350                 MyApp->path_to( 'root', 'templates', 'src' ),
 351             ],
 352             PRE_PROCESS  => 'config/main',
 353             WRAPPER      => 'site/wrapper',
 354         },
 355     });
 356
 357 Note that any configuration items defined by one of the earlier
 358 methods will be overwritten by items of the same name provided by the
 359 latter methods.
 360
 361 =head2 DYNAMIC INCLUDE_PATH
 362
 363 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 364
 365 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 366 follows:
 367
 368     $c->stash->{additional_template_paths} =
 369         [$c->config->{root} . '/test_include_path'];
 370
 371 If you need to add paths to the end of INCLUDE_PATH, there is also an
 372 include_path() accessor available:
 373
 374     push( @{ $c->view('TT')->include_path }, qw/path/ );
 375
 376 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 377 MUST check for duplicate paths. Without such checking, the above code will add
 378 "path" to INCLUDE_PATH at every request, causing a memory leak.
 379
 380 A safer approach is to use include_path() to overwrite the array of paths
 381 rather than adding to it. This eliminates both the need to perform duplicate
 382 checking and the chance of a memory leak:
 383
 384     @{ $c->view('TT')->include_path } = qw/path another_path/;
 385
 386 If you are calling C<render> directly then you can specify dynamic paths by
 387 having a C<additional_template_paths> key with a value of additonal directories
 388 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 389
 390 =head2 RENDERING VIEWS
 391
 392 The view plugin renders the template specified in the C<template>
 393 item in the stash.
 394
 395     sub message : Global {
 396         my ( $self, $c ) = @_;
 397         $c->stash->{template} = 'message.tt2';
 398         $c->forward('MyApp::V::TT');
 399     }
 400
 401 If a stash item isn't defined, then it instead uses the
 402 stringification of the action dispatched to (as defined by $c->action)
 403 in the above example, this would be C<message>, but because the default
 404 is to append '.tt', it would load C<root/message.tt>.
 405
 406 The items defined in the stash are passed to the Template Toolkit for
 407 use as template variables.
 408
 409     sub default : Private {
 410         my ( $self, $c ) = @_;
 411         $c->stash->{template} = 'message.tt2';
 412         $c->stash->{message}  = 'Hello World!';
 413         $c->forward('MyApp::V::TT');
 414     }
 415
 416 A number of other template variables are also added:
 417
 418     c      A reference to the context object, $c
 419     base   The URL base, from $c->req->base()
 420     name   The application name, from $c->config->{ name }
 421
 422 These can be accessed from the template in the usual way:
 423
 424 <message.tt2>:
 425
 426     The message is: [% message %]
 427     The base is [% base %]
 428     The name is [% name %]
 429
 430
 431 The output generated by the template is stored in C<< $c->response->body >>.
 432
 433 =head2 CAPTURING TEMPLATE OUTPUT
 434
 435 If you wish to use the output of a template for some other purpose than
 436 displaying in the response, e.g. for sending an email, this is possible using
 437 L<Catalyst::Plugin::Email> and the L<render> method:
 438
 439   sub send_email : Local {
 440     my ($self, $c) = @_;
 441
 442     $c->email(
 443       header => [
 444         To      => 'me@localhost',
 445         Subject => 'A TT Email',
 446       ],
 447       body => $c->view('TT')->render($c, 'email.tt', {
 448         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 449         email_tmpl_param1 => 'foo'
 450         }
 451       ),
 452     );
 453   # Redirect or display a message
 454   }
 455
 456 =head2 TEMPLATE PROFILING
 457
 458 See L<C<TIMER>> property of the L<config> method.
 459
 460 =head2 METHODS
 461
 462 =head2 new
 463
 464 The constructor for the TT view. Sets up the template provider,
 465 and reads the application config.
 466
 467 =head2 process
 468
 469 Renders the template specified in C<< $c->stash->{template} >> or
 470 C<< $c->action >> (the private name of the matched action.  Calls L<render> to
 471 perform actual rendering. Output is stored in C<< $c->response->body >>.
 472
 473 =head2 render($c, $template, \%args)
 474
 475 Renders the given template and returns output, or a L<Template::Exception>
 476 object upon error.
 477
 478 The template variables are set to C<%$args> if $args is a hashref, or
 479 $C<< $c->stash >> otherwise. In either case the variables are augmented with
 480 C<base> set to C< << $c->req->base >>, C<c> to C<$c> and C<name> to
 481 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 482 can be defined to specify the name of a template variable through which the
 483 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base> and
 484 C<name> variables are omitted.
 485
 486 C<$template> can be anything that Template::process understands how to
 487 process, including the name of a template file or a reference to a test string.
 488 See L<Template::process|Template/process> for a full list of supported formats.
 489
 490 =head2 template_vars
 491
 492 Returns a list of keys/values to be used as the catalyst variables in the
 493 template.
 494
 495 =head2 config
 496
 497 This method allows your view subclass to pass additional settings to
 498 the TT configuration hash, or to set the options as below:
 499
 500 =head2 paths
 501
 502 The list of paths TT will look for templates in.
 503
 504 =head2 C<CATALYST_VAR>
 505
 506 Allows you to change the name of the Catalyst context object. If set, it will also
 507 remove the base and name aliases, so you will have access them through <context>.
 508
 509 For example:
 510
 511     MyApp->config({
 512         name     => 'MyApp',
 513         root     => MyApp->path_to('root'),
 514         'V::TT' => {
 515             CATALYST_VAR => 'Catalyst',
 516         },
 517     });
 518
 519 F<message.tt2>:
 520
 521     The base is [% Catalyst.req.base %]
 522     The name is [% Catalyst.config.name %]
 523
 524 =head2 C<TIMER>
 525
 526 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 527 C<Catalyst::View::TT> will enable profiling of template processing
 528 (using L<Template::Timer>). This will embed HTML comments in the
 529 output from your templates, such as:
 530
 531     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 532     <!-- TIMER START: include mainmenu/cssindex.tt -->
 533     <!-- TIMER START: process mainmenu/cssindex.tt -->
 534     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 535     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 536
 537     ....
 538
 539     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 540
 541
 542 =head2 C<TEMPLATE_EXTENSION>
 543
 544 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 545
 546 For example:
 547
 548   package MyApp::C::Test;
 549   sub test : Local { .. }
 550
 551 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 552 <root>/test/test.tt.
 553
 554 =head2 C<PROVIDERS>
 555
 556 Allows you to specify the template providers that TT will use.
 557
 558     MyApp->config({
 559         name     => 'MyApp',
 560         root     => MyApp->path_to('root'),
 561         'V::TT' => {
 562             PROVIDERS => [
 563                 {
 564                     name    => 'DBI',
 565                     args    => {
 566                         DBI_DSN => 'dbi:DB2:books',
 567                         DBI_USER=> 'foo'
 568                     }
 569                 }, {
 570                     name    => '_file_',
 571                     args    => {}
 572                 }
 573             ]
 574         },
 575     });
 576
 577 The 'name' key should correspond to the class name of the provider you
 578 want to use.  The _file_ name is a special case that represents the default
 579 TT file-based provider.  By default the name is will be prefixed with
 580 'Template::Provider::'.  You can fully qualify the name by using a unary
 581 plus:
 582
 583     name => '+MyApp::Provider::Foo'
 584
 585 =head2 HELPERS
 586
 587 The L<Catalyst::Helper::View::TT> and
 588 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 589 your view module.  There are invoked by the F<myapp_create.pl> script:
 590
 591     $ script/myapp_create.pl view TT TT
 592
 593     $ script/myapp_create.pl view TT TTSite
 594
 595 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 596 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 597 further.  It also creates a default set of templates to get you
 598 started.  It also configures the view module to locate the templates
 599 automatically.
 600
 601 =head1 SEE ALSO
 602
 603 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 604 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 605
 606 =head1 AUTHORS
 607
 608 Sebastian Riedel, C<sri@cpan.org>
 609
 610 Marcus Ramberg, C<mramberg@cpan.org>
 611
 612 Jesse Sheidlower, C<jester@panix.com>
 613
 614 Andy Wardley, C<abw@cpan.org>
 615
 616 =head1 COPYRIGHT
 617
 618 This program is free software, you can redistribute it and/or modify it
 619 under the same terms as Perl itself.
 620
 621 =cut