lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11 use Scalar::Util qw/blessed/;
  12
  13 our $VERSION = '0.34';
  14
  15 __PACKAGE__->mk_accessors('template');
  16 __PACKAGE__->mk_accessors('include_path');
  17
  18 *paths = \&include_path;
  19
  20 =head1 NAME
  21
  22 Catalyst::View::TT - Template View Class
  23
  24 =head1 SYNOPSIS
  25
  26 # use the helper to create your View
  27
  28     myapp_create.pl view Web TT
  29
  30 # add custom configration in View/Web.pm
  31
  32     __PACKAGE__->config(
  33         # any TT configuration items go here
  34         INCLUDE_PATH => [
  35           MyApp->path_to( 'root', 'src' ),
  36           MyApp->path_to( 'root', 'lib' ),
  37         ],
  38         TEMPLATE_EXTENSION => '.tt',
  39         CATALYST_VAR => 'c',
  40         TIMER        => 0,
  41         # Not set by default
  42         PRE_PROCESS        => 'config/main',
  43         WRAPPER            => 'site/wrapper',
  44         render_die => 1, # Default for new apps, see render method docs
  45     );
  46
  47 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  48
  49     sub message : Global {
  50         my ( $self, $c ) = @_;
  51         $c->stash->{template} = 'message.tt2';
  52         $c->stash->{message}  = 'Hello World!';
  53         $c->forward( $c->view('Web') );
  54     }
  55
  56 # access variables from template
  57
  58     The message is: [% message %].
  59
  60     # example when CATALYST_VAR is set to 'Catalyst'
  61     Context is [% Catalyst %]
  62     The base is [% Catalyst.req.base %]
  63     The name is [% Catalyst.config.name %]
  64
  65     # example when CATALYST_VAR isn't set
  66     Context is [% c %]
  67     The base is [% base %]
  68     The name is [% name %]
  69
  70 =cut
  71
  72 sub _coerce_paths {
  73     my ( $paths, $dlim ) = shift;
  74     return () if ( !$paths );
  75     return @{$paths} if ( ref $paths eq 'ARRAY' );
  76
  77     # tweak delim to ignore C:/
  78     unless ( defined $dlim ) {
  79         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  80     }
  81     return split( /$dlim/, $paths );
  82 }
  83
  84 sub new {
  85     my ( $class, $c, $arguments ) = @_;
  86     my $config = {
  87         EVAL_PERL          => 0,
  88         TEMPLATE_EXTENSION => '',
  89         %{ $class->config },
  90         %{$arguments},
  91     };
  92     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  93         my $delim = $config->{DELIMITER};
  94         my @include_path
  95             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  96         if ( !@include_path ) {
  97             my $root = $c->config->{root};
  98             my $base = Path::Class::dir( $root, 'base' );
  99             @include_path = ( "$root", "$base" );
 100         }
 101         $config->{INCLUDE_PATH} = \@include_path;
 102     }
 103
 104     # if we're debugging and/or the TIMER option is set, then we install
 105     # Template::Timer as a custom CONTEXT object, but only if we haven't
 106     # already got a custom CONTEXT defined
 107
 108     if ( $config->{TIMER} ) {
 109         if ( $config->{CONTEXT} ) {
 110             $c->log->error(
 111                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 112             );
 113         }
 114         else {
 115             $config->{CONTEXT} = Template::Timer->new(%$config);
 116         }
 117     }
 118
 119     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 120         $c->log->debug( "TT Config: ", dump($config) );
 121     }
 122
 123     my $self = $class->next::method(
 124         $c, { %$config },
 125     );
 126
 127     # Set base include paths. Local'd in render if needed
 128     $self->include_path($config->{INCLUDE_PATH});
 129
 130     $self->config($config);
 131
 132     # Creation of template outside of call to new so that we can pass [ $self ]
 133     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 134     # of include paths to search for templates.
 135
 136     # Use a weakend copy of self so we dont have loops preventing GC from working
 137     my $copy = $self;
 138     Scalar::Util::weaken($copy);
 139     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 140
 141     if ( $config->{PROVIDERS} ) {
 142         my @providers = ();
 143         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 144             foreach my $p (@{$config->{PROVIDERS}}) {
 145                 my $pname = $p->{name};
 146                 my $prov = 'Template::Provider';
 147                 if($pname eq '_file_')
 148                 {
 149                     $p->{args} = { %$config };
 150                 }
 151                 else
 152                 {
 153                     if($pname =~ s/^\+//) {
 154                         $prov = $pname;
 155                     }
 156                     else
 157                     {
 158                         $prov .= "::$pname";
 159                     }
 160                     # We copy the args people want from the config
 161                     # to the args
 162                     $p->{args} ||= {};
 163                     if ($p->{copy_config}) {
 164                         map  { $p->{args}->{$_} = $config->{$_}  }
 165                                    grep { exists $config->{$_} }
 166                                    @{ $p->{copy_config} };
 167                     }
 168                 }
 169                 local $@;
 170                 eval "require $prov";
 171                 if(!$@) {
 172                     push @providers, "$prov"->new($p->{args});
 173                 }
 174                 else
 175                 {
 176                     $c->log->warn("Can't load $prov, ($@)");
 177                 }
 178             }
 179         }
 180         delete $config->{PROVIDERS};
 181         if(@providers) {
 182             $config->{LOAD_TEMPLATES} = \@providers;
 183         }
 184     }
 185
 186     $self->{template} =
 187         Template->new($config) || do {
 188             my $error = Template->error();
 189             $c->log->error($error);
 190             $c->error($error);
 191             return undef;
 192         };
 193
 194
 195     return $self;
 196 }
 197
 198 sub process {
 199     my ( $self, $c ) = @_;
 200
 201     my $template = $c->stash->{template}
 202       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 203
 204     unless (defined $template) {
 205         $c->log->debug('No template specified for rendering') if $c->debug;
 206         return 0;
 207     }
 208
 209     local $@;
 210     my $output = eval { $self->render($c, $template) };
 211     if (my $err = $@) {
 212         return $self->_rendering_error($c, $template . ': ' . $err);
 213     }
 214     if (blessed($output) && $output->isa('Template::Exception')) {
 215         $self->_rendering_error($c, $output);
 216     }
 217
 218     unless ( $c->response->content_type ) {
 219         $c->response->content_type('text/html; charset=utf-8');
 220     }
 221
 222     $c->response->body($output);
 223
 224     return 1;
 225 }
 226
 227 sub _rendering_error {
 228     my ($self, $c, $err) = @_;
 229     my $error = qq/Couldn't render template "$err"/;
 230     $c->log->error($error);
 231     $c->error($error);
 232     return 0;
 233 }
 234
 235 sub render {
 236     my ($self, $c, $template, $args) = @_;
 237
 238     $c->log->debug(qq/Rendering template "$template"/) if $c && $c->debug;
 239
 240     my $output;
 241     my $vars = {
 242         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 243         $self->template_vars($c)
 244     };
 245
 246     local $self->{include_path} =
 247         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 248         if ref $vars->{additional_template_paths};
 249
 250     unless ( $self->template->process( $template, $vars, \$output ) ) {
 251         if (exists $self->{render_die}) {
 252             die $self->template->error if $self->{render_die};
 253             return $self->template->error;
 254         }
 255         $c->log->debug('The Catalyst::View::TT render() method will start dying on error in a future release. Unless you are calling the render() method manually, you probably want the new behaviour, so set render_die => 1 in config for ' . blessed($self) . '. If you wish to continue to return the exception rather than throwing it, add render_die => 0 to your config.') if $c->debug;
 256         return $self->template->error;
 257     }
 258     return $output;
 259 }
 260
 261 sub template_vars {
 262     my ( $self, $c ) = @_;
 263
 264     return  () unless $c;
 265     my $cvar = $self->config->{CATALYST_VAR};
 266
 267     defined $cvar
 268       ? ( $cvar => $c )
 269       : (
 270         c    => $c,
 271         base => $c->req->base,
 272         name => $c->config->{name}
 273       )
 274 }
 275
 276
 277 1;
 278
 279 __END__
 280
 281 =head1 DESCRIPTION
 282
 283 This is the Catalyst view class for the L<Template Toolkit|Template>.
 284 Your application should defined a view class which is a subclass of
 285 this module. Throughout this manual it will be assumed that your application
 286 is named F<MyApp> and you are creating a TT view named F<Web>; these names
 287 are placeholders and should always be replaced with whatever name you've
 288 chosen for your application and your view. The easiest way to create a TT
 289 view class is through the F<myapp_create.pl> script that is created along
 290 with the application:
 291
 292     $ script/myapp_create.pl view Web TT
 293
 294 This creates a F<MyApp::View::Web.pm> module in the F<lib> directory (again,
 295 replacing C<MyApp> with the name of your application) which looks
 296 something like this:
 297
 298     package FooBar::View::Web;
 299
 300     use strict;
 301     use warnings;
 302
 303     use base 'Catalyst::View::TT';
 304
 305     __PACKAGE__->config(DEBUG => 'all');
 306
 307 Now you can modify your action handlers in the main application and/or
 308 controllers to forward to your view class.  You might choose to do this
 309 in the end() method, for example, to automatically forward all actions
 310 to the TT view class.
 311
 312     # In MyApp or MyApp::Controller::SomeController
 313
 314     sub end : Private {
 315         my( $self, $c ) = @_;
 316         $c->forward( $c->view('Web') );
 317     }
 318
 319 But if you are using the standard auto-generated end action, you don't even need
 320 to do this!
 321
 322     # in MyApp::Controller::Root
 323     sub end : ActionClass('RenderView') {} # no need to change this line
 324
 325     # in MyApp.pm
 326     __PACKAGE__->config(
 327         ...
 328         default_view => 'Web',
 329     );
 330
 331 This will Just Work.  And it has the advantages that:
 332
 333 =over 4
 334
 335 =item *
 336
 337 If you want to use a different view for a given request, just set
 338 << $c->stash->{current_view} >>.  (See L<Catalyst>'s C<< $c->view >> method
 339 for details.
 340
 341 =item *
 342
 343 << $c->res->redirect >> is handled by default.  If you just forward to
 344 C<View::Web> in your C<end> routine, you could break this by sending additional
 345 content.
 346
 347 =back
 348
 349 See L<Catalyst::Action::RenderView> for more details.
 350
 351 =head2 CONFIGURATION
 352
 353 There are a three different ways to configure your view class.  The
 354 first way is to call the C<config()> method in the view subclass.  This
 355 happens when the module is first loaded.
 356
 357     package MyApp::View::Web;
 358
 359     use strict;
 360     use base 'Catalyst::View::TT';
 361
 362     __PACKAGE__->config({
 363         INCLUDE_PATH => [
 364             MyApp->path_to( 'root', 'templates', 'lib' ),
 365             MyApp->path_to( 'root', 'templates', 'src' ),
 366         ],
 367         PRE_PROCESS  => 'config/main',
 368         WRAPPER      => 'site/wrapper',
 369     });
 370
 371 You may also override the configuration provided in the view class by adding
 372 a 'View::Web' section to your application config (either in the application
 373 main class, or in your configuration file). This should be reserved for
 374 deployment-specific concerns. For example:
 375
 376     # MyApp_local.conf (Config::General format)
 377
 378     <View Web>
 379       WRAPPER "custom_wrapper"
 380       INCLUDE_PATH __path_to('root/templates/custom_site')__
 381       INCLUDE_PATH __path_to('root/templates')__
 382     </View>
 383
 384 might be used as part of a simple way to deploy different instances of the
 385 same application with different themes.
 386
 387 =head2 DYNAMIC INCLUDE_PATH
 388
 389 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 390
 391 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 392 follows:
 393
 394     $c->stash->{additional_template_paths} =
 395         [$c->config->{root} . '/test_include_path'];
 396
 397 If you need to add paths to the end of INCLUDE_PATH, there is also an
 398 include_path() accessor available:
 399
 400     push( @{ $c->view('Web')->include_path }, qw/path/ );
 401
 402 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 403 MUST check for duplicate paths. Without such checking, the above code will add
 404 "path" to INCLUDE_PATH at every request, causing a memory leak.
 405
 406 A safer approach is to use include_path() to overwrite the array of paths
 407 rather than adding to it. This eliminates both the need to perform duplicate
 408 checking and the chance of a memory leak:
 409
 410     @{ $c->view('Web')->include_path } = qw/path another_path/;
 411
 412 If you are calling C<render> directly then you can specify dynamic paths by
 413 having a C<additional_template_paths> key with a value of additonal directories
 414 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 415
 416 =head2 RENDERING VIEWS
 417
 418 The view plugin renders the template specified in the C<template>
 419 item in the stash.
 420
 421     sub message : Global {
 422         my ( $self, $c ) = @_;
 423         $c->stash->{template} = 'message.tt2';
 424         $c->forward( $c->view('Web') );
 425     }
 426
 427 If a stash item isn't defined, then it instead uses the
 428 stringification of the action dispatched to (as defined by $c->action)
 429 in the above example, this would be C<message>, but because the default
 430 is to append '.tt', it would load C<root/message.tt>.
 431
 432 The items defined in the stash are passed to the Template Toolkit for
 433 use as template variables.
 434
 435     sub default : Private {
 436         my ( $self, $c ) = @_;
 437         $c->stash->{template} = 'message.tt2';
 438         $c->stash->{message}  = 'Hello World!';
 439         $c->forward( $c->view('Web') );
 440     }
 441
 442 A number of other template variables are also added:
 443
 444     c      A reference to the context object, $c
 445     base   The URL base, from $c->req->base()
 446     name   The application name, from $c->config->{ name }
 447
 448 These can be accessed from the template in the usual way:
 449
 450 <message.tt2>:
 451
 452     The message is: [% message %]
 453     The base is [% base %]
 454     The name is [% name %]
 455
 456
 457 The output generated by the template is stored in C<< $c->response->body >>.
 458
 459 =head2 CAPTURING TEMPLATE OUTPUT
 460
 461 If you wish to use the output of a template for some other purpose than
 462 displaying in the response, e.g. for sending an email, this is possible using
 463 L<Catalyst::Plugin::Email> and the L<render> method:
 464
 465   sub send_email : Local {
 466     my ($self, $c) = @_;
 467
 468     $c->email(
 469       header => [
 470         To      => 'me@localhost',
 471         Subject => 'A TT Email',
 472       ],
 473       body => $c->view('Web')->render($c, 'email.tt', {
 474         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 475         email_tmpl_param1 => 'foo'
 476         }
 477       ),
 478     );
 479   # Redirect or display a message
 480   }
 481
 482 =head2 TEMPLATE PROFILING
 483
 484 See L<C<TIMER>> property of the L<config> method.
 485
 486 =head2 METHODS
 487
 488 =head2 new
 489
 490 The constructor for the TT view. Sets up the template provider,
 491 and reads the application config.
 492
 493 =head2 process($c)
 494
 495 Renders the template specified in C<< $c->stash->{template} >> or
 496 C<< $c->action >> (the private name of the matched action).  Calls L<render> to
 497 perform actual rendering. Output is stored in C<< $c->response->body >>.
 498
 499 It is possible to forward to the process method of a TT view from inside
 500 Catalyst like this:
 501
 502     $c->forward('View::Web');
 503
 504 N.B. This is usually done automatically by L<Catalyst::Action::RenderView>.
 505
 506 =head2 render($c, $template, \%args)
 507
 508 Renders the given template and returns output. Throws a L<Template::Exception>
 509 object upon error.
 510
 511 The template variables are set to C<%$args> if C<$args> is a hashref, or
 512 C<< $c->stash >> otherwise. In either case the variables are augmented with
 513 C<base> set to C<< $c->req->base >>, C<c> to C<$c>, and C<name> to
 514 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 515 can be defined to specify the name of a template variable through which the
 516 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base>, and
 517 C<name> variables are omitted.
 518
 519 C<$template> can be anything that Template::process understands how to
 520 process, including the name of a template file or a reference to a test string.
 521 See L<Template::process|Template/process> for a full list of supported formats.
 522
 523 To use the render method outside of your Catalyst app, just pass a undef context.
 524 This can be useful for tests, for instance.
 525
 526 It is possible to forward to the render method of a TT view from inside Catalyst
 527 to render page fragments like this:
 528
 529     my $fragment = $c->forward("View::Web", "render", $template_name, $c->stash->{fragment_data});
 530
 531 =head3 Backwards compatibility note
 532
 533 The render method used to just return the Template::Exception object, rather
 534 than just throwing it. This is now deprecated and instead the render method
 535 will throw an exception for new applications.
 536
 537 This behaviour can be activated (and is activated in the default skeleton
 538 configuration) by using C<< render_die => 1 >>. If you rely on the legacy
 539 behaviour then a warning will be issued.
 540
 541 To silence this warning, set C<< render_die => 0 >>, but it is recommended
 542 you adjust your code so that it works with C<< render_die => 1 >>.
 543
 544 In a future release, C<< render_die => 1 >> will become the default if
 545 unspecified.
 546
 547 =head2 template_vars
 548
 549 Returns a list of keys/values to be used as the catalyst variables in the
 550 template.
 551
 552 =head2 config
 553
 554 This method allows your view subclass to pass additional settings to
 555 the TT configuration hash, or to set the options as below:
 556
 557 =head2 paths
 558
 559 The list of paths TT will look for templates in.
 560
 561 =head2 C<CATALYST_VAR>
 562
 563 Allows you to change the name of the Catalyst context object. If set, it will also
 564 remove the base and name aliases, so you will have access them through <context>.
 565
 566 For example, if CATALYST_VAR has been set to "Catalyst", a template might
 567 contain:
 568
 569     The base is [% Catalyst.req.base %]
 570     The name is [% Catalyst.config.name %]
 571
 572 =head2 C<TIMER>
 573
 574 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 575 C<Catalyst::View::TT> will enable profiling of template processing
 576 (using L<Template::Timer>). This will embed HTML comments in the
 577 output from your templates, such as:
 578
 579     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 580     <!-- TIMER START: include mainmenu/cssindex.tt -->
 581     <!-- TIMER START: process mainmenu/cssindex.tt -->
 582     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 583     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 584
 585     ....
 586
 587     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 588
 589
 590 =head2 C<TEMPLATE_EXTENSION>
 591
 592 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 593
 594 For example:
 595
 596   package MyApp::Controller::Test;
 597   sub test : Local { .. }
 598
 599 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 600 <root>/test/test.tt.
 601
 602 =head2 C<PROVIDERS>
 603
 604 Allows you to specify the template providers that TT will use.
 605
 606     MyApp->config({
 607         name     => 'MyApp',
 608         root     => MyApp->path_to('root'),
 609         'View::Web' => {
 610             PROVIDERS => [
 611                 {
 612                     name    => 'DBI',
 613                     args    => {
 614                         DBI_DSN => 'dbi:DB2:books',
 615                         DBI_USER=> 'foo'
 616                     }
 617                 }, {
 618                     name    => '_file_',
 619                     args    => {}
 620                 }
 621             ]
 622         },
 623     });
 624
 625 The 'name' key should correspond to the class name of the provider you
 626 want to use.  The _file_ name is a special case that represents the default
 627 TT file-based provider.  By default the name is will be prefixed with
 628 'Template::Provider::'.  You can fully qualify the name by using a unary
 629 plus:
 630
 631     name => '+MyApp::Provider::Foo'
 632
 633 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 634 from the general config, into the config for the provider:
 635
 636     DEFAULT_ENCODING    => 'utf-8',
 637     PROVIDERS => [
 638         {
 639             name    => 'Encoding',
 640             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 641         }
 642     ]
 643
 644 This can prove useful when you want to use the additional_template_paths hack
 645 in your own provider, or if you need to use Template::Provider::Encoding
 646
 647 =head2 HELPERS
 648
 649 The L<Catalyst::Helper::View::TT> and
 650 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 651 your view module.  There are invoked by the F<myapp_create.pl> script:
 652
 653     $ script/myapp_create.pl view Web TT
 654
 655     $ script/myapp_create.pl view Web TTSite
 656
 657 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 658 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 659 further.  It also creates a default set of templates to get you
 660 started.  It also configures the view module to locate the templates
 661 automatically.
 662
 663 =head1 NOTES
 664
 665 If you are using the L<CGI> module inside your templates, you will
 666 experience that the Catalyst server appears to hang while rendering
 667 the web page. This is due to the debug mode of L<CGI> (which is
 668 waiting for input in the terminal window). Turning off the
 669 debug mode using the "-no_debug" option solves the
 670 problem, eg.:
 671
 672     [% USE CGI('-no_debug') %]
 673
 674 =head1 SEE ALSO
 675
 676 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 677 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 678
 679 =head1 AUTHORS
 680
 681 Sebastian Riedel, C<sri@cpan.org>
 682
 683 Marcus Ramberg, C<mramberg@cpan.org>
 684
 685 Jesse Sheidlower, C<jester@panix.com>
 686
 687 Andy Wardley, C<abw@cpan.org>
 688
 689 =head1 COPYRIGHT
 690
 691 This program is free software. You can redistribute it and/or modify it
 692 under the same terms as Perl itself.
 693
 694 =cut