lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11
  12 our $VERSION = '0.31';
  13
  14 __PACKAGE__->mk_accessors('template');
  15 __PACKAGE__->mk_accessors('include_path');
  16
  17 *paths = \&include_path;
  18
  19 =head1 NAME
  20
  21 Catalyst::View::TT - Template View Class
  22
  23 =head1 SYNOPSIS
  24
  25 # use the helper to create your View
  26
  27     myapp_create.pl view TT TT
  28
  29 # configure in lib/MyApp.pm (Could be set from configfile instead)
  30
  31     MyApp->config(
  32         name     => 'MyApp',
  33         root     => MyApp->path_to('root'),
  34         'View::TT' => {
  35             # any TT configurations items go here
  36             INCLUDE_PATH => [
  37               MyApp->path_to( 'root', 'src' ),
  38               MyApp->path_to( 'root', 'lib' ),
  39             ],
  40             TEMPLATE_EXTENSION => '.tt',
  41             CATALYST_VAR => 'c',
  42             TIMER        => 0,
  43             # Not set by default
  44             PRE_PROCESS        => 'config/main',
  45             WRAPPER            => 'site/wrapper',
  46         },
  47     );
  48
  49 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  50
  51     sub message : Global {
  52         my ( $self, $c ) = @_;
  53         $c->stash->{template} = 'message.tt2';
  54         $c->stash->{message}  = 'Hello World!';
  55         $c->forward( $c->view('TT') );
  56     }
  57
  58 # access variables from template
  59
  60     The message is: [% message %].
  61
  62     # example when CATALYST_VAR is set to 'Catalyst'
  63     Context is [% Catalyst %]
  64     The base is [% Catalyst.req.base %]
  65     The name is [% Catalyst.config.name %]
  66
  67     # example when CATALYST_VAR isn't set
  68     Context is [% c %]
  69     The base is [% base %]
  70     The name is [% name %]
  71
  72 =cut
  73
  74 sub _coerce_paths {
  75     my ( $paths, $dlim ) = shift;
  76     return () if ( !$paths );
  77     return @{$paths} if ( ref $paths eq 'ARRAY' );
  78
  79     # tweak delim to ignore C:/
  80     unless ( defined $dlim ) {
  81         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  82     }
  83     return split( /$dlim/, $paths );
  84 }
  85
  86 sub new {
  87     my ( $class, $c, $arguments ) = @_;
  88     my $config = {
  89         EVAL_PERL          => 0,
  90         TEMPLATE_EXTENSION => '',
  91         %{ $class->config },
  92         %{$arguments},
  93     };
  94     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  95         my $delim = $config->{DELIMITER};
  96         my @include_path
  97             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  98         if ( !@include_path ) {
  99             my $root = $c->config->{root};
 100             my $base = Path::Class::dir( $root, 'base' );
 101             @include_path = ( "$root", "$base" );
 102         }
 103         $config->{INCLUDE_PATH} = \@include_path;
 104     }
 105
 106     # if we're debugging and/or the TIMER option is set, then we install
 107     # Template::Timer as a custom CONTEXT object, but only if we haven't
 108     # already got a custom CONTEXT defined
 109
 110     if ( $config->{TIMER} ) {
 111         if ( $config->{CONTEXT} ) {
 112             $c->log->error(
 113                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 114             );
 115         }
 116         else {
 117             $config->{CONTEXT} = Template::Timer->new(%$config);
 118         }
 119     }
 120
 121     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 122         $c->log->debug( "TT Config: ", dump($config) );
 123     }
 124
 125     my $self = $class->next::method(
 126         $c, { %$config },
 127     );
 128
 129     # Set base include paths. Local'd in render if needed
 130     $self->include_path($config->{INCLUDE_PATH});
 131
 132     $self->config($config);
 133
 134     # Creation of template outside of call to new so that we can pass [ $self ]
 135     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 136     # of include paths to search for templates.
 137
 138     # Use a weakend copy of self so we dont have loops preventing GC from working
 139     my $copy = $self;
 140     Scalar::Util::weaken($copy);
 141     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 142
 143     if ( $config->{PROVIDERS} ) {
 144         my @providers = ();
 145         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 146             foreach my $p (@{$config->{PROVIDERS}}) {
 147                 my $pname = $p->{name};
 148                 my $prov = 'Template::Provider';
 149                 if($pname eq '_file_')
 150                 {
 151                     $p->{args} = { %$config };
 152                 }
 153                 else
 154                 {
 155                     if($pname =~ s/^\+//) {
 156                         $prov = $pname;
 157                     }
 158                     else
 159                     {
 160                         $prov .= "::$pname";
 161                     }
 162                     # We copy the args people want from the config
 163                     # to the args
 164                     $p->{args} ||= {};
 165                     if ($p->{copy_config}) {
 166                         map  { $p->{args}->{$_} = $config->{$_}  }
 167                                    grep { exists $config->{$_} }
 168                                    @{ $p->{copy_config} };
 169                     }
 170                 }
 171                 eval "require $prov";
 172                 if(!$@) {
 173                     push @providers, "$prov"->new($p->{args});
 174                 }
 175                 else
 176                 {
 177                     $c->log->warn("Can't load $prov, ($@)");
 178                 }
 179             }
 180         }
 181         delete $config->{PROVIDERS};
 182         if(@providers) {
 183             $config->{LOAD_TEMPLATES} = \@providers;
 184         }
 185     }
 186
 187     $self->{template} =
 188         Template->new($config) || do {
 189             my $error = Template->error();
 190             $c->log->error($error);
 191             $c->error($error);
 192             return undef;
 193         };
 194
 195
 196     return $self;
 197 }
 198
 199 sub process {
 200     my ( $self, $c ) = @_;
 201
 202     my $template = $c->stash->{template}
 203       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 204
 205     unless (defined $template) {
 206         $c->log->debug('No template specified for rendering') if $c->debug;
 207         return 0;
 208     }
 209
 210     my $output = eval { $self->render($c, $template) };
 211     if (my $err = $@) {
 212         my $error = qq/Couldn't render template "$template"/;
 213         $c->log->error($error);
 214         $c->error($error);
 215         return 0;
 216     }
 217
 218     unless ( $c->response->content_type ) {
 219         $c->response->content_type('text/html; charset=utf-8');
 220     }
 221
 222     $c->response->body($output);
 223
 224     return 1;
 225 }
 226
 227 sub render {
 228     my ($self, $c, $template, $args) = @_;
 229
 230     $c->log->debug(qq/Rendering template "$template"/) if $c && $c->debug;
 231
 232     my $output;
 233     my $vars = {
 234         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 235         $self->template_vars($c)
 236     };
 237
 238     local $self->{include_path} =
 239         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 240         if ref $vars->{additional_template_paths};
 241
 242     $self->template->process( $template, $vars, \$output )
 243         or die $self->template->error;
 244     return $output;
 245 }
 246
 247 sub template_vars {
 248     my ( $self, $c ) = @_;
 249
 250     return  () unless $c;
 251     my $cvar = $self->config->{CATALYST_VAR};
 252
 253     defined $cvar
 254       ? ( $cvar => $c )
 255       : (
 256         c    => $c,
 257         base => $c->req->base,
 258         name => $c->config->{name}
 259       )
 260 }
 261
 262
 263 1;
 264
 265 __END__
 266
 267 =head1 DESCRIPTION
 268
 269 This is the Catalyst view class for the L<Template Toolkit|Template>.
 270 Your application should defined a view class which is a subclass of
 271 this module.  The easiest way to achieve this is using the
 272 F<myapp_create.pl> script (where F<myapp> should be replaced with
 273 whatever your application is called).  This script is created as part
 274 of the Catalyst setup.
 275
 276     $ script/myapp_create.pl view TT TT
 277
 278 This creates a MyApp::View::TT.pm module in the F<lib> directory (again,
 279 replacing C<MyApp> with the name of your application) which looks
 280 something like this:
 281
 282     package FooBar::View::TT;
 283
 284     use strict;
 285     use warnings;
 286
 287     use base 'Catalyst::View::TT';
 288
 289     __PACKAGE__->config->{DEBUG} = 'all';
 290
 291 Now you can modify your action handlers in the main application and/or
 292 controllers to forward to your view class.  You might choose to do this
 293 in the end() method, for example, to automatically forward all actions
 294 to the TT view class.
 295
 296     # In MyApp or MyApp::Controller::SomeController
 297
 298     sub end : Private {
 299         my( $self, $c ) = @_;
 300         $c->forward( $c->view('TT') );
 301     }
 302
 303 =head2 CONFIGURATION
 304
 305 There are a three different ways to configure your view class.  The
 306 first way is to call the C<config()> method in the view subclass.  This
 307 happens when the module is first loaded.
 308
 309     package MyApp::View::TT;
 310
 311     use strict;
 312     use base 'Catalyst::View::TT';
 313
 314     MyApp::View::TT->config({
 315         INCLUDE_PATH => [
 316             MyApp->path_to( 'root', 'templates', 'lib' ),
 317             MyApp->path_to( 'root', 'templates', 'src' ),
 318         ],
 319         PRE_PROCESS  => 'config/main',
 320         WRAPPER      => 'site/wrapper',
 321     });
 322
 323 The second way is to define a C<new()> method in your view subclass.
 324 This performs the configuration when the view object is created,
 325 shortly after being loaded.  Remember to delegate to the base class
 326 C<new()> method (via C<$self-E<gt>next::method()> in the example below) after
 327 performing any configuration.
 328
 329     sub new {
 330         my $self = shift;
 331         $self->config({
 332             INCLUDE_PATH => [
 333                 MyApp->path_to( 'root', 'templates', 'lib' ),
 334                 MyApp->path_to( 'root', 'templates', 'src' ),
 335             ],
 336             PRE_PROCESS  => 'config/main',
 337             WRAPPER      => 'site/wrapper',
 338         });
 339         return $self->next::method(@_);
 340     }
 341
 342 The final, and perhaps most direct way, is to define a class
 343 item in your main application configuration, again by calling the
 344 ubiquitous C<config()> method.  The items in the class hash are
 345 added to those already defined by the above two methods.  This happens
 346 in the base class new() method (which is one reason why you must
 347 remember to call it via C<MRO::Compat> if you redefine the C<new()>
 348 method in a subclass).
 349
 350     package MyApp;
 351
 352     use strict;
 353     use Catalyst;
 354
 355     MyApp->config({
 356         name     => 'MyApp',
 357         root     => MyApp->path_to('root'),
 358         'View::TT' => {
 359             INCLUDE_PATH => [
 360                 MyApp->path_to( 'root', 'templates', 'lib' ),
 361                 MyApp->path_to( 'root', 'templates', 'src' ),
 362             ],
 363             PRE_PROCESS  => 'config/main',
 364             WRAPPER      => 'site/wrapper',
 365         },
 366     });
 367
 368 Note that any configuration items defined by one of the earlier
 369 methods will be overwritten by items of the same name provided by the
 370 latter methods.
 371
 372 =head2 DYNAMIC INCLUDE_PATH
 373
 374 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 375
 376 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 377 follows:
 378
 379     $c->stash->{additional_template_paths} =
 380         [$c->config->{root} . '/test_include_path'];
 381
 382 If you need to add paths to the end of INCLUDE_PATH, there is also an
 383 include_path() accessor available:
 384
 385     push( @{ $c->view('TT')->include_path }, qw/path/ );
 386
 387 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 388 MUST check for duplicate paths. Without such checking, the above code will add
 389 "path" to INCLUDE_PATH at every request, causing a memory leak.
 390
 391 A safer approach is to use include_path() to overwrite the array of paths
 392 rather than adding to it. This eliminates both the need to perform duplicate
 393 checking and the chance of a memory leak:
 394
 395     @{ $c->view('TT')->include_path } = qw/path another_path/;
 396
 397 If you are calling C<render> directly then you can specify dynamic paths by
 398 having a C<additional_template_paths> key with a value of additonal directories
 399 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 400
 401 =head2 RENDERING VIEWS
 402
 403 The view plugin renders the template specified in the C<template>
 404 item in the stash.
 405
 406     sub message : Global {
 407         my ( $self, $c ) = @_;
 408         $c->stash->{template} = 'message.tt2';
 409         $c->forward( $c->view('TT') );
 410     }
 411
 412 If a stash item isn't defined, then it instead uses the
 413 stringification of the action dispatched to (as defined by $c->action)
 414 in the above example, this would be C<message>, but because the default
 415 is to append '.tt', it would load C<root/message.tt>.
 416
 417 The items defined in the stash are passed to the Template Toolkit for
 418 use as template variables.
 419
 420     sub default : Private {
 421         my ( $self, $c ) = @_;
 422         $c->stash->{template} = 'message.tt2';
 423         $c->stash->{message}  = 'Hello World!';
 424         $c->forward( $c->view('TT') );
 425     }
 426
 427 A number of other template variables are also added:
 428
 429     c      A reference to the context object, $c
 430     base   The URL base, from $c->req->base()
 431     name   The application name, from $c->config->{ name }
 432
 433 These can be accessed from the template in the usual way:
 434
 435 <message.tt2>:
 436
 437     The message is: [% message %]
 438     The base is [% base %]
 439     The name is [% name %]
 440
 441
 442 The output generated by the template is stored in C<< $c->response->body >>.
 443
 444 =head2 CAPTURING TEMPLATE OUTPUT
 445
 446 If you wish to use the output of a template for some other purpose than
 447 displaying in the response, e.g. for sending an email, this is possible using
 448 L<Catalyst::Plugin::Email> and the L<render> method:
 449
 450   sub send_email : Local {
 451     my ($self, $c) = @_;
 452
 453     $c->email(
 454       header => [
 455         To      => 'me@localhost',
 456         Subject => 'A TT Email',
 457       ],
 458       body => $c->view('TT')->render($c, 'email.tt', {
 459         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 460         email_tmpl_param1 => 'foo'
 461         }
 462       ),
 463     );
 464   # Redirect or display a message
 465   }
 466
 467 =head2 TEMPLATE PROFILING
 468
 469 See L<C<TIMER>> property of the L<config> method.
 470
 471 =head2 METHODS
 472
 473 =head2 new
 474
 475 The constructor for the TT view. Sets up the template provider,
 476 and reads the application config.
 477
 478 =head2 process($c)
 479
 480 Renders the template specified in C<< $c->stash->{template} >> or
 481 C<< $c->action >> (the private name of the matched action).  Calls L<render> to
 482 perform actual rendering. Output is stored in C<< $c->response->body >>.
 483
 484 It is possible to forward to the process method of a TT view from inside
 485 Catalyst like this:
 486
 487     $c->forward('View::TT');
 488
 489 N.B. This is usually done automatically by L<Catalyst::Action::RenderView>.
 490
 491 =head2 render($c, $template, \%args)
 492
 493 Renders the given template and returns output. Throws a L<Template::Exception>
 494 object upon error.
 495
 496 The template variables are set to C<%$args> if $args is a hashref, or
 497 $C<< $c->stash >> otherwise. In either case the variables are augmented with
 498 C<base> set to C< << $c->req->base >>, C<c> to C<$c> and C<name> to
 499 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 500 can be defined to specify the name of a template variable through which the
 501 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base> and
 502 C<name> variables are omitted.
 503
 504 C<$template> can be anything that Template::process understands how to
 505 process, including the name of a template file or a reference to a test string.
 506 See L<Template::process|Template/process> for a full list of supported formats.
 507
 508 To use the render method outside of your Catalyst app, just pass a undef context.
 509 This can be useful for tests, for instance.
 510
 511 It is possible to forward to the render method of a TT view from inside Catalyst
 512 to render page fragments like this:
 513
 514     my $fragment = $c->forward("View::TT", "render", $template_name, $c->stash->{fragment_data});
 515
 516 =head2 template_vars
 517
 518 Returns a list of keys/values to be used as the catalyst variables in the
 519 template.
 520
 521 =head2 config
 522
 523 This method allows your view subclass to pass additional settings to
 524 the TT configuration hash, or to set the options as below:
 525
 526 =head2 paths
 527
 528 The list of paths TT will look for templates in.
 529
 530 =head2 C<CATALYST_VAR>
 531
 532 Allows you to change the name of the Catalyst context object. If set, it will also
 533 remove the base and name aliases, so you will have access them through <context>.
 534
 535 For example:
 536
 537     MyApp->config({
 538         name     => 'MyApp',
 539         root     => MyApp->path_to('root'),
 540         'View::TT' => {
 541             CATALYST_VAR => 'Catalyst',
 542         },
 543     });
 544
 545 F<message.tt2>:
 546
 547     The base is [% Catalyst.req.base %]
 548     The name is [% Catalyst.config.name %]
 549
 550 =head2 C<TIMER>
 551
 552 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 553 C<Catalyst::View::TT> will enable profiling of template processing
 554 (using L<Template::Timer>). This will embed HTML comments in the
 555 output from your templates, such as:
 556
 557     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 558     <!-- TIMER START: include mainmenu/cssindex.tt -->
 559     <!-- TIMER START: process mainmenu/cssindex.tt -->
 560     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 561     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 562
 563     ....
 564
 565     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 566
 567
 568 =head2 C<TEMPLATE_EXTENSION>
 569
 570 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 571
 572 For example:
 573
 574   package MyApp::Controller::Test;
 575   sub test : Local { .. }
 576
 577 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 578 <root>/test/test.tt.
 579
 580 =head2 C<PROVIDERS>
 581
 582 Allows you to specify the template providers that TT will use.
 583
 584     MyApp->config({
 585         name     => 'MyApp',
 586         root     => MyApp->path_to('root'),
 587         'View::TT' => {
 588             PROVIDERS => [
 589                 {
 590                     name    => 'DBI',
 591                     args    => {
 592                         DBI_DSN => 'dbi:DB2:books',
 593                         DBI_USER=> 'foo'
 594                     }
 595                 }, {
 596                     name    => '_file_',
 597                     args    => {}
 598                 }
 599             ]
 600         },
 601     });
 602
 603 The 'name' key should correspond to the class name of the provider you
 604 want to use.  The _file_ name is a special case that represents the default
 605 TT file-based provider.  By default the name is will be prefixed with
 606 'Template::Provider::'.  You can fully qualify the name by using a unary
 607 plus:
 608
 609     name => '+MyApp::Provider::Foo'
 610
 611 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 612 from the general config, into the config for the provider:
 613
 614     DEFAULT_ENCODING    => 'utf-8',
 615     PROVIDERS => [
 616         {
 617             name    => 'Encoding',
 618             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 619         }
 620     ]
 621
 622 This can prove useful when you want to use the additional_template_paths hack
 623 in your own provider, or if you need to use Template::Provider::Encoding
 624
 625 =head2 HELPERS
 626
 627 The L<Catalyst::Helper::View::TT> and
 628 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 629 your view module.  There are invoked by the F<myapp_create.pl> script:
 630
 631     $ script/myapp_create.pl view TT TT
 632
 633     $ script/myapp_create.pl view TT TTSite
 634
 635 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 636 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 637 further.  It also creates a default set of templates to get you
 638 started.  It also configures the view module to locate the templates
 639 automatically.
 640
 641 =head1 NOTES
 642
 643 If you are using the L<CGI> module inside your templates, you will
 644 experience that the Catalyst server appears to hang while rendering
 645 the web page. This is due to the debug mode of L<CGI> (which is
 646 waiting for input in the terminal window). Turning off the
 647 debug mode using the "-no_debug" option solves the
 648 problem, eg.:
 649
 650     [% USE CGI('-no_debug') %]
 651
 652 =head1 SEE ALSO
 653
 654 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 655 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 656
 657 =head1 AUTHORS
 658
 659 Sebastian Riedel, C<sri@cpan.org>
 660
 661 Marcus Ramberg, C<mramberg@cpan.org>
 662
 663 Jesse Sheidlower, C<jester@panix.com>
 664
 665 Andy Wardley, C<abw@cpan.org>
 666
 667 =head1 COPYRIGHT
 668
 669 This program is free software. You can redistribute it and/or modify it
 670 under the same terms as Perl itself.
 671
 672 =cut