lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11 use Scalar::Util qw/blessed/;
  12
  13 our $VERSION = '0.34';
  14
  15 __PACKAGE__->mk_accessors('template');
  16 __PACKAGE__->mk_accessors('include_path');
  17
  18 *paths = \&include_path;
  19
  20 =head1 NAME
  21
  22 Catalyst::View::TT - Template View Class
  23
  24 =head1 SYNOPSIS
  25
  26 # use the helper to create your View
  27
  28     myapp_create.pl view Web TT
  29
  30 # add custom configration in View/Web.pm
  31
  32     __PACKAGE__->config(
  33         # any TT configuration items go here
  34         INCLUDE_PATH => [
  35           MyApp->path_to( 'root', 'src' ),
  36           MyApp->path_to( 'root', 'lib' ),
  37         ],
  38         TEMPLATE_EXTENSION => '.tt',
  39         CATALYST_VAR => 'c',
  40         TIMER        => 0,
  41         # Not set by default
  42         PRE_PROCESS        => 'config/main',
  43         WRAPPER            => 'site/wrapper',
  44         render_die => 1, # Default for new apps, see render method docs
  45         expose_methods => [qw/method_in_view_class/],
  46     );
  47
  48 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  49
  50     sub message : Global {
  51         my ( $self, $c ) = @_;
  52         $c->stash->{template} = 'message.tt2';
  53         $c->stash->{message}  = 'Hello World!';
  54         $c->forward( $c->view('Web') );
  55     }
  56
  57 # access variables from template
  58
  59     The message is: [% message %].
  60
  61     # example when CATALYST_VAR is set to 'Catalyst'
  62     Context is [% Catalyst %]
  63     The base is [% Catalyst.req.base %]
  64     The name is [% Catalyst.config.name %]
  65
  66     # example when CATALYST_VAR isn't set
  67     Context is [% c %]
  68     The base is [% base %]
  69     The name is [% name %]
  70
  71 =cut
  72
  73 sub _coerce_paths {
  74     my ( $paths, $dlim ) = shift;
  75     return () if ( !$paths );
  76     return @{$paths} if ( ref $paths eq 'ARRAY' );
  77
  78     # tweak delim to ignore C:/
  79     unless ( defined $dlim ) {
  80         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  81     }
  82     return split( /$dlim/, $paths );
  83 }
  84
  85 sub new {
  86     my ( $class, $c, $arguments ) = @_;
  87     my $config = {
  88         EVAL_PERL          => 0,
  89         TEMPLATE_EXTENSION => '',
  90         %{ $class->config },
  91         %{$arguments},
  92     };
  93     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  94         my $delim = $config->{DELIMITER};
  95         my @include_path
  96             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  97         if ( !@include_path ) {
  98             my $root = $c->config->{root};
  99             my $base = Path::Class::dir( $root, 'base' );
 100             @include_path = ( "$root", "$base" );
 101         }
 102         $config->{INCLUDE_PATH} = \@include_path;
 103     }
 104
 105     # if we're debugging and/or the TIMER option is set, then we install
 106     # Template::Timer as a custom CONTEXT object, but only if we haven't
 107     # already got a custom CONTEXT defined
 108
 109     if ( $config->{TIMER} ) {
 110         if ( $config->{CONTEXT} ) {
 111             $c->log->error(
 112                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 113             );
 114         }
 115         else {
 116             $config->{CONTEXT} = Template::Timer->new(%$config);
 117         }
 118     }
 119
 120     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 121         $c->log->debug( "TT Config: ", dump($config) );
 122     }
 123
 124     my $self = $class->next::method(
 125         $c, { %$config },
 126     );
 127
 128     # Set base include paths. Local'd in render if needed
 129     $self->include_path($config->{INCLUDE_PATH});
 130
 131     $self->config($config);
 132
 133     # Creation of template outside of call to new so that we can pass [ $self ]
 134     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 135     # of include paths to search for templates.
 136
 137     # Use a weakend copy of self so we dont have loops preventing GC from working
 138     my $copy = $self;
 139     Scalar::Util::weaken($copy);
 140     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 141
 142     if ( $config->{PROVIDERS} ) {
 143         my @providers = ();
 144         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 145             foreach my $p (@{$config->{PROVIDERS}}) {
 146                 my $pname = $p->{name};
 147                 my $prov = 'Template::Provider';
 148                 if($pname eq '_file_')
 149                 {
 150                     $p->{args} = { %$config };
 151                 }
 152                 else
 153                 {
 154                     if($pname =~ s/^\+//) {
 155                         $prov = $pname;
 156                     }
 157                     else
 158                     {
 159                         $prov .= "::$pname";
 160                     }
 161                     # We copy the args people want from the config
 162                     # to the args
 163                     $p->{args} ||= {};
 164                     if ($p->{copy_config}) {
 165                         map  { $p->{args}->{$_} = $config->{$_}  }
 166                                    grep { exists $config->{$_} }
 167                                    @{ $p->{copy_config} };
 168                     }
 169                 }
 170                 local $@;
 171                 eval "require $prov";
 172                 if(!$@) {
 173                     push @providers, "$prov"->new($p->{args});
 174                 }
 175                 else
 176                 {
 177                     $c->log->warn("Can't load $prov, ($@)");
 178                 }
 179             }
 180         }
 181         delete $config->{PROVIDERS};
 182         if(@providers) {
 183             $config->{LOAD_TEMPLATES} = \@providers;
 184         }
 185     }
 186
 187     $self->{template} =
 188         Template->new($config) || do {
 189             my $error = Template->error();
 190             $c->log->error($error);
 191             $c->error($error);
 192             return undef;
 193         };
 194
 195
 196     return $self;
 197 }
 198
 199 sub process {
 200     my ( $self, $c ) = @_;
 201
 202     my $template = $c->stash->{template}
 203       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 204
 205     unless (defined $template) {
 206         $c->log->debug('No template specified for rendering') if $c->debug;
 207         return 0;
 208     }
 209
 210     local $@;
 211     my $output = eval { $self->render($c, $template) };
 212     if (my $err = $@) {
 213         return $self->_rendering_error($c, $template . ': ' . $err);
 214     }
 215     if (blessed($output) && $output->isa('Template::Exception')) {
 216         $self->_rendering_error($c, $output);
 217     }
 218
 219     unless ( $c->response->content_type ) {
 220         $c->response->content_type('text/html; charset=utf-8');
 221     }
 222
 223     $c->response->body($output);
 224
 225     return 1;
 226 }
 227
 228 sub _rendering_error {
 229     my ($self, $c, $err) = @_;
 230     my $error = qq/Couldn't render template "$err"/;
 231     $c->log->error($error);
 232     $c->error($error);
 233     return 0;
 234 }
 235
 236 sub render {
 237     my ($self, $c, $template, $args) = @_;
 238
 239     $c->log->debug(qq/Rendering template "$template"/) if $c && $c->debug;
 240
 241     my $output;
 242     my $vars = {
 243         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 244         $self->template_vars($c)
 245     };
 246
 247     local $self->{include_path} =
 248         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 249         if ref $vars->{additional_template_paths};
 250
 251     unless ( $self->template->process( $template, $vars, \$output ) ) {
 252         if (exists $self->{render_die}) {
 253             die $self->template->error if $self->{render_die};
 254             return $self->template->error;
 255         }
 256         $c->log->debug('The Catalyst::View::TT render() method will start dying on error in a future release. Unless you are calling the render() method manually, you probably want the new behaviour, so set render_die => 1 in config for ' . blessed($self) . '. If you wish to continue to return the exception rather than throwing it, add render_die => 0 to your config.') if $c->debug;
 257         return $self->template->error;
 258     }
 259     return $output;
 260 }
 261
 262 sub template_vars {
 263     my ( $self, $c ) = @_;
 264
 265     return  () unless $c;
 266     my $cvar = $self->config->{CATALYST_VAR};
 267
 268     my %vars = defined $cvar
 269       ? ( $cvar => $c )
 270       : (
 271         c    => $c,
 272         base => $c->req->base,
 273         name => $c->config->{name}
 274       );
 275
 276     if ($self->config->{expose_methods}) {
 277         my $meta = $self->meta;
 278         foreach my $method_name (@{$self->config->{expose_methods}}) {
 279             my $method = $meta->get_method( $method_name );
 280             unless ($method) {
 281                 Catalyst::Exception->throw( "$method_name not found in TT view" );
 282             }
 283             my $method_body = $method->body;
 284             my $sub = sub {
 285                 $self->$method_body($c, @_);
 286             };
 287             $vars{$method_name} = $sub;
 288         }
 289     }
 290     return %vars;
 291 }
 292
 293 1;
 294
 295 __END__
 296
 297 =head1 DESCRIPTION
 298
 299 This is the Catalyst view class for the L<Template Toolkit|Template>.
 300 Your application should defined a view class which is a subclass of
 301 this module. Throughout this manual it will be assumed that your application
 302 is named F<MyApp> and you are creating a TT view named F<Web>; these names
 303 are placeholders and should always be replaced with whatever name you've
 304 chosen for your application and your view. The easiest way to create a TT
 305 view class is through the F<myapp_create.pl> script that is created along
 306 with the application:
 307
 308     $ script/myapp_create.pl view Web TT
 309
 310 This creates a F<MyApp::View::Web.pm> module in the F<lib> directory (again,
 311 replacing C<MyApp> with the name of your application) which looks
 312 something like this:
 313
 314     package FooBar::View::Web;
 315
 316     use strict;
 317     use warnings;
 318
 319     use base 'Catalyst::View::TT';
 320
 321     __PACKAGE__->config(DEBUG => 'all');
 322
 323 Now you can modify your action handlers in the main application and/or
 324 controllers to forward to your view class.  You might choose to do this
 325 in the end() method, for example, to automatically forward all actions
 326 to the TT view class.
 327
 328     # In MyApp or MyApp::Controller::SomeController
 329
 330     sub end : Private {
 331         my( $self, $c ) = @_;
 332         $c->forward( $c->view('Web') );
 333     }
 334
 335 But if you are using the standard auto-generated end action, you don't even need
 336 to do this!
 337
 338     # in MyApp::Controller::Root
 339     sub end : ActionClass('RenderView') {} # no need to change this line
 340
 341     # in MyApp.pm
 342     __PACKAGE__->config(
 343         ...
 344         default_view => 'Web',
 345     );
 346
 347 This will Just Work.  And it has the advantages that:
 348
 349 =over 4
 350
 351 =item *
 352
 353 If you want to use a different view for a given request, just set
 354 << $c->stash->{current_view} >>.  (See L<Catalyst>'s C<< $c->view >> method
 355 for details.
 356
 357 =item *
 358
 359 << $c->res->redirect >> is handled by default.  If you just forward to
 360 C<View::Web> in your C<end> routine, you could break this by sending additional
 361 content.
 362
 363 =back
 364
 365 See L<Catalyst::Action::RenderView> for more details.
 366
 367 =head2 CONFIGURATION
 368
 369 There are a three different ways to configure your view class.  The
 370 first way is to call the C<config()> method in the view subclass.  This
 371 happens when the module is first loaded.
 372
 373     package MyApp::View::Web;
 374
 375     use strict;
 376     use base 'Catalyst::View::TT';
 377
 378     __PACKAGE__->config({
 379         INCLUDE_PATH => [
 380             MyApp->path_to( 'root', 'templates', 'lib' ),
 381             MyApp->path_to( 'root', 'templates', 'src' ),
 382         ],
 383         PRE_PROCESS  => 'config/main',
 384         WRAPPER      => 'site/wrapper',
 385     });
 386
 387 You may also override the configuration provided in the view class by adding
 388 a 'View::Web' section to your application config (either in the application
 389 main class, or in your configuration file). This should be reserved for
 390 deployment-specific concerns. For example:
 391
 392     # MyApp_local.conf (Config::General format)
 393
 394     <View Web>
 395       WRAPPER "custom_wrapper"
 396       INCLUDE_PATH __path_to('root/templates/custom_site')__
 397       INCLUDE_PATH __path_to('root/templates')__
 398     </View>
 399
 400 might be used as part of a simple way to deploy different instances of the
 401 same application with different themes.
 402
 403 =head2 DYNAMIC INCLUDE_PATH
 404
 405 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 406
 407 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 408 follows:
 409
 410     $c->stash->{additional_template_paths} =
 411         [$c->config->{root} . '/test_include_path'];
 412
 413 If you need to add paths to the end of INCLUDE_PATH, there is also an
 414 include_path() accessor available:
 415
 416     push( @{ $c->view('Web')->include_path }, qw/path/ );
 417
 418 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 419 MUST check for duplicate paths. Without such checking, the above code will add
 420 "path" to INCLUDE_PATH at every request, causing a memory leak.
 421
 422 A safer approach is to use include_path() to overwrite the array of paths
 423 rather than adding to it. This eliminates both the need to perform duplicate
 424 checking and the chance of a memory leak:
 425
 426     @{ $c->view('Web')->include_path } = qw/path another_path/;
 427
 428 If you are calling C<render> directly then you can specify dynamic paths by
 429 having a C<additional_template_paths> key with a value of additonal directories
 430 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 431
 432 =head2 RENDERING VIEWS
 433
 434 The view plugin renders the template specified in the C<template>
 435 item in the stash.
 436
 437     sub message : Global {
 438         my ( $self, $c ) = @_;
 439         $c->stash->{template} = 'message.tt2';
 440         $c->forward( $c->view('Web') );
 441     }
 442
 443 If a stash item isn't defined, then it instead uses the
 444 stringification of the action dispatched to (as defined by $c->action)
 445 in the above example, this would be C<message>, but because the default
 446 is to append '.tt', it would load C<root/message.tt>.
 447
 448 The items defined in the stash are passed to the Template Toolkit for
 449 use as template variables.
 450
 451     sub default : Private {
 452         my ( $self, $c ) = @_;
 453         $c->stash->{template} = 'message.tt2';
 454         $c->stash->{message}  = 'Hello World!';
 455         $c->forward( $c->view('Web') );
 456     }
 457
 458 A number of other template variables are also added:
 459
 460     c      A reference to the context object, $c
 461     base   The URL base, from $c->req->base()
 462     name   The application name, from $c->config->{ name }
 463
 464 These can be accessed from the template in the usual way:
 465
 466 <message.tt2>:
 467
 468     The message is: [% message %]
 469     The base is [% base %]
 470     The name is [% name %]
 471
 472
 473 The output generated by the template is stored in C<< $c->response->body >>.
 474
 475 =head2 CAPTURING TEMPLATE OUTPUT
 476
 477 If you wish to use the output of a template for some other purpose than
 478 displaying in the response, e.g. for sending an email, this is possible using
 479 L<Catalyst::Plugin::Email> and the L<render> method:
 480
 481   sub send_email : Local {
 482     my ($self, $c) = @_;
 483
 484     $c->email(
 485       header => [
 486         To      => 'me@localhost',
 487         Subject => 'A TT Email',
 488       ],
 489       body => $c->view('Web')->render($c, 'email.tt', {
 490         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 491         email_tmpl_param1 => 'foo'
 492         }
 493       ),
 494     );
 495   # Redirect or display a message
 496   }
 497
 498 =head2 TEMPLATE PROFILING
 499
 500 See L<C<TIMER>> property of the L<config> method.
 501
 502 =head2 METHODS
 503
 504 =head2 new
 505
 506 The constructor for the TT view. Sets up the template provider,
 507 and reads the application config.
 508
 509 =head2 process($c)
 510
 511 Renders the template specified in C<< $c->stash->{template} >> or
 512 C<< $c->action >> (the private name of the matched action).  Calls L<render> to
 513 perform actual rendering. Output is stored in C<< $c->response->body >>.
 514
 515 It is possible to forward to the process method of a TT view from inside
 516 Catalyst like this:
 517
 518     $c->forward('View::Web');
 519
 520 N.B. This is usually done automatically by L<Catalyst::Action::RenderView>.
 521
 522 =head2 render($c, $template, \%args)
 523
 524 Renders the given template and returns output. Throws a L<Template::Exception>
 525 object upon error.
 526
 527 The template variables are set to C<%$args> if C<$args> is a hashref, or
 528 C<< $c->stash >> otherwise. In either case the variables are augmented with
 529 C<base> set to C<< $c->req->base >>, C<c> to C<$c>, and C<name> to
 530 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 531 can be defined to specify the name of a template variable through which the
 532 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base>, and
 533 C<name> variables are omitted.
 534
 535 C<$template> can be anything that Template::process understands how to
 536 process, including the name of a template file or a reference to a test string.
 537 See L<Template::process|Template/process> for a full list of supported formats.
 538
 539 To use the render method outside of your Catalyst app, just pass a undef context.
 540 This can be useful for tests, for instance.
 541
 542 It is possible to forward to the render method of a TT view from inside Catalyst
 543 to render page fragments like this:
 544
 545     my $fragment = $c->forward("View::Web", "render", $template_name, $c->stash->{fragment_data});
 546
 547 =head3 Backwards compatibility note
 548
 549 The render method used to just return the Template::Exception object, rather
 550 than just throwing it. This is now deprecated and instead the render method
 551 will throw an exception for new applications.
 552
 553 This behaviour can be activated (and is activated in the default skeleton
 554 configuration) by using C<< render_die => 1 >>. If you rely on the legacy
 555 behaviour then a warning will be issued.
 556
 557 To silence this warning, set C<< render_die => 0 >>, but it is recommended
 558 you adjust your code so that it works with C<< render_die => 1 >>.
 559
 560 In a future release, C<< render_die => 1 >> will become the default if
 561 unspecified.
 562
 563 =head2 template_vars
 564
 565 Returns a list of keys/values to be used as the catalyst variables in the
 566 template.
 567
 568 =head2 config
 569
 570 This method allows your view subclass to pass additional settings to
 571 the TT configuration hash, or to set the options as below:
 572
 573 =head2 paths
 574
 575 The list of paths TT will look for templates in.
 576
 577 =head2 expose_methods
 578
 579 The list of methods in your View class which should be made available to the templates.
 580
 581 For example:
 582
 583   expose_methods => [qw/uri_for_static/],
 584
 585   ...
 586
 587   sub uri_for_css {
 588     my ($self, $c, $filename) = @_;
 589
 590     # additional complexity like checking file exists here
 591
 592     return $c->uri_for('/static/css/' . $filename);
 593   }
 594
 595 Then in the template:
 596
 597   [% uri_for_css('home.css') %]
 598
 599 =head2 C<CATALYST_VAR>
 600
 601 Allows you to change the name of the Catalyst context object. If set, it will also
 602 remove the base and name aliases, so you will have access them through <context>.
 603
 604 For example, if CATALYST_VAR has been set to "Catalyst", a template might
 605 contain:
 606
 607     The base is [% Catalyst.req.base %]
 608     The name is [% Catalyst.config.name %]
 609
 610 =head2 C<TIMER>
 611
 612 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 613 C<Catalyst::View::TT> will enable profiling of template processing
 614 (using L<Template::Timer>). This will embed HTML comments in the
 615 output from your templates, such as:
 616
 617     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 618     <!-- TIMER START: include mainmenu/cssindex.tt -->
 619     <!-- TIMER START: process mainmenu/cssindex.tt -->
 620     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 621     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 622
 623     ....
 624
 625     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 626
 627
 628 =head2 C<TEMPLATE_EXTENSION>
 629
 630 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 631
 632 For example:
 633
 634   package MyApp::Controller::Test;
 635   sub test : Local { .. }
 636
 637 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 638 <root>/test/test.tt.
 639
 640 =head2 C<PROVIDERS>
 641
 642 Allows you to specify the template providers that TT will use.
 643
 644     MyApp->config({
 645         name     => 'MyApp',
 646         root     => MyApp->path_to('root'),
 647         'View::Web' => {
 648             PROVIDERS => [
 649                 {
 650                     name    => 'DBI',
 651                     args    => {
 652                         DBI_DSN => 'dbi:DB2:books',
 653                         DBI_USER=> 'foo'
 654                     }
 655                 }, {
 656                     name    => '_file_',
 657                     args    => {}
 658                 }
 659             ]
 660         },
 661     });
 662
 663 The 'name' key should correspond to the class name of the provider you
 664 want to use.  The _file_ name is a special case that represents the default
 665 TT file-based provider.  By default the name is will be prefixed with
 666 'Template::Provider::'.  You can fully qualify the name by using a unary
 667 plus:
 668
 669     name => '+MyApp::Provider::Foo'
 670
 671 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 672 from the general config, into the config for the provider:
 673
 674     DEFAULT_ENCODING    => 'utf-8',
 675     PROVIDERS => [
 676         {
 677             name    => 'Encoding',
 678             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 679         }
 680     ]
 681
 682 This can prove useful when you want to use the additional_template_paths hack
 683 in your own provider, or if you need to use Template::Provider::Encoding
 684
 685 =head2 HELPERS
 686
 687 The L<Catalyst::Helper::View::TT> and
 688 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 689 your view module.  There are invoked by the F<myapp_create.pl> script:
 690
 691     $ script/myapp_create.pl view Web TT
 692
 693     $ script/myapp_create.pl view Web TTSite
 694
 695 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 696 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 697 further.  It also creates a default set of templates to get you
 698 started.  It also configures the view module to locate the templates
 699 automatically.
 700
 701 =head1 NOTES
 702
 703 If you are using the L<CGI> module inside your templates, you will
 704 experience that the Catalyst server appears to hang while rendering
 705 the web page. This is due to the debug mode of L<CGI> (which is
 706 waiting for input in the terminal window). Turning off the
 707 debug mode using the "-no_debug" option solves the
 708 problem, eg.:
 709
 710     [% USE CGI('-no_debug') %]
 711
 712 =head1 SEE ALSO
 713
 714 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 715 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 716
 717 =head1 AUTHORS
 718
 719 Sebastian Riedel, C<sri@cpan.org>
 720
 721 Marcus Ramberg, C<mramberg@cpan.org>
 722
 723 Jesse Sheidlower, C<jester@panix.com>
 724
 725 Andy Wardley, C<abw@cpan.org>
 726
 727 =head1 COPYRIGHT
 728
 729 This program is free software. You can redistribute it and/or modify it
 730 under the same terms as Perl itself.
 731
 732 =cut