lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use base qw/Catalyst::View/;
   5 use Template;
   6 use Template::Timer;
   7 use NEXT;
   8
   9 our $VERSION = '0.20';
  10
  11 __PACKAGE__->mk_accessors('template');
  12 __PACKAGE__->mk_accessors('include_path');
  13
  14 =head1 NAME
  15
  16 Catalyst::View::TT - Template View Class
  17
  18 =head1 SYNOPSIS
  19
  20 # use the helper to create View
  21     myapp_create.pl view TT TT
  22
  23 # configure in lib/MyApp.pm
  24
  25     MyApp->config({
  26         name     => 'MyApp',
  27         root     => MyApp->path_to('root');,
  28         'V::TT' => {
  29             # any TT configurations items go here
  30             INCLUDE_PATH => [
  31               MyApp->path_to( 'root', 'src' ),
  32               MyApp->path_to( 'root', 'lib' ),
  33             ],
  34             PRE_PROCESS        => 'config/main',
  35             WRAPPER            => 'site/wrapper',
  36             TEMPLATE_EXTENSION => '.tt',
  37
  38             # two optional config items
  39             CATALYST_VAR => 'Catalyst',
  40             TIMER        => 1,
  41         },
  42     });
  43
  44 # render view from lib/MyApp.pm or lib/MyApp::C::SomeController.pm
  45
  46     sub message : Global {
  47         my ( $self, $c ) = @_;
  48         $c->stash->{template} = 'message.tt2';
  49         $c->stash->{message}  = 'Hello World!';
  50         $c->forward('MyApp::V::TT');
  51     }
  52
  53 # access variables from template
  54
  55     The message is: [% message %].
  56
  57     # example when CATALYST_VAR is set to 'Catalyst'
  58     Context is [% Catalyst %]
  59     The base is [% Catalyst.req.base %]
  60     The name is [% Catalyst.config.name %]
  61
  62     # example when CATALYST_VAR isn't set
  63     Context is [% c %]
  64     The base is [% base %]
  65     The name is [% name %]
  66
  67 =head1 DESCRIPTION
  68
  69 This is the Catalyst view class for the L<Template Toolkit|Template>.
  70 Your application should defined a view class which is a subclass of
  71 this module.  The easiest way to achieve this is using the
  72 F<myapp_create.pl> script (where F<myapp> should be replaced with
  73 whatever your application is called).  This script is created as part
  74 of the Catalyst setup.
  75
  76     $ script/myapp_create.pl view TT TT
  77
  78 This creates a MyApp::V::TT.pm module in the F<lib> directory (again,
  79 replacing C<MyApp> with the name of your application) which looks
  80 something like this:
  81
  82     package FooBar::V::TT;
  83
  84     use strict;
  85      use base 'Catalyst::View::TT';
  86
  87     __PACKAGE__->config->{DEBUG} = 'all';
  88
  89 Now you can modify your action handlers in the main application and/or
  90 controllers to forward to your view class.  You might choose to do this
  91 in the end() method, for example, to automatically forward all actions
  92 to the TT view class.
  93
  94     # In MyApp or MyApp::Controller::SomeController
  95
  96     sub end : Private {
  97         my( $self, $c ) = @_;
  98         $c->forward('MyApp::V::TT');
  99     }
 100
 101 =head2 CONFIGURATION
 102
 103 There are a three different ways to configure your view class.  The
 104 first way is to call the C<config()> method in the view subclass.  This
 105 happens when the module is first loaded.
 106
 107     package MyApp::V::TT;
 108
 109     use strict;
 110     use base 'Catalyst::View::TT';
 111
 112     MyApp::V::TT->config({
 113         INCLUDE_PATH => [
 114             MyApp->path_to( 'root', 'templates', 'lib' ),
 115             MyApp->path_to( 'root', 'templates', 'src' ),
 116         ],
 117         PRE_PROCESS  => 'config/main',
 118         WRAPPER      => 'site/wrapper',
 119     });
 120
 121 The second way is to define a C<new()> method in your view subclass.
 122 This performs the configuration when the view object is created,
 123 shortly after being loaded.  Remember to delegate to the base class
 124 C<new()> method (via C<$self-E<gt>NEXT::new()> in the example below) after
 125 performing any configuration.
 126
 127     sub new {
 128         my $self = shift;
 129         $self->config({
 130             INCLUDE_PATH => [
 131                 MyApp->path_to( 'root', 'templates', 'lib' ),
 132                 MyApp->path_to( 'root', 'templates', 'src' ),
 133             ],
 134             PRE_PROCESS  => 'config/main',
 135             WRAPPER      => 'site/wrapper',
 136         });
 137         return $self->NEXT::new(@_);
 138     }
 139
 140 The final, and perhaps most direct way, is to define a class
 141 item in your main application configuration, again by calling the
 142 uniquitous C<config()> method.  The items in the class hash are
 143 added to those already defined by the above two methods.  This happens
 144 in the base class new() method (which is one reason why you must
 145 remember to call it via C<NEXT> if you redefine the C<new()> method in a
 146 subclass).
 147
 148     package MyApp;
 149
 150     use strict;
 151     use Catalyst;
 152
 153     MyApp->config({
 154         name     => 'MyApp',
 155         root     => MyApp->path_to('root'),
 156         'V::TT' => {
 157             INCLUDE_PATH => [
 158                 MyApp->path_to( 'root', 'templates', 'lib' ),
 159                 MyApp->path_to( 'root', 'templates', 'src' ),
 160             ],
 161             PRE_PROCESS  => 'config/main',
 162             WRAPPER      => 'site/wrapper',
 163         },
 164     });
 165
 166 Note that any configuration items defined by one of the earlier
 167 methods will be overwritten by items of the same name provided by the
 168 latter methods.
 169
 170 =head2 DYNAMIC INCLUDE_PATH
 171
 172 It is sometimes needed to dynamically add additional paths to the
 173 INCLUDE_PATH variable of the template object. This can be done by setting
 174 'additional_include_paths' on stash to a referrence to an array with
 175 additional paths:
 176
 177     $c->stash->{additional_template_paths} = [$c->config->{root} . '/test_include_path'];
 178
 179 =head2 RENDERING VIEWS
 180
 181 The view plugin renders the template specified in the C<template>
 182 item in the stash.
 183
 184     sub message : Global {
 185         my ( $self, $c ) = @_;
 186         $c->stash->{template} = 'message.tt2';
 187         $c->forward('MyApp::V::TT');
 188     }
 189
 190 If a class item isn't defined, then it instead uses the
 191 current match, as returned by C<$c-E<gt>match>.  In the above
 192 example, this would be C<message>.
 193
 194 The items defined in the stash are passed to the Template Toolkit for
 195 use as template variables.
 196
 197 sub message : Global {
 198     sub default : Private {
 199         my ( $self, $c ) = @_;
 200         $c->stash->{template} = 'message.tt2';
 201         $c->stash->{message}  = 'Hello World!';
 202         $c->forward('MyApp::V::TT');
 203     }
 204
 205 A number of other template variables are also added:
 206
 207     c      A reference to the context object, $c
 208     base   The URL base, from $c->req->base()
 209     name   The application name, from $c->config->{ name }
 210
 211 These can be accessed from the template in the usual way:
 212
 213 <message.tt2>:
 214
 215     The message is: [% message %]
 216     The base is [% base %]
 217     The name is [% name %]
 218
 219
 220 The output generated by the template is stored in
 221 C<$c-E<gt>response-E<gt>output>.
 222
 223 =head2 TEMPLATE PROFILING
 224
 225 =head2 METHODS
 226
 227 =over 4
 228
 229 =item new
 230
 231 The constructor for the TT view. Sets up the template provider,
 232 and reads the application config.
 233
 234 =cut
 235
 236 sub _coerce_paths {
 237     my ( $paths, $dlim ) = shift;
 238     return () if ( ! $paths );
 239     return @{$paths} if ( ref $paths eq 'ARRAY');
 240             # tweak delim to ignore C:/
 241             unless (defined $dlim) {
 242                 $dlim = ($^O eq 'MSWin32') ? ':(?!\\/)' : ':';
 243             }
 244             return split(/$dlim/, $paths);
 245 }
 246
 247
 248 sub new {
 249     my ( $class, $c, $arguments ) = @_;
 250     my $delim = $class->config->{DELIMITER} || $arguments->{DELIMITER};
 251     my $include_path;
 252     if(ref $arguments->{INCLUDE_PATH} eq 'ARRAY'){
 253         $include_path = $arguments->{INCLUDE_PATH};
 254     }elsif(ref $class->config->{INCLUDE_PATH} eq 'ARRAY'){
 255         $include_path = $class->config->{INCLUDE_PATH};
 256     }else{
 257         my @include_path = _coerce_paths($arguments->{INCLUDE_PATH}, $delim);
 258         if(!@include_path){
 259             @include_path = _coerce_paths($class->config->{INCLUDE_PATH}, $delim);
 260         }
 261         if(!@include_path){
 262             my $root = $c->config->{root};
 263             my $base = Path::Class::dir($root, 'base');
 264             @include_path = ( "$root", "$base" );
 265         }
 266         $include_path = \@include_path;
 267     }
 268     my $config = {
 269         EVAL_PERL          => 0,
 270         TEMPLATE_EXTENSION => '',
 271         %{ $class->config },
 272         %{$arguments},
 273         INCLUDE_PATH => $include_path,
 274     };
 275
 276     # if we're debugging and/or the TIMER option is set, then we install
 277     # Template::Timer as a custom CONTEXT object, but only if we haven't
 278     # already got a custom CONTEXT defined
 279
 280     if ( $config->{TIMER} ) {
 281         if ( $config->{CONTEXT} ) {
 282             $c->log->error(
 283                 'Cannot use Template::Timer - a TT CONFIG is already defined');
 284         }
 285         else {
 286             $config->{CONTEXT} = Template::Timer->new(%$config);
 287         }
 288     }
 289
 290     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 291         use Data::Dumper;
 292         $c->log->debug( "TT Config: ", Dumper($config) );
 293     }
 294
 295     my $self = $class->NEXT::new(
 296         $c,
 297         {
 298             template => Template->new($config) || do {
 299                 my $error = Template->error();
 300                 $c->log->error($error);
 301                 $c->error($error);
 302                 return undef;
 303               },
 304         %{$config},
 305         },
 306     );
 307     $self->include_path($include_path);
 308     $self->config($config);
 309
 310     return $self;
 311 }
 312
 313 =item process
 314
 315 Renders the template specified in C<$c-E<gt>stash-E<gt>{template}> or
 316 C<$c-E<gt>request-E<gt>match>. Template variables are set up from the
 317 contents of C<$c-E<gt>stash>, augmented with C<base> set to
 318 C<$c-E<gt>req-E<gt>base>, C<c> to C<$c> and C<name> to
 319 C<$c-E<gt>config-E<gt>{name}>. Alternately, the C<CATALYST_VAR>
 320 configuration item can be defined to specify the name of a template
 321 variable through which the context reference (C<$c>) can be accessed.
 322 In this case, the C<c>, C<base> and C<name> variables are omitted.
 323 Output is stored in C<$c-E<gt>response-E<gt>output>.
 324
 325 =cut
 326
 327 sub process {
 328     my ( $self, $c ) = @_;
 329
 330     my $template = $c->stash->{template}
 331       || ( $c->request->match || $c->request->action ) .
 332            $self->config->{TEMPLATE_EXTENSION};
 333
 334     unless ($template) {
 335         $c->log->debug('No template specified for rendering') if $c->debug;
 336         return 0;
 337     }
 338
 339     $c->log->debug(qq/Rendering template "$template"/) if $c->debug;
 340
 341     my $output;
 342     my $cvar = $self->config->{CATALYST_VAR};
 343     my $vars = {
 344         defined $cvar
 345         ? ( $cvar => $c )
 346         : (
 347             c    => $c,
 348             base => $c->req->base,
 349             name => $c->config->{name}
 350         ),
 351         %{ $c->stash() }
 352     };
 353     unshift @{$self->include_path}, @{$c->stash->{additional_template_paths}} if ref $c->stash->{additional_template_paths};
 354     unless ( $self->template->process( $template, $vars, \$output ) ) {
 355         my $error = $self->template->error;
 356         $error = qq/Couldn't render template "$error"/;
 357         $c->log->error($error);
 358         $c->error($error);
 359         return 0;
 360     }
 361     splice @{$self->include_path}, 0, scalar @{$c->stash->{additional_template_paths}} if ref $c->stash->{additional_template_paths};
 362
 363     unless ( $c->response->content_type ) {
 364         $c->response->content_type('text/html; charset=utf-8');
 365     }
 366
 367     $c->response->body($output);
 368
 369     return 1;
 370 }
 371
 372 =item config
 373
 374 This method allows your view subclass to pass additional settings to
 375 the TT configuration hash, or to set the options as below:
 376
 377 =over 2
 378
 379 =item C<CATALYST_VAR>
 380
 381 Allows you to change the name of the Catalyst context object. If set, it will also
 382 remove the base and name aliases, so you will have access them through <context>.
 383
 384 For example:
 385
 386     MyApp->config({
 387         name     => 'MyApp',
 388         root     => MyApp->path_to('root'),
 389         'V::TT' => {
 390             CATALYST_VAR => 'Catalyst',
 391         },
 392     });
 393
 394 F<message.tt2>:
 395
 396     The base is [% Catalyst.req.base %]
 397     The name is [% Catalyst.config.name %]
 398
 399 =item C<TIMER>
 400
 401 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 402 C<Catalyst::View::TT> will enable profiling of template processing
 403 (using L<Template::Timer>). This will embed HTML comments in the
 404 output from your templates, such as:
 405
 406     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 407     <!-- TIMER START: include mainmenu/cssindex.tt -->
 408     <!-- TIMER START: process mainmenu/cssindex.tt -->
 409     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 410     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 411
 412     ....
 413
 414     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 415
 416
 417 =item C<TEMPLATE_EXTENSION>
 418
 419 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 420
 421 For example:
 422
 423   package MyApp::C::Test;
 424   sub test : Local { .. }
 425
 426 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 427 <root>/test/test.tt.
 428
 429 =back
 430
 431 =back
 432
 433 =head2 HELPERS
 434
 435 The L<Catalyst::Helper::View::TT> and
 436 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 437 your view module.  There are invoked by the F<myapp_create.pl> script:
 438
 439     $ script/myapp_create.pl view TT TT
 440
 441     $ script/myapp_create.pl view TT TTSite
 442
 443 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 444 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 445 further.  It also creates a default set of templates to get you
 446 started.  It also configures the view module to locate the templates
 447 automatically.
 448
 449 =head1 SEE ALSO
 450
 451 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 452 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 453
 454 =head1 AUTHORS
 455
 456 Sebastian Riedel, C<sri@cpan.org>
 457
 458 Marcus Ramberg, C<mramberg@cpan.org>
 459
 460 Jesse Sheidlower, C<jester@panix.com>
 461
 462 Andy Wardley, C<abw@cpan.org>
 463
 464 =head1 COPYRIGHT
 465
 466 This program is free software, you can redistribute it and/or modify it
 467 under the same terms as Perl itself.
 468
 469 =cut
 470
 471 1;