lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11 use Scalar::Util qw/blessed weaken/;
  12
  13 our $VERSION = '0.36';
  14 $VERSION = eval $VERSION;
  15
  16 __PACKAGE__->mk_accessors('template');
  17 __PACKAGE__->mk_accessors('expose_methods');
  18 __PACKAGE__->mk_accessors('include_path');
  19
  20 *paths = \&include_path;
  21
  22 =head1 NAME
  23
  24 Catalyst::View::TT - Template View Class
  25
  26 =head1 SYNOPSIS
  27
  28 # use the helper to create your View
  29
  30     myapp_create.pl view Web TT
  31
  32 # add custom configration in View/Web.pm
  33
  34     __PACKAGE__->config(
  35         # any TT configuration items go here
  36         INCLUDE_PATH => [
  37           MyApp->path_to( 'root', 'src' ),
  38           MyApp->path_to( 'root', 'lib' ),
  39         ],
  40         TEMPLATE_EXTENSION => '.tt',
  41         CATALYST_VAR => 'c',
  42         TIMER        => 0,
  43         # Not set by default
  44         PRE_PROCESS        => 'config/main',
  45         WRAPPER            => 'site/wrapper',
  46         render_die => 1, # Default for new apps, see render method docs
  47         expose_methods => [qw/method_in_view_class/],
  48     );
  49
  50 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  51
  52     sub message : Global {
  53         my ( $self, $c ) = @_;
  54         $c->stash->{template} = 'message.tt2';
  55         $c->stash->{message}  = 'Hello World!';
  56         $c->forward( $c->view('Web') );
  57     }
  58
  59 # access variables from template
  60
  61     The message is: [% message %].
  62
  63     # example when CATALYST_VAR is set to 'Catalyst'
  64     Context is [% Catalyst %]
  65     The base is [% Catalyst.req.base %]
  66     The name is [% Catalyst.config.name %]
  67
  68     # example when CATALYST_VAR isn't set
  69     Context is [% c %]
  70     The base is [% base %]
  71     The name is [% name %]
  72
  73 =cut
  74
  75 sub _coerce_paths {
  76     my ( $paths, $dlim ) = shift;
  77     return () if ( !$paths );
  78     return @{$paths} if ( ref $paths eq 'ARRAY' );
  79
  80     # tweak delim to ignore C:/
  81     unless ( defined $dlim ) {
  82         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  83     }
  84     return split( /$dlim/, $paths );
  85 }
  86
  87 sub new {
  88     my ( $class, $c, $arguments ) = @_;
  89     my $config = {
  90         EVAL_PERL          => 0,
  91         TEMPLATE_EXTENSION => '',
  92         CLASS              => 'Template',
  93         %{ $class->config },
  94         %{$arguments},
  95     };
  96     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  97         my $delim = $config->{DELIMITER};
  98         my @include_path
  99             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
 100         if ( !@include_path ) {
 101             my $root = $c->config->{root};
 102             my $base = Path::Class::dir( $root, 'base' );
 103             @include_path = ( "$root", "$base" );
 104         }
 105         $config->{INCLUDE_PATH} = \@include_path;
 106     }
 107
 108     # if we're debugging and/or the TIMER option is set, then we install
 109     # Template::Timer as a custom CONTEXT object, but only if we haven't
 110     # already got a custom CONTEXT defined
 111
 112     if ( $config->{TIMER} ) {
 113         if ( $config->{CONTEXT} ) {
 114             $c->log->error(
 115                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 116             );
 117         }
 118         else {
 119             $config->{CONTEXT} = Template::Timer->new(%$config);
 120         }
 121     }
 122
 123     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 124         $c->log->debug( "TT Config: ", dump($config) );
 125     }
 126
 127     my $self = $class->next::method(
 128         $c, { %$config },
 129     );
 130
 131     # Set base include paths. Local'd in render if needed
 132     $self->include_path($config->{INCLUDE_PATH});
 133
 134     $self->expose_methods($config->{expose_methods});
 135     $self->config($config);
 136
 137     # Creation of template outside of call to new so that we can pass [ $self ]
 138     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 139     # of include paths to search for templates.
 140
 141     # Use a weakend copy of self so we dont have loops preventing GC from working
 142     my $copy = $self;
 143     Scalar::Util::weaken($copy);
 144     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 145
 146     if ( $config->{PROVIDERS} ) {
 147         my @providers = ();
 148         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 149             foreach my $p (@{$config->{PROVIDERS}}) {
 150                 my $pname = $p->{name};
 151                 my $prov = 'Template::Provider';
 152                 if($pname eq '_file_')
 153                 {
 154                     $p->{args} = { %$config };
 155                 }
 156                 else
 157                 {
 158                     if($pname =~ s/^\+//) {
 159                         $prov = $pname;
 160                     }
 161                     else
 162                     {
 163                         $prov .= "::$pname";
 164                     }
 165                     # We copy the args people want from the config
 166                     # to the args
 167                     $p->{args} ||= {};
 168                     if ($p->{copy_config}) {
 169                         map  { $p->{args}->{$_} = $config->{$_}  }
 170                                    grep { exists $config->{$_} }
 171                                    @{ $p->{copy_config} };
 172                     }
 173                 }
 174                 local $@;
 175                 eval "require $prov";
 176                 if(!$@) {
 177                     push @providers, "$prov"->new($p->{args});
 178                 }
 179                 else
 180                 {
 181                     $c->log->warn("Can't load $prov, ($@)");
 182                 }
 183             }
 184         }
 185         delete $config->{PROVIDERS};
 186         if(@providers) {
 187             $config->{LOAD_TEMPLATES} = \@providers;
 188         }
 189     }
 190
 191     $self->{template} =
 192         $config->{CLASS}->new($config) || do {
 193             my $error = $config->{CLASS}->error();
 194             $c->log->error($error);
 195             $c->error($error);
 196             return undef;
 197         };
 198
 199
 200     return $self;
 201 }
 202
 203 sub process {
 204     my ( $self, $c ) = @_;
 205
 206     my $template = $c->stash->{template}
 207       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 208
 209     unless (defined $template) {
 210         $c->log->debug('No template specified for rendering') if $c->debug;
 211         return 0;
 212     }
 213
 214     local $@;
 215     my $output = eval { $self->render($c, $template) };
 216     if (my $err = $@) {
 217         return $self->_rendering_error($c, $template . ': ' . $err);
 218     }
 219     if (blessed($output) && $output->isa('Template::Exception')) {
 220         $self->_rendering_error($c, $output);
 221     }
 222
 223     unless ( $c->response->content_type ) {
 224         $c->response->content_type('text/html; charset=utf-8');
 225     }
 226
 227     $c->response->body($output);
 228
 229     return 1;
 230 }
 231
 232 sub _rendering_error {
 233     my ($self, $c, $err) = @_;
 234     my $error = qq/Couldn't render template "$err"/;
 235     $c->log->error($error);
 236     $c->error($error);
 237     return 0;
 238 }
 239
 240 sub render {
 241     my ($self, $c, $template, $args) = @_;
 242
 243     $c->log->debug(qq/Rendering template "$template"/) if $c && $c->debug;
 244
 245     my $output;
 246     my $vars = {
 247         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 248         $self->template_vars($c)
 249     };
 250
 251     local $self->{include_path} =
 252         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 253         if ref $vars->{additional_template_paths};
 254
 255     unless ( $self->template->process( $template, $vars, \$output ) ) {
 256         if (exists $self->{render_die}) {
 257             die $self->template->error if $self->{render_die};
 258             return $self->template->error;
 259         }
 260         $c->log->debug('The Catalyst::View::TT render() method will start dying on error in a future release. Unless you are calling the render() method manually, you probably want the new behaviour, so set render_die => 1 in config for ' . blessed($self) . '. If you wish to continue to return the exception rather than throwing it, add render_die => 0 to your config.') if $c->debug;
 261         return $self->template->error;
 262     }
 263     return $output;
 264 }
 265
 266 sub template_vars {
 267     my ( $self, $c ) = @_;
 268
 269     return  () unless $c;
 270     my $cvar = $self->config->{CATALYST_VAR};
 271
 272     my %vars = defined $cvar
 273       ? ( $cvar => $c )
 274       : (
 275         c    => $c,
 276         base => $c->req->base,
 277         name => $c->config->{name}
 278       );
 279
 280     if ($self->expose_methods) {
 281         my $meta = $self->meta;
 282         foreach my $method_name (@{$self->expose_methods}) {
 283             my $method = $meta->find_method_by_name( $method_name );
 284             unless ($method) {
 285                 Catalyst::Exception->throw( "$method_name not found in TT view" );
 286             }
 287             my $method_body = $method->body;
 288             my $weak_ctx = $c;
 289             weaken $weak_ctx;
 290             my $sub = sub {
 291                 $self->$method_body($weak_ctx, @_);
 292             };
 293             $vars{$method_name} = $sub;
 294         }
 295     }
 296     return %vars;
 297 }
 298
 299 1;
 300
 301 __END__
 302
 303 =head1 DESCRIPTION
 304
 305 This is the Catalyst view class for the L<Template Toolkit|Template>.
 306 Your application should defined a view class which is a subclass of
 307 this module. Throughout this manual it will be assumed that your application
 308 is named F<MyApp> and you are creating a TT view named F<Web>; these names
 309 are placeholders and should always be replaced with whatever name you've
 310 chosen for your application and your view. The easiest way to create a TT
 311 view class is through the F<myapp_create.pl> script that is created along
 312 with the application:
 313
 314     $ script/myapp_create.pl view Web TT
 315
 316 This creates a F<MyApp::View::Web.pm> module in the F<lib> directory (again,
 317 replacing C<MyApp> with the name of your application) which looks
 318 something like this:
 319
 320     package FooBar::View::Web;
 321
 322     use strict;
 323     use warnings;
 324
 325     use base 'Catalyst::View::TT';
 326
 327     __PACKAGE__->config(DEBUG => 'all');
 328
 329 Now you can modify your action handlers in the main application and/or
 330 controllers to forward to your view class.  You might choose to do this
 331 in the end() method, for example, to automatically forward all actions
 332 to the TT view class.
 333
 334     # In MyApp or MyApp::Controller::SomeController
 335
 336     sub end : Private {
 337         my( $self, $c ) = @_;
 338         $c->forward( $c->view('Web') );
 339     }
 340
 341 But if you are using the standard auto-generated end action, you don't even need
 342 to do this!
 343
 344     # in MyApp::Controller::Root
 345     sub end : ActionClass('RenderView') {} # no need to change this line
 346
 347     # in MyApp.pm
 348     __PACKAGE__->config(
 349         ...
 350         default_view => 'Web',
 351     );
 352
 353 This will Just Work.  And it has the advantages that:
 354
 355 =over 4
 356
 357 =item *
 358
 359 If you want to use a different view for a given request, just set
 360 << $c->stash->{current_view} >>.  (See L<Catalyst>'s C<< $c->view >> method
 361 for details.
 362
 363 =item *
 364
 365 << $c->res->redirect >> is handled by default.  If you just forward to
 366 C<View::Web> in your C<end> routine, you could break this by sending additional
 367 content.
 368
 369 =back
 370
 371 See L<Catalyst::Action::RenderView> for more details.
 372
 373 =head2 CONFIGURATION
 374
 375 There are a three different ways to configure your view class.  The
 376 first way is to call the C<config()> method in the view subclass.  This
 377 happens when the module is first loaded.
 378
 379     package MyApp::View::Web;
 380
 381     use strict;
 382     use base 'Catalyst::View::TT';
 383
 384     __PACKAGE__->config({
 385         INCLUDE_PATH => [
 386             MyApp->path_to( 'root', 'templates', 'lib' ),
 387             MyApp->path_to( 'root', 'templates', 'src' ),
 388         ],
 389         PRE_PROCESS  => 'config/main',
 390         WRAPPER      => 'site/wrapper',
 391     });
 392
 393 You may also override the configuration provided in the view class by adding
 394 a 'View::Web' section to your application config (either in the application
 395 main class, or in your configuration file). This should be reserved for
 396 deployment-specific concerns. For example:
 397
 398     # MyApp_local.conf (Config::General format)
 399
 400     <View Web>
 401       WRAPPER "custom_wrapper"
 402       INCLUDE_PATH __path_to('root/templates/custom_site')__
 403       INCLUDE_PATH __path_to('root/templates')__
 404     </View>
 405
 406 might be used as part of a simple way to deploy different instances of the
 407 same application with different themes.
 408
 409 =head2 DYNAMIC INCLUDE_PATH
 410
 411 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 412
 413 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 414 follows:
 415
 416     $c->stash->{additional_template_paths} =
 417         [$c->config->{root} . '/test_include_path'];
 418
 419 If you need to add paths to the end of INCLUDE_PATH, there is also an
 420 include_path() accessor available:
 421
 422     push( @{ $c->view('Web')->include_path }, qw/path/ );
 423
 424 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 425 MUST check for duplicate paths. Without such checking, the above code will add
 426 "path" to INCLUDE_PATH at every request, causing a memory leak.
 427
 428 A safer approach is to use include_path() to overwrite the array of paths
 429 rather than adding to it. This eliminates both the need to perform duplicate
 430 checking and the chance of a memory leak:
 431
 432     @{ $c->view('Web')->include_path } = qw/path another_path/;
 433
 434 If you are calling C<render> directly then you can specify dynamic paths by
 435 having a C<additional_template_paths> key with a value of additonal directories
 436 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 437
 438 =head2 RENDERING VIEWS
 439
 440 The view plugin renders the template specified in the C<template>
 441 item in the stash.
 442
 443     sub message : Global {
 444         my ( $self, $c ) = @_;
 445         $c->stash->{template} = 'message.tt2';
 446         $c->forward( $c->view('Web') );
 447     }
 448
 449 If a stash item isn't defined, then it instead uses the
 450 stringification of the action dispatched to (as defined by $c->action)
 451 in the above example, this would be C<message>, but because the default
 452 is to append '.tt', it would load C<root/message.tt>.
 453
 454 The items defined in the stash are passed to the Template Toolkit for
 455 use as template variables.
 456
 457     sub default : Private {
 458         my ( $self, $c ) = @_;
 459         $c->stash->{template} = 'message.tt2';
 460         $c->stash->{message}  = 'Hello World!';
 461         $c->forward( $c->view('Web') );
 462     }
 463
 464 A number of other template variables are also added:
 465
 466     c      A reference to the context object, $c
 467     base   The URL base, from $c->req->base()
 468     name   The application name, from $c->config->{ name }
 469
 470 These can be accessed from the template in the usual way:
 471
 472 <message.tt2>:
 473
 474     The message is: [% message %]
 475     The base is [% base %]
 476     The name is [% name %]
 477
 478
 479 The output generated by the template is stored in C<< $c->response->body >>.
 480
 481 =head2 CAPTURING TEMPLATE OUTPUT
 482
 483 If you wish to use the output of a template for some other purpose than
 484 displaying in the response, e.g. for sending an email, this is possible using
 485 L<Catalyst::Plugin::Email> and the L<render> method:
 486
 487   sub send_email : Local {
 488     my ($self, $c) = @_;
 489
 490     $c->email(
 491       header => [
 492         To      => 'me@localhost',
 493         Subject => 'A TT Email',
 494       ],
 495       body => $c->view('Web')->render($c, 'email.tt', {
 496         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 497         email_tmpl_param1 => 'foo'
 498         }
 499       ),
 500     );
 501   # Redirect or display a message
 502   }
 503
 504 =head2 TEMPLATE PROFILING
 505
 506 See L<C<TIMER>> property of the L<config> method.
 507
 508 =head2 METHODS
 509
 510 =head2 new
 511
 512 The constructor for the TT view. Sets up the template provider,
 513 and reads the application config.
 514
 515 =head2 process($c)
 516
 517 Renders the template specified in C<< $c->stash->{template} >> or
 518 C<< $c->action >> (the private name of the matched action).  Calls L<render> to
 519 perform actual rendering. Output is stored in C<< $c->response->body >>.
 520
 521 It is possible to forward to the process method of a TT view from inside
 522 Catalyst like this:
 523
 524     $c->forward('View::Web');
 525
 526 N.B. This is usually done automatically by L<Catalyst::Action::RenderView>.
 527
 528 =head2 render($c, $template, \%args)
 529
 530 Renders the given template and returns output. Throws a L<Template::Exception>
 531 object upon error.
 532
 533 The template variables are set to C<%$args> if C<$args> is a hashref, or
 534 C<< $c->stash >> otherwise. In either case the variables are augmented with
 535 C<base> set to C<< $c->req->base >>, C<c> to C<$c>, and C<name> to
 536 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 537 can be defined to specify the name of a template variable through which the
 538 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base>, and
 539 C<name> variables are omitted.
 540
 541 C<$template> can be anything that Template::process understands how to
 542 process, including the name of a template file or a reference to a test string.
 543 See L<Template::process|Template/process> for a full list of supported formats.
 544
 545 To use the render method outside of your Catalyst app, just pass a undef context.
 546 This can be useful for tests, for instance.
 547
 548 It is possible to forward to the render method of a TT view from inside Catalyst
 549 to render page fragments like this:
 550
 551     my $fragment = $c->forward("View::Web", "render", $template_name, $c->stash->{fragment_data});
 552
 553 =head3 Backwards compatibility note
 554
 555 The render method used to just return the Template::Exception object, rather
 556 than just throwing it. This is now deprecated and instead the render method
 557 will throw an exception for new applications.
 558
 559 This behaviour can be activated (and is activated in the default skeleton
 560 configuration) by using C<< render_die => 1 >>. If you rely on the legacy
 561 behaviour then a warning will be issued.
 562
 563 To silence this warning, set C<< render_die => 0 >>, but it is recommended
 564 you adjust your code so that it works with C<< render_die => 1 >>.
 565
 566 In a future release, C<< render_die => 1 >> will become the default if
 567 unspecified.
 568
 569 =head2 template_vars
 570
 571 Returns a list of keys/values to be used as the catalyst variables in the
 572 template.
 573
 574 =head2 config
 575
 576 This method allows your view subclass to pass additional settings to
 577 the TT configuration hash, or to set the options as below:
 578
 579 =head2 paths
 580
 581 The list of paths TT will look for templates in.
 582
 583 =head2 expose_methods
 584
 585 The list of methods in your View class which should be made available to the templates.
 586
 587 For example:
 588
 589   expose_methods => [qw/uri_for_css/],
 590
 591   ...
 592
 593   sub uri_for_css {
 594     my ($self, $c, $filename) = @_;
 595
 596     # additional complexity like checking file exists here
 597
 598     return $c->uri_for('/static/css/' . $filename);
 599   }
 600
 601 Then in the template:
 602
 603   [% uri_for_css('home.css') %]
 604
 605 =head2 C<CATALYST_VAR>
 606
 607 Allows you to change the name of the Catalyst context object. If set, it will also
 608 remove the base and name aliases, so you will have access them through <context>.
 609
 610 For example, if CATALYST_VAR has been set to "Catalyst", a template might
 611 contain:
 612
 613     The base is [% Catalyst.req.base %]
 614     The name is [% Catalyst.config.name %]
 615
 616 =head2 C<TIMER>
 617
 618 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 619 C<Catalyst::View::TT> will enable profiling of template processing
 620 (using L<Template::Timer>). This will embed HTML comments in the
 621 output from your templates, such as:
 622
 623     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 624     <!-- TIMER START: include mainmenu/cssindex.tt -->
 625     <!-- TIMER START: process mainmenu/cssindex.tt -->
 626     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 627     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 628
 629     ....
 630
 631     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 632
 633
 634 =head2 C<TEMPLATE_EXTENSION>
 635
 636 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 637
 638 For example:
 639
 640   package MyApp::Controller::Test;
 641   sub test : Local { .. }
 642
 643 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 644 <root>/test/test.tt.
 645
 646 =head2 C<PROVIDERS>
 647
 648 Allows you to specify the template providers that TT will use.
 649
 650     MyApp->config({
 651         name     => 'MyApp',
 652         root     => MyApp->path_to('root'),
 653         'View::Web' => {
 654             PROVIDERS => [
 655                 {
 656                     name    => 'DBI',
 657                     args    => {
 658                         DBI_DSN => 'dbi:DB2:books',
 659                         DBI_USER=> 'foo'
 660                     }
 661                 }, {
 662                     name    => '_file_',
 663                     args    => {}
 664                 }
 665             ]
 666         },
 667     });
 668
 669 The 'name' key should correspond to the class name of the provider you
 670 want to use.  The _file_ name is a special case that represents the default
 671 TT file-based provider.  By default the name is will be prefixed with
 672 'Template::Provider::'.  You can fully qualify the name by using a unary
 673 plus:
 674
 675     name => '+MyApp::Provider::Foo'
 676
 677 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 678 from the general config, into the config for the provider:
 679
 680     DEFAULT_ENCODING    => 'utf-8',
 681     PROVIDERS => [
 682         {
 683             name    => 'Encoding',
 684             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 685         }
 686     ]
 687
 688 This can prove useful when you want to use the additional_template_paths hack
 689 in your own provider, or if you need to use Template::Provider::Encoding
 690
 691 =head2 C<CLASS>
 692
 693 Allows you to specify a custom class to use as the template class instead of
 694 L<Template>.
 695
 696     package MyApp::View::Web;
 697
 698     use strict;
 699     use base 'Catalyst::View::TT';
 700
 701     use Template::AutoFilter;
 702
 703     __PACKAGE__->config({
 704         CLASS => 'Template::AutoFilter',
 705     });
 706
 707 This is useful if you want to use your own subclasses of L<Template>, so you
 708 can, for example, prevent XSS by automatically filtering all output through
 709 C<| html>.
 710
 711 =head2 HELPERS
 712
 713 The L<Catalyst::Helper::View::TT> and
 714 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 715 your view module.  There are invoked by the F<myapp_create.pl> script:
 716
 717     $ script/myapp_create.pl view Web TT
 718
 719     $ script/myapp_create.pl view Web TTSite
 720
 721 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 722 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 723 further.  It also creates a default set of templates to get you
 724 started.  It also configures the view module to locate the templates
 725 automatically.
 726
 727 =head1 NOTES
 728
 729 If you are using the L<CGI> module inside your templates, you will
 730 experience that the Catalyst server appears to hang while rendering
 731 the web page. This is due to the debug mode of L<CGI> (which is
 732 waiting for input in the terminal window). Turning off the
 733 debug mode using the "-no_debug" option solves the
 734 problem, eg.:
 735
 736     [% USE CGI('-no_debug') %]
 737
 738 =head1 SEE ALSO
 739
 740 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 741 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 742
 743 =head1 AUTHORS
 744
 745 Sebastian Riedel, C<sri@cpan.org>
 746
 747 Marcus Ramberg, C<mramberg@cpan.org>
 748
 749 Jesse Sheidlower, C<jester@panix.com>
 750
 751 Andy Wardley, C<abw@cpan.org>
 752
 753 Luke Saunders, C<luke.saunders@gmail.com>
 754
 755 =head1 COPYRIGHT
 756
 757 This program is free software. You can redistribute it and/or modify it
 758 under the same terms as Perl itself.
 759
 760 =cut